PureBasic Forums - English

Posted: **Tue Feb 09, 2010 7:13 pm**

Hello at all

I use an EditorGadget, but i see that the first click put the cursor into it, and sometime the second clic by random way detect the clic

I have try two method and it's the same thing

1/ Have you a tips for detect the first clic all the time ??? :roll:

2/ Have you another tips for hide cursor and stop the selection of the text inside ???
Because when i write this instruction, the cursor always appears

Code: Select all

SetGadgetAttribute(#Editor, #PB_Editor_ReadOnly, #true)

I can't use "DisableGadget()" because when an EditorGadget is Disable he loose his color and is all grey

Code: Select all

OpenWindow(0, 0, 0, 322, 150, "EditorGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  
EditorGadget(0, 8, 8, 306, 133) 

Repeat
 
 Event = WaitWindowEvent()
 
 If Event = #WM_LBUTTONDOWN
  MessageRequester("", "Hello WM")
 EndIf
  
 Select #PB_Event_Gadget
  
  Case #PB_EventType_LeftClick
  
   MessageRequester("", "Hello PB")
   
 EndSelect
   
Until Event = #PB_Event_CloseWindow

Thanks and good day

Posted: **Wed Feb 10, 2010 1:38 am**

See if this behaves the way you want:

Code: Select all

Procedure EditProc(hwnd, msg, wparam, lparam)
  oldproc = GetProp_(hwnd, "oldproc")

  Select msg
    Case #WM_NCDESTROY
      RemoveProp_(hwnd, "oldproc")
    
    Case #WM_MOUSEMOVE
      If GetForegroundWindow_()<>WindowID(0)
        SetForegroundWindow_(WindowID(0))
      EndIf
      If GetActiveGadget()<>GetDlgCtrlID_(hwnd)
        SetActiveGadget(GetDlgCtrlID_(hwnd))
      EndIf
    
    Case #WM_KEYDOWN, #WM_KEYUP
      ProcedureReturn 0
    
  EndSelect   
  ProcedureReturn CallWindowProc_(oldproc, hwnd, msg, wparam, lparam)
EndProcedure

Procedure WinProc(hwnd, msg, wparam, lparam)
  result = #PB_ProcessPureBasicEvents
  Select msg
    Case #WM_COMMAND
      If lparam = GadgetID(0)
        If wparam>>16 = #EN_SETFOCUS
          HideCaret_(GadgetID(0))
        EndIf
      EndIf
  EndSelect
  ProcedureReturn result
EndProcedure

OpenWindow(0, 0, 0, 322, 150, "EditorGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  

hwnd = EditorGadget(0, 8, 8, 306, 133, #PB_Editor_ReadOnly) 
SetGadgetText(0,"Hello I'm an editor gadget")
SetProp_(hwnd, "oldproc", SetWindowLongPtr_(hwnd, #GWL_WNDPROC, @EditProc()))
SetWindowCallback(@WinProc())

Repeat

Event = WaitWindowEvent()

If Event = #WM_LBUTTONDOWN
  MessageRequester("", "Hello WM")
EndIf
  
Select #PB_Event_Gadget
  
  Case #PB_EventType_LeftClick
  
   MessageRequester("", "Hello PB")
   
EndSelect
   
Until Event = #PB_Event_CloseWindow

Posted: **Wed Feb 10, 2010 1:53 am**

I'm 100% certain that netmaestro has given the best solution. An alternative would be to test the cursor x y position and hide/un-hide the cursor based on that result.

Posted: **Wed Feb 10, 2010 9:14 am**

Thanks MASTER NETMAESTRO

It's exactely what i want....
You are really my favorite frog

Perhaps a day ....i can give you, a little kiss on your splendid teeth, for thanks you to all your help at KCC :roll:
And you transform in prince, like in walt disney...

And even...i'm sure you transform in better that a prince ....in king of the programming

I have try to modify your jewel...and with it ...KCC have make a ....vulgar stone code

Because i want can stop the effect of inactive Editor.

The top of the top, is a function like this

Code: Select all

EditorDisable(0, #true)

I have again a problem, when the Edito to be active, i can write on it, but not Erase character

This is my shit

Code: Select all

Global ActiveEditor

Procedure EditorDisable(PbId, Value)

 If Value
  
  ActiveEditor = #False
  SetGadgetAttribute(0, #PB_Editor_ReadOnly, #True)
  
 Else
  
  ActiveEditor = #True
  ShowCaret_(GadgetID(0))
  SetGadgetAttribute(0, #PB_Editor_ReadOnly, #False)
 EndIf
 
EndProcedure

Procedure EditProc(hwnd, msg, wparam, lparam)

 oldproc = GetProp_(hwnd, "oldproc")
 
 Select msg
 
  Case #WM_NCDESTROY
   
   If Not ActiveEditor
    RemoveProp_(hwnd, "oldproc")
   EndIf
   
  Case #WM_MOUSEMOVE
  
   If Not ActiveEditor
   
    If GetForegroundWindow_()<>WindowID(0)
     SetForegroundWindow_(WindowID(0))
    EndIf
    If GetActiveGadget()<>GetDlgCtrlID_(hwnd)
     SetActiveGadget(GetDlgCtrlID_(hwnd))
    EndIf
    
    HideCaret_(GadgetID(0))
    
   EndIf
   
  Case #WM_KEYDOWN, #WM_KEYUP
  
   ProcedureReturn 0
      
  Case #WM_RBUTTONDOWN
        
   If Not ActiveEditor
    MessageRequester("", "Hello PB, 'im active now !!")
    EditorDisable(0, #False)
   Else
    MessageRequester("", "Hello PB, 'im inactive now !!")
    EditorDisable(0, #True)
   EndIf
       
 EndSelect   
   
 ProcedureReturn CallWindowProc_(oldproc, hwnd, msg, wparam, lparam)
 
EndProcedure

Procedure WinProc(hwnd, msg, wparam, lparam)
 
 result = #PB_ProcessPureBasicEvents
 
 If Not ActiveEditor
 
 Select msg
 
  Case #WM_COMMAND
      
   If lparam = GadgetID(0)
     
    If wparam>>16 = #EN_SETFOCUS
     HideCaret_(GadgetID(0))
    EndIf 
     
   EndIf
   
  EndSelect
  
 EndIf 
 
 ProcedureReturn result
 
EndProcedure

OpenWindow(0, 0, 0, 322, 150, "EditorGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  

hwnd = EditorGadget(0, 8, 8, 306, 133, #PB_Editor_ReadOnly) 
SetGadgetText(0,"Hello I'm an inactive editor gadget," + Chr(13) + "Right click To convert me in active editor !!!")
SetProp_(hwnd, "oldproc", SetWindowLongPtr_(hwnd, #GWL_WNDPROC, @EditProc()))
SetWindowCallback(@WinProc())
EditorDisable(0, #True)

Repeat

 Event = WaitWindowEvent()
   
Until Event = #PB_Event_CloseWindow

Posted: **Wed Feb 10, 2010 7:21 pm**

KCC,

I might be missing the point of it but comment out the "ProcedureReturn 0" call here...

Code: Select all

  Case #WM_KEYDOWN, #WM_KEYUP
   
   ProcedureReturn 0

Again, perhaps it's in there for some other reason. I just looked quickly.

Posted: **Thu Feb 11, 2010 10:31 am**

Hello XOMBIE glad to talk to you

You have right, i don't know why i have take off it ??? :roll:
So i have add this two lines, and i have always the same problem

I can't use delete or backspace for delete character ?? :roll:

Code: Select all

Global ActiveEditor

Procedure EditorDisable(PbId, Value)

If Value
  
  ActiveEditor = #False
  SetGadgetAttribute(0, #PB_Editor_ReadOnly, #True)
  
Else
  
  ActiveEditor = #True
  ShowCaret_(GadgetID(0))
  SetGadgetAttribute(0, #PB_Editor_ReadOnly, #False)
EndIf

EndProcedure

Procedure EditProc(hwnd, msg, wparam, lparam)

oldproc = GetProp_(hwnd, "oldproc")

Select msg

  Case #WM_NCDESTROY
   
   If Not ActiveEditor
    RemoveProp_(hwnd, "oldproc")
   EndIf
   
  Case #WM_MOUSEMOVE
  
   If Not ActiveEditor
   
    If GetForegroundWindow_()<>WindowID(0)
     SetForegroundWindow_(WindowID(0))
    EndIf
    If GetActiveGadget()<>GetDlgCtrlID_(hwnd)
     SetActiveGadget(GetDlgCtrlID_(hwnd))
    EndIf
    
    HideCaret_(GadgetID(0))
    
   EndIf
   
  Case #WM_KEYDOWN, #WM_KEYUP
  
   ProcedureReturn 0
      
  Case #WM_RBUTTONDOWN
        
   If Not ActiveEditor
    MessageRequester("", "Hello PB, 'im active now !!")
    EditorDisable(0, #False)
   Else
    MessageRequester("", "Hello PB, 'im inactive now !!")
    EditorDisable(0, #True)
   EndIf
  
  Case #WM_KEYDOWN, #WM_KEYUP
   
   ProcedureReturn 0
   
EndSelect   
   
ProcedureReturn CallWindowProc_(oldproc, hwnd, msg, wparam, lparam)

EndProcedure

Procedure WinProc(hwnd, msg, wparam, lparam)

result = #PB_ProcessPureBasicEvents

If Not ActiveEditor

Select msg

  Case #WM_COMMAND
      
   If lparam = GadgetID(0)
     
    If wparam>>16 = #EN_SETFOCUS
     HideCaret_(GadgetID(0))
    EndIf 
     
   EndIf
   
  EndSelect
  
EndIf 

ProcedureReturn result

EndProcedure

OpenWindow(0, 0, 0, 322, 150, "EditorGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)  

hwnd = EditorGadget(0, 8, 8, 306, 133, #PB_Editor_ReadOnly) 
SetGadgetText(0,"Hello I'm an inactive editor gadget," + Chr(13) + "Right click To convert me in active editor !!!")
SetProp_(hwnd, "oldproc", SetWindowLongPtr_(hwnd, #GWL_WNDPROC, @EditProc()))
SetWindowCallback(@WinProc())
EditorDisable(0, #True)

Repeat

Event = WaitWindowEvent()
   
Until Event = #PB_Event_CloseWindow

Posted: **Thu Feb 11, 2010 4:59 pm**

Well, no. I meant if you comment out the line I mentioned then you will be able to use the backspace key.

Posted: **Thu Feb 11, 2010 5:47 pm**

Yeeeesss !!!!
You have right i'm a mule, that's works now

Master ZOMBIE wrote:I might be missing the point of .....

I have not understand what you say to me :roll:
I have read that i have missing the line

Code: Select all

Case #WM_KEYDOWN, #WM_KEYUP
      ProcedureReturn 0

So i have add a second time this two lines

If you see my code above, i have two time

Code: Select all

Case #WM_KEYDOWN, #WM_KEYUP
      ProcedureReturn 0

Thanks XOMBIE for your precious help

I wish you a very good day

Posted: **Thu Feb 11, 2010 6:12 pm**

Is it possible to add at the code of NETMAESTRO, the disable of highlight of text in the editorgadget ???

PureBasic Forums - English

EditorGadget receive first clic and hide cursor [Resolved]

EditorGadget receive first clic and hide cursor [Resolved]

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor

Re: EditorGadget receive first clic and hide cursor [Resolved]