PureBasic Forums - English

Code: Select all

;Original code by Little John
;http://forums.purebasic.com/english/viewtopic.php?f=5&t=44978
EnableExplicit
Define Result, TestFile$, TestPath$ = "M:\Completed\CSI Miami - Season 03 - HDTV\";GetTemporaryDirectory()
Procedure.i FileIsClosed (fileName$)
   ; returns #False if the file does not exist, or if it is opened by another process;
   ;         #True otherwise
   ;
   ; Note: By passing zero as 3rd parameter for CreateFile_(),
   ;       we request *exclusive* access to the respective file.
   ;       This fails if the file is already open.
   ; <http://msdn.microsoft.com/en-us/library/aa363858%28v=vs.85%29.aspx>
   ; <http://msdn.microsoft.com/en-us/library/aa363874%28v=vs.85%29.aspx>
   Protected handle
   
   handle = CreateFile_(@fileName$, #GENERIC_READ, 0, #Null, #OPEN_EXISTING, #FILE_ATTRIBUTE_NORMAL, #Null)
   If handle = #INVALID_HANDLE_VALUE
      ProcedureReturn #False
   Else
      CloseHandle_(handle)
      ProcedureReturn #True
   EndIf   
EndProcedure

If ExamineDirectory(0, TestPath$, "*.*")  
  While NextDirectoryEntry(0)
    If DirectoryEntryType(0) = #PB_DirectoryEntry_File
      TestFile$ = TestPath$ + DirectoryEntryName(0)
      Result = FileIsClosed(TestFile$)
      If Result = #False
        Debug "Another process has exclusive access to this file: " + TestFile$
      EndIf
    EndIf
  Wend
  FinishDirectory(0)
Else
  Debug "oops, that directory doesn't exist...."
EndIf