PureBasic Forums - English

Code: Select all

; ---------------------------------------------------------------------------------------------
; author: nituvious
; notes:
;	This program will try to modify your source code by adding the date 
;	upon saving the file. If it finds a date recorded already, it will attempt 
;	 to overwrite it with the current date and time. 
;	Otherwise it will automatically add the date at the beginning of the file.
;	This program includes fully changable date/time functions as well.
;	
;	Please let me know of any bugs!
;
; ---------------------------------------------------------------------------------------------
; last modified: February 27th, 2011 @ 3:24:05 AM
; ---------------------------------------------------------------------------------------------


#C12HOUR = 12 ; silly constants, trying to pretend to be a clock!
#C24HOUR = 24

Procedure.s GetDate()

	gMonth.b = Month(Date()) : gDay.b = Day(Date()) : gYear.i = Year(Date())
	
	Dim monthName.s(12) ; set each month by it's english name into an array
	; I am not aware of any native PB function that formats the date with a string
	monthName.s(0) = "none" ; <-- the array should only have 11 elements, but for sake of simplicity(my favorite thing in the world) it will have 12 elements instead
	monthName.s(1) = "January"
	monthName.s(2) =  "February"
	monthName.s(3) =  "March"
	monthName.s(4) =  "April"
	monthName.s(5) =  "May"
	monthName.s(6) =  "June"
	monthName.s(7) =  "July"
	monthName.s(8) =  "August"
	monthName.s(9) =  "September"
	monthName.s(10) =  "October"
	monthName.s(11) =  "November"
	monthName.s(12) =  "December" ; <-- my favorite month

	; give each day ending with 1, 2, 3, 4... 23,24 etc their proper ordinal suffix
	If (Val(Mid(Str(gDay.b),Len(Str(gDay.b)))) = 1) : ordSuffix.s = "st"
	ElseIf (Val(Mid(Str(gDay.b),Len(Str(gDay.b)))) = 2) : ordSuffix.s = "nd"
	ElseIf (Val(Mid(Str(gDay.b),Len(Str(gDay.b)))) = 3) : ordSuffix.s = "rd"
	Else : ordSuffix.s = "th" : EndIf
	
	gDate.s = monthName.s(gMonth.b) + " " + Str(gDay.b)+ ordSuffix.s + ", " + Str(gYear.i)
	ProcedureReturn  gDate.s
EndProcedure

Procedure.S GetTime(const)
	; depending on user settings, should this date be displayed as a 24 hour clock, or 12 hour?
	; format 12 hour clock...

	gHour.i = Hour(Date())

	If const = #C12HOUR ; this is my crappy time conversion function which will add meridiem if the 12 hour clock is used
		If gHour.i >= 13
			gHour_n.i = gHour.i - 12
			gMeridiem.s = "PM"
		Else
			If gHour.i = 0
				gHour_n = 12
			EndIf
			gHour_n.i = gHour.i
			gMeridiem.s = "AM"
		EndIf
		gTime.s = Str(gHour_n.i) + ":" + FormatDate("%ii:%ss",Date()) + " " + gMeridiem.s
		ProcedureReturn gTime.s
	ElseIf const = #C24HOUR
		gTime.s = FormatDate("%hh:%ii:%ss",Date())
		ProcedureReturn gTime.s
	EndIf
EndProcedure

