PureBasic Forums - English

Code: Select all

;
; Receive the OpenDocument event on OSX
;

; Some required definitions
;
#eventNotHandledErr = -9874

#CoreEventClass = 'aevt'
#AEOpenDocuments = 'odoc'
 
#typeFSS = 'fss ' 
#typeAEList = 'list'
#typeFSRef = 'fsrf'
#keyDirectObject = '----'

#typeNull = 'null' 
#noErr = 0

Structure FSRef
  hidden.b[80]
EndStructure

Structure AEDesc
  desctiptorType.l
  dataHandle.l
EndStructure

; ProcedureCDLL is important, for the right calling convention (on x86) and
; the correct callback behavior (therefore the DLL part)
;
ProcedureCDLL OpenDocument(*appleEvt, *reply, refcon)
 
  ; extract the event parameters
  If AECreateDesc_(#typeNull, 0, 0, @documents.AEDesc) = #noErr
    If AEGetParamDesc_(*appleEvt, #keyDirectObject, #typeAEList, @documents)  = #noErr
      If AECountItems_(@documents, @n) = 0

        *Buffer = AllocateMemory(1000)
        If *Buffer

          ; There can be multiple files sent
          For i = 1 To n
            If AEGetNthPtr_(@documents, i, #typeFSRef, @keyWd, @typeCd, @fileRef.FSRef, SizeOf(FSRef), @actualSize) = #noErr
              If FSRefMakePath_(@fileRef, *Buffer, 1000) = #noErr

                File$ = PeekS(*Buffer, -1, #PB_Ascii)
                ;
                ; If you want to accepte directories too, then change this
                ;
                If FileSize(File$) >= 0 
                  ;
                  ; Here you have the filename to open
                  ;
                  AddGadgetItem(0, -1, File$)
                                   
                EndIf
                
              EndIf 
            EndIf
          Next i
        
          FreeMemory(*Buffer)
        EndIf
        
      EndIf
    EndIf
    AEDisposeDesc_(@documents)
  EndIf
 
EndProcedure



If OpenWindow(0, 0, 0, 600, 300, "Open Document test", #PB_Window_ScreenCentered|#PB_Window_SystemMenu)
  ListViewGadget(0, 10, 10, 580, 280)
  
  ; Call this before processing the first window events, else you may miss the open event!
  ;
  If AEInstallEventHandler_(#CoreEventClass, #AEOpenDocuments, @OpenDocument(), 0, 0) <> #NoErr
    AddGadgetItem(0, -1, "cannot install event handler!")
  EndIf
  
  Repeat
  Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

End

Code: Select all

  <key>CFBundleDocumentTypes</key>
  <array>
    <dict>
      <key>CFBundleTypeExtensions</key>
      <array>
        <string>pb</string>
        <string>pbi</string>
      </array>
      <key>CFBundleTypeIconFile</key>
      <string>FileIcon.icns</string>
      <key>CFBundleTypeName</key>
      <string>PureBasic Sourcecode</string>
      <key>CFBundleTypeRole</key>
      <string>Editor</string>
    </dict>
  </array>

Code: Select all

	<key>CFBundleDocumentTypes</key>
	<array>
		<dict>
			<key>CFBundleTypeExtensions</key>
			<array>
				<string>*</string>
			</array>
			<key>CFBundleTypeRole</key>
			<string>Editor</string>
		</dict>
  </array>

Code: Select all

PB_Gadget_SetOpenFinderFiles

Code: Select all

;Fred's OpenDoc (early in code)
            ImportC ""
                PB_Gadget_SetOpenFinderFiles(Callback)
            EndImport
            
            ;Enumeration CustomEvent #PB_Event_FirstCustomValue
              #MyEvent_OpenFiles=1000
            ;EndEnumeration
            
            Global FileIn$
            
            IsGadget(0) ; Ensures the gadget lib is linked as this command is in it
            ProcedureC OpenFinderFilesCallback(*Utf8Files)
                Protected filecnt,filesin$,filepath$,filename$
                filesin$ = PeekS(*Utf8Files, -1, #PB_UTF8) ; Each file is separated by a 'tab' 
                ;MessageRequester("Raw Load...",filesin$)
                If Len(filesin$) ; Here you have the filename to open
                    filein$=StringField(filesin$,1,Chr(9)) 
                EndIf
                PostEvent(#MyEvent_OpenFiles)
            EndProcedure
            PB_Gadget_SetOpenFinderFiles(@OpenFinderFilesCallback()) ; should be put very early in the code, before any event loop
            ;end of Fred's opendoc

Code: Select all

Repeat
    event = WaitWindowEvent()
    Select event
    Case #MyEvent_OpenFiles
        FilePath=GetPathPart(filein$)
        FLD$=GetFilePart(filein$)
        LoadFile(FLD$,"")
        DefaultWnd()
    EndSelect
ForEver