PureBasic Forums - English

Posted: **Wed Mar 31, 2004 10:40 am**

Can I copy highlighted text from WebGadget by Ctrl+C?

I tried to do it in WebBrowser (from Examples)
and I had to click right mouse button and select copy
to copy the highlighted text.

Posted: **Wed Mar 31, 2004 11:38 am**

I don't think it works with Ctrl-c.. (at least I didn't get it to work)..

I don't know if it is possible by some API calls though..
You might want to check that.. or maybe someone else knows!??

Posted: **Wed Mar 31, 2004 12:24 pm**

The WebGadget has a IWebBrowser2 Interface, which lets you do lots of stuff
from your code. Like copying the selected content to the clipboard.

So just add a keyboardshortcut to the window, and do that stuff when you
get the event.

Example:

Code: Select all

; Constants for the ExecWB() method of IWebBrowser2

Enumeration 1
  #OLECMDID_OPEN         
  #OLECMDID_NEW       
  #OLECMDID_SAVE         
  #OLECMDID_SAVEAS           
  #OLECMDID_SAVECOPYAS   
  #OLECMDID_PRINT       
  #OLECMDID_PRINTPREVIEW       
  #OLECMDID_PAGESETUP       
  #OLECMDID_SPELL           
  #OLECMDID_PROPERTIES 
  #OLECMDID_CUT         
  #OLECMDID_COPY       
  #OLECMDID_PASTE           
  #OLECMDID_PASTESPECIAL   
  #OLECMDID_UNDO           
  #OLECMDID_REDO         
  #OLECMDID_SELECTALL       
  #OLECMDID_CLEARSELECTION
  #OLECMDID_ZOOM           
  #OLECMDID_GETZOOMRANGE     
  #OLECMDID_UPDATECOMMANDS 
  #OLECMDID_REFRESH           
  #OLECMDID_STOP             
  #OLECMDID_HIDETOOLBARS     
  #OLECMDID_SETPROGRESSMAX   
  #OLECMDID_SETPROGRESSPOS 
  #OLECMDID_SETPROGRESSTEXT   
  #OLECMDID_SETTITLE         
  #OLECMDID_SETDOWNLOADSTATE 
  #OLECMDID_STOPDOWNLOAD     
EndEnumeration

Enumeration 0
  #OLECMDEXECOPT_DODEFAULT     
  #OLECMDEXECOPT_PROMPTUSER       
  #OLECMDEXECOPT_DONTPROMPTUSER   
  #OLECMDEXECOPT_SHOWHELP       
EndEnumeration

; -----------------------------------------------------

#WebGadget = 1
#Shortcut = 1

OpenWindow(0, 0, 0, 800, 800, #PB_Window_Screencentered|#PB_Window_SystemMenu, "WebBrowser")
CreateGadgetList(WindowID())

AddKeyboardShortcut(0, #PB_Shortcut_C | #PB_Shortcut_Control, #Shortcut)

WebGadget(#WebGadget, 10, 40, 780, 750, "www.purebasic.com")

; get the WebGadget Interface
;
WebObject.IWebBrowser2 = GetWindowLong_(GadgetID(#WebGadget), #GWL_USERDATA)

Repeat
  Event = WaitWindowEvent()
  If Event = #PB_EventMenu And EventMenuID() = #Shortcut ; Shortcuts are Menu Events
   
    ; Copy content to clipboard
   
    WebObject\ExecWB(#OLECMDID_COPY, #OLECMDEXECOPT_DONTPROMPTUSER, 0, 0)   
   
   
  EndIf
Until Event = #PB_EventCLoseWindow

End

For more information on this Interface, search for "IWebBrowser2" here
in the forum.

Timo

Posted: **Wed Mar 31, 2004 2:03 pm**

(Thanks, thanks) * 100
I tried. It works!

Posted: **Thu Apr 01, 2004 7:23 pm**

Do you know how to make it stop pop-ups?

PureBasic Forums - English

Coping from WebGadget

Coping from WebGadget