PureBasic Forums - English

Code: Select all

NewList JPG_CommentList.s()

Procedure JPG_Comment(Filename$, List Comment.s())
  
  Dim Buffer.a(1)
  
  Result = #False
  
  File = ReadFile(#PB_Any, Filename$)
  If File
    FileSize = Lof(File)
    ;Debug "Filesize: " + Str(FileSize)
    EOI = #False
    Length.l = 0
    FilePos.q = 0
    Repeat
      If ReadData(File, @Buffer(0), 2) = 2
        FilePos + 2
        If Buffer(0) = $FF
          ;Debug "Filepos: " + Hex(FilePos)
          ;Debug Hex(Buffer(1))
          Select Buffer(1)
            Case $D8  ; SOI
            Case $D9  ; EOI
              EOI = #True
            Case $DA  ; SOS
              EOI = #True
            Case $FE  ; COM
              If ReadData(File, @Buffer(0), 2) = 2
                Length = Buffer(0) << 8 | Buffer(1)
                Comment$ = ReadString(File)
                AddElement(Comment())
                Comment() = Comment$
                FilePos + Len(Comment$)
                Result = #True
              EndIf
            Default
              If ReadData(File, @Buffer(0), 2) = 2
                Length = Buffer(0) << 8 | Buffer(1)
                ;Debug "Length: " + Hex(Length)
                FilePos + Length
                ;Debug "Filepos BKK: " + Hex(FilePos)
                FileSeek(File, FilePos)
              EndIf
          EndSelect
        EndIf
      EndIf
      If Eof(File)
        ;Debug "EOF"
        EOI = #True
      EndIf
    Until EOI
    CloseFile(File)
  EndIf
  
  ProcedureReturn Result
  
EndProcedure


Filename$ = OpenFileRequester("Choose a JPG file", "", "JPG (*.jpg)|*.jpg", 0)
If Len(Filename$) > 0
  If JPG_Comment(Filename$, JPG_CommentList())
    Text$ = "Comments:" + #LF$
    ForEach JPG_CommentList()
      Text$ + JPG_CommentList() + #LF$
    Next
  Else
    Text$ = "No comment found"
  EndIf
  MessageRequester("Comments", Text$)
EndIf