Procedure AddDateToSource(modString.s)
	source.s = ProgramParameter(0)
	file = OpenFile(#PB_Any,source.s)
	If file <> 0
		While Eof(file) = 0
			string$ = ReadString(file)
			bufferSize = Lof(file) - Loc(file)
			If FindString(string$, "; last modified: ",1) ; all i am doing here is looking for the "last modified" string, if it's found then I add date in it's location
				*bufferFile = AllocateMemory(bufferSize)
	
				location = Loc(file) - Len(string$) - 2 ; -- Why does it require len - 2?? beginning/ending of line maybe?
				ReadData(file, *bufferFile,bufferSize)
				FileSeek(file, location)
				TruncateFile(file)
				
				WriteStringN(file, modString.s)
				WriteData(file, *bufferFile, bufferSize)

				CloseFile(file)

				ProcedureReturn 1 ; done, exit loop and return
			EndIf
		Wend
		
		; I can't seem to think of any other way to reset location to the beginning of the file after reaching the EoF
		; no entry found, so add one at the beginning of the file
		
		bufferSize = Lof(file)
		FileSeek(file,0) ; <-- go back to beginning of the file
		*bufferFile = AllocateMemory(bufferSize)
		ReadData(file, *bufferFile, bufferSize)
		FileSeek(file,0) ; <-- go back again after copying everything
		TruncateFile(file)

		WriteStringN(file,modString.s)
		WriteData(file,*bufferFile,bufferSize)

		CloseFile(file)
		; all done :-(
	EndIf
EndProcedure

AddDateToSource("; last modified: " + GetDate() + " @ " + GetTime(#C12HOUR))

Code: Select all

Procedure.s GetDate()
	Protected Result.s, gMonth, gDay.s, gYear.s, monthNames.s

	gMonth     = Month(Date())
	gDay       = Str(Day(Date()))
	gYear      = Str(Year(Date()))
	monthNames = "January|February|March|April|May|June|July|August|September|October|November|December"

	; give each day ending with 1, 2, 3, 4... 23,24 etc their proper ordinal suffix
	If gDay = "1"
		gDay + "st"
	ElseIf gDay = "2"
		gDay + "nd"
	ElseIf gDay = "3"
		gDay + "rd"
	Else
		gDay + "th"
	EndIf

	Result = StringField(monthNames, gMonth, "|") + " " + gDay + ", " + gYear
	ProcedureReturn  Result
EndProcedure

Code: Select all

Procedure.s GetDate()
   Protected Result.s, gMonth, gDay.s, gYear.s, monthNames.s

   gMonth     = Month(Date())
   gDay       = Str(Day(Date()))
   gYear      = Str(Year(Date()))
   monthNames = "January|February|March|April|May|June|July|August|September|October|November|December"

   ; give each day ending with 1, 2, 3, 4... 23,24 etc their proper ordinal suffix
   Select gDay
     Case "1", "21","31"
       gDay + "st"
     Case "2","22"
       gDay + "nd"
     Case "3","23"
       gDay + "rd"
     Default
       gDay + "th"
   EndSelect 
   
   Result = StringField(monthNames, gMonth, "|") + " " + gDay + ", " + gYear
   ProcedureReturn  Result
EndProcedure

Debug GetDate()

Code: Select all

; ----------------------------------------------------
; last modified: March 3rd, 2011 @ 22:40:35
; ----------------------------------------------------

Code: Select all

RunProgram("open", Chr(34) + source + ".pb" + Chr(34), "", #PB_Program_Wait)

Code: Select all

myVariable.i = 1 ; last modified: March 4th, 2011 @ 3:36:25 AM

Code: Select all

Procedure AddDateToSource(modstring.s)  ; New routine, FileName "AddDateToSource",  Toolname: "AddDateToSource"
   Protected done
   done = 1
   
   source.s = ProgramParameter(0)
   tempsource.s = ProgramParameter(1)
   
   If ReadFile(1, source)   ; open file for reading
     If CreateFile(2, source + ".pb")    ; create 2. file for writing the changed file
       
       Repeat
         string.s = ReadString(1)   ; read string from source
         
         pos1 = FindString(string.s, "; last modified:", 1)
         If pos1 = 1    ; yes, this is the line ! And it begins at position 1 !!
           WriteStringN(2, modString.s + #CR$)    ; write the new values into 2. file
           done = 0
         Else
           WriteStringN(2, string.s + #CR$)
         EndIf
         
       Until Eof(1)
       
       If done = 1
         FileSeek(1, 0)
         If CreateFile(2, source + ".pb")
           WriteStringN(2, "; ----------------------------------------------------" + #CR$)
           WriteStringN(2, modstring.s + #CR$)
           WriteStringN(2, "; ----------------------------------------------------" + #CR$)
           Repeat
             WriteStringN(2, ReadString(1) + #CR$)
           Until Eof(1)
         EndIf
         
       EndIf
       
       
     EndIf
   EndIf
   
   CloseFile(2)
   CloseFile(1)
   
   DeleteFile(source)    ; delete old file
   RenameFile(source +".pb", source)   ; rename new File (nr. 2) to old file
   
   CopyFile(source, tempsource)

 EndProcedure

Code: Select all

; To configure, compile program With whatever name you wish then click Tools > Configure Tools > Click New
; Now edit To something similar:
; New routine, FileName "AddDateToSource",  Toolname: "AddDateToSource"
; Commandline: 'Browse' to "AddDateToSource"
; Arguments: %FILE %TEMPFILE
; Name: "AddDateToSource"
; Event To trigger the tool: Sourcecode saved

; To prevent an annoying console from popping up every save, I have Run Hidden checked

; ---------------------------------------------------------------------------------------------
; author: nituvious (modifed by mitchel51)
; notes:
;   This program will try to modify your source code by adding the date 
;   upon saving the file. If it finds a date recorded already, it will attempt 
;    to overwrite it with the current date and time. 
;   Otherwise it will automatically add the date at the beginning of the file.
;   This program includes fully changable date/time functions as well.
; ---------------------------------------------------------------------------------------------

EnableExplicit

#C12HOUR = 12 ; silly constants, trying to pretend to be a clock!
#C24HOUR = 24
  
Procedure.s GetDate()  ; modified by LuCiFeR[SD]
   Protected Result.s, gMonth, gDay.s, gYear.s, monthNames.s
   gMonth     = Month(Date())
   gDay       = Str(Day(Date()))
   gYear      = Str(Year(Date()))
   monthNames = "January|February|March|April|May|June|July|August|September|October|November|December"

   ; give each day ending with 1, 2, 3, 4... 23,24 etc their proper ordinal suffix
   Select gDay
     Case "1", "21","31"
       gDay + "st"
     Case "2","22"
       gDay + "nd"
     Case "3","23"
       gDay + "rd"
     Default
       gDay + "th"
   EndSelect 
   Result = StringField(monthNames, gMonth, "|") + " " + gDay + ", " + gYear
   ProcedureReturn  Result
EndProcedure

Procedure.S GetTime(const)
   ; depending on user settings, should this date be displayed as a 24 hour clock, or 12 hour?
   ; format 12 hour clock...
    Protected gHour,gHour_n,gMeridiem.s,gTime.s
   gHour.i = Hour(Date())

   If const = #C12HOUR ; this is my crappy time conversion function which will add meridiem if the 12 hour clock is used
      If gHour>= 13
         gHour_n.i = gHour.i - 12
         gMeridiem.s = "PM"
      Else
         If gHour.i = 0
            gHour_n = 12
         EndIf
         gHour_n.i = gHour.i
         gMeridiem.s = "AM"
      EndIf
      gTime.s = Str(gHour_n.i) + ":" + FormatDate("%ii:%ss",Date()) + " " + gMeridiem.s
      ProcedureReturn gTime.s
   ElseIf const = #C24HOUR
      gTime.s = FormatDate("%hh:%ii:%ss",Date())
      ProcedureReturn gTime.s
   EndIf
EndProcedure

Procedure AddDateToSource(modstring.s)  ; by mitchel51
   Protected done,source.s,tempsource.s,string.s,pos1
   done = 1
   
   source.s = ProgramParameter(0)
   tempsource.s = ProgramParameter(1)
   
   If ReadFile(1, source)   ; open file for reading
     If CreateFile(2, source + ".pb")    ; create 2. file for writing the changed file
       
       Repeat
         string.s = ReadString(1)   ; read string from source
         
         pos1 = FindString(string.s, "; last modified:", 1)
         If pos1 = 1    ; yes, this is the line ! And it begins at position 1 !!
           WriteStringN(2, modString.s + #CR$)    ; write the new values into 2. file
           done = 0
         Else
           WriteStringN(2, string.s + #CR$)
         EndIf
         
       Until Eof(1)
       
       If done = 1
         FileSeek(1, 0)
         If CreateFile(2, source + ".pb")
           WriteStringN(2, "; ----------------------------------------------------" + #CR$)
           WriteStringN(2, modstring.s + #CR$)
           WriteStringN(2, "; ----------------------------------------------------" + #CR$)
           Repeat
             WriteStringN(2, ReadString(1) + #CR$)
           Until Eof(1)
         EndIf
         
       EndIf
       
       
     EndIf
   EndIf
   
   CloseFile(2)
   CloseFile(1)
   
   DeleteFile(source)    ; delete old file
   RenameFile(source +".pb", source)   ; rename new File (nr. 2) to old file
   
   CopyFile(source, tempsource)

EndProcedure

AddDateToSource("; last modified: " + GetDate() + " @ " + GetTime(#C12HOUR))