PureBasic Forums - English

Code: Select all

Enumeration
  #Princess
  #Tiger
  #Empty
EndEnumeration

Procedure CheckSigns(Array Rooms.l(1))
  Protected Dim Signs.l(8)

  ; Sign 1
  If Rooms(4) <> #Empty
    Signs(1) = #True    
  EndIf
  If (Rooms(1) = #Princess And Signs(1) = #False) Or (Rooms(1) <> #Princess And Signs(1) = #True)
    ProcedureReturn #False
  EndIf

  ; Sign 3
  If Rooms(2) <> #Empty And Rooms(7) <> #Empty
    Signs(3) = #True
  EndIf
  If (Rooms(3) = #Princess And Signs(3) = #False) Or (Rooms(3) <> #Princess And Signs(3) = #True)
    ProcedureReturn #False
  EndIf
  
  ; Sign 4
  If Rooms(1) <> #Empty
    Signs(4) = #True
  EndIf
  If (Rooms(4) = #Princess And Signs(4) = #False) Or (Rooms(4) <> #Princess And Signs(4) = #True)
    ProcedureReturn #False
  EndIf
  
  ; Sign 7
  For i = 1 To 8
    If i % 2 = 1 And Rooms(i) = #Princess
      Signs(7) = #True
      Break
    EndIf
  Next i
  If (Rooms(7) = #Princess And Signs(7) = #False) Or (Rooms(7) <> #Princess And Signs(7) = #True)
    ProcedureReturn #False
  EndIf  
  
  ; Sign 8
  If Rooms(8) = #Tiger And Signs(3) = #False
    Signs(8) = #True
  EndIf
  If (Rooms(8) = #Princess And Signs(8) = #False) Or (Rooms(8) <> #Princess And Signs(8) = #True)
    ProcedureReturn #False
  EndIf 
  
  ; 2, 5 and 6 need a bit thinking
  
  ; The princeess can never be in Room 2, else its sign is false and that cannot be
  If Rooms(2) = #Princess
    ProcedureReturn #False
  EndIf
  
  ; .. but then for sign 2 to be false, sign 5 must be false, so no princess in room 5
  If Rooms(5) = #Princess
    ProcedureReturn #False
  EndIf
  
  ; ... same for sign 6
  If Rooms(6) = #Princess
    ProcedureReturn #False
  EndIf
  
  ; No princess in room 6, so its sign must be false. sign 2 is already false, so room 8 must be empty
  If Rooms(8) <> #Empty
    ProcedureReturn #False
  EndIf
  
  ; all signs checked, this is a solution
  ProcedureReturn #True
 
EndProcedure

; permutate all possibilitties
;
Dim Rooms.l(8)

For Princess = 1 To 8

  ; 7 fields to set with either tiger or no tiger, so everything from binary %0000000 to binary %1111111
  For x = %0000000 To %1111111
  
    For i = 1 To 8
      If i = Princess
        Rooms(i) = #Princess
      ElseIf i < Princess And x & (1 << (i-1))
        Rooms(i) = #Tiger
      ElseIf i > Princess And x & (1 << (i-2))
        Rooms(i) = #Tiger
      Else
        Rooms(i) = #Empty
      EndIf
    Next i
    
    If CheckSigns(Rooms())
      Debug "solution:"
      For i = 1 To 8
        If Rooms(i) = #Princess
          Debug "  " + Str(i) + ": Princess"
        ElseIf Rooms(i) = #Tiger
          Debug "  " + Str(i) + ": Tiger"
        Else
          Debug "  " + Str(i) + ": -"
        EndIf
      Next i
      c + 1
    EndIf
        
  Next x
Next Princess

Debug "Solutions: " + Str(c)