How to convert this from C to PB?

[Mistrel]

I'm trying to convert this bit of C into PB to return a floating point number to DarkBasic from my dll but I can't seem to make it work. I don't understand what's actually happening in the C function. Would someone explain this to me?

Code: Select all

MYCOMMAND DWORD ReturnAFloat(void)
 {
	float fValue = 42.05f;
	return *(DWORD*)&fValue;
 }

[citystate]

I think it's the equivalent of

Code: Select all

Procedure.f ReturnAFloat()
  fValue.f = 42.05
  ProcedureReturn fValue
EndProcedure

[Maxus]

Maybe this code rule.

Code: Select all

Structure AFloat
  StructureUnion
    F.F
    L.L
  EndStructureUnion
EndStructure

Procedure.l ReturnAFloat() 
  fValue.AFloat\F = 42.05 
  ProcedureReturn fValue\L
EndProcedure

[pdwyer]

my take on it

Code: Select all

Procedure.l ReturnAFloat() 
    fValue.f = 42.05 
    ProcedureReturn @fValue 
EndProcedure

Maybe you'd need to declare float as static so that it didn't fall out of scope when the proc exited

[Mistrel]

Maxus it worked! Thank you! But how?

Thanks to everyone else who posted some code. All of those were variations I tried too.

[Maxus]

Maxus it worked! Thank you! But how?

Thanks to everyone else who posted some code. All of those were variations I tried too.

What is how?

The whole secret lies in the structure that we declare above.

Code: Select all

StructureUnion 
  F.F 
  L.F 
EndStructureUnion 

F.F and L.L invoked in this case at the same station memory.
When you write F.F = 42.05 it can be the opposite numbers through L.L

[pdwyer]

I see, kind of like type spoofing so that you can return 4 bytes as a dword but actually there's a 4 byte float in there.

Wonder what the point of doing that is?

[Kaeru Gaman]

> Wonder what the point of doing that is?

additionally, there is alwys the same Value used...

instead of calling this procedure, I could just put a 0x42283333 into the C-code..

is the author trying to hide some key by this action?

but the literal float will appear as a 42283333 in a hex-viewer, too...

[pdwyer]

Okay, searching around on the net it seems to be a darkbasic workaround where by their DLL can't return floats so they need to sort of encpsulate it to get around a limitation of the language

[Fluid Byte]

... a darkbasic workaround where by their DLL can't return floats so they need to sort of encpsulate it to get around a limitation of the language

[Mistrel]

I see, kind of like type spoofing so that you can return 4 bytes as a dword but actually there's a 4 byte float in there.

Wonder what the point of doing that is?

This really turns my head around. The code returns a float as a long without type-casting. That's kind of neat.

[pdwyer]

hmmmm,

Well, my name is four letters so I could set a longs bytes to asc(P) asc(a) asc(u) asc(l) and return it as a long.

Or I could return it as a string since that's what it is...

But noooo, I will not make it that easy for them

Why publish a simple API when you can publish a difficult one with just a little extra effort

[Kaeru Gaman]

Code: Select all

Structure Essense
  StructureUnion
    Name.s{4}
    Esse.f
  EndStructureUnion
EndStructure

Define Test.Essense

Test\Name = "Paul"

Debug Test\Esse 

[GedB]

The following includes an alternative approach which uses PeekL instead of a StructureUnion. It does the cast in a single line, just like the C code.

Code: Select all

;-Testing Methods

TestsRun.l = 0
TestsPassed.l = 0
TestsFailed. l = 0

Procedure AssertEqualsL(expected.l, actual.l)
  Shared TestsRun
  Shared TestsPassed
  Shared TestsFailed
  
  TestsRun+1
  
  If actual = expected
    TestsPassed+1
  Else
    TestsFailed+1
    Debug "Assertion Failed: expected " + Str(expected) + " but received " + Str(actual)
  EndIf
EndProcedure

Procedure TestReport()
  Shared TestsRun
  Shared TestsPassed
  Shared TestsFailed

  Debug "----------------------------------------------------------------------------------------"
  Debug "Test Report.  Run ("+Str(TestsRun)+")  Passed ("+Str(TestsPassed)+")  Failed ("+Str(TestsFailed)+")"
  Debug "----------------------------------------------------------------------------------------"
  
EndProcedure

;-Solution I using Structured Union

Structure AFloat
  StructureUnion
    F.F
    L.L
  EndStructureUnion
EndStructure

Procedure.l ReturnAFloatI(value.f)
  fValue.AFloat\F = value
  ProcedureReturn fValue\L
EndProcedure 

;-Solution II using PeekL

Procedure.l ReturnAFloatII(value.f)
  ProcedureReturn PeekL(@value)
EndProcedure 


;-Test Soluction I

AssertEqualsL( ReturnAFloatI(42.03) , 1109925560) 
AssertEqualsL( ReturnAFloatI(-89.3333334) , -1028478293)
AssertEqualsL( ReturnAFloatI(82489.45) , 1201740986)

;-Test Soluction II

AssertEqualsL( ReturnAFloatII(42.03) , 1109925560) 
AssertEqualsL( ReturnAFloatII(-89.3333334) , -1028478293)
AssertEqualsL( ReturnAFloatII(82489.45) , 1201740986)


TestReport()

[pdwyer]

Code: Select all

Structure Essense
  StructureUnion
    Name.s{4}
    Esse.f
  EndStructureUnion
EndStructure

Define Test.Essense

Test\Name = "Paul"

Debug Test\Esse 

Too much free time!