PureBasic Forums - English

Code: Select all

;******************************************************************************************
;'egrid' editable grid control. By Stephen Rodriguez.
;******************************************************************************************
;This example shows how to use a simple CellCallback function to enable one-click editing.


XIncludeFile "egrid.pb"


;The following simple CellCallback function allows us to enable one-click editing.
Procedure.l MyCellCallBack(egrid, uMsg, *cellinfo.egridCellInfo)
  Protected result
    Select uMsg
      Case #egrid_SelectCell
;Check whether the cell was selected using the mouse.
        If *cellinfo\param=#egrid_leftClick
          egrid_HideEdit(egrid) ;Hides the selection border.
          egrid_SelectCell(egrid, *cellinfo\row, *cellinfo\column, #True) ;Selects the cell.
;The '#True' value in the above line causes the selected cell to enter 'edit mode'.
          result=#False ;No point getting the Egrid to select the cell as well.
        Else
          result=#True
        EndIf
      Default
        result=#True
    EndSelect
  ProcedureReturn result
EndProcedure
;******************************************************************************************

;******************************************************************************************


;*************************************WINDOW + GADGET LIST*********************************
If OpenWindow(0,0,0,640,300,"One-click edit.",#PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_Maximize |#PB_Window_ScreenCentered) And CreateGadgetList(WindowID(0))
  ;******************************************************************************************
  
  
  ;********************************************EGRID*****************************************
  ;Create an egrid with resizable columns.
  egrid_CreateGrid(1, WindowWidth(0)/4, WindowHeight(0)/8, WindowWidth(0)/2, WindowHeight(0)/2,21,#PB_ListIcon_GridLines, #egrid_ResizeColumnsTrue)
  ;******************************************************************************************
  
  ;**********************************SET CELLCALLBACK FUNCTION*******************************
  ;Set the callback early to avoid massive flickering when populating the egrid with initial data.
  egrid_CreateCellCallback(1, @MyCellCallBack())
  ;******************************************************************************************

  ;***************************************ADD DATA TO EGRID**********************************
  For b=1 To 50            ;50 columns. NOTE the column index begins at 1!
    AddGadgetColumn(1,b,"Col " + Str(b),60)
  Next
  For b=0 To 9            ; Add 10 rows.
    AddGadgetItem(1,-1,"") ;The "" is for the zero column which is always invisible in an egrid.
  Next
  For i = 0 To 9
    For j = 1 To 50
      SetGadgetItemText(1,i,"(" + Str(i) + ", "+Str(j) + ")",j)
    Next j
  Next i            
  ;NOTE that the zero column of an egrid is blanked out, hence the "" in the above AddGadgetItem() command.
  ;******************************************************************************************
  
  
  ;*****************************************EVENT LOOP***************************************
  Repeat
    EventID = WaitWindowEvent()
  Until EventID = #PB_Event_CloseWindow
  
EndIf
  
End
;******************************************************************************************