PureBasic Forums - English

Code: Select all

SendMessage_(WindowID(#MainWindow), #WM_SETICON, 0, ImageID(PureTrisIco))

Code: Select all

CompilerIf #PB_Compiler_OS = #PB_OS_Linux
UseGIFImageDecoder()
DataSection
		IconTitle:
		IncludeBinary "icon.gif"
		IconTitleend:
EndDataSection
CatchImage(0, ?IconTitle)
CompilerEndIf


hGUI = OpenWindow(#Window, 0, 0, 111, 111, "example",  #PB_Window_SystemMenu)
If hGUI
	CompilerIf #PB_Compiler_OS = #PB_OS_Linux
		gtk_window_set_icon_(hGUI, ImageID(0)) ; assign an icon to the title
	CompilerEndIf

Code: Select all

Global  PathLang$

; Specifies the language of the OS
CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Windows
		Global UserIntLang, *Lang
		If OpenLibrary(0, "kernel32.dll")
			*Lang = GetFunction(0, "GetUserDefaultUILanguage")
			If *Lang
				UserIntLang = CallFunctionFast(*Lang)
			EndIf
			CloseLibrary(0)
		EndIf
    CompilerCase #PB_OS_Linux
		Global UserIntLang$
		If ExamineEnvironmentVariables()
		    While NextEnvironmentVariable()
		    	If Left(EnvironmentVariableName(), 4) = "LANG"
; 		    		LANG=ru_RU.UTF-8
; 		    		LANGUAGE=ru
					UserIntLang$ = Left(EnvironmentVariableValue(), 2)
					Break
				EndIf
		    Wend
		EndIf
CompilerEndSelect
; Debug UserIntLang$

#CountStrLang = 2 ; number of translation lines and corresponding array
Global Dim Lng.s(#CountStrLang)
; Interface strings even if the language file is not found (default)
Lng(1) = "Example"
Lng(2) = "Program"


; you can add 2 languages, your own and English, so as not to depend on external files.
CompilerSelect #PB_Compiler_OS
	CompilerCase #PB_OS_Windows
		If UserIntLang = 1049
    CompilerCase #PB_OS_Linux
		If UserIntLang$ = "ru"
CompilerEndSelect

	Lng(1) = "Пример"
	Lng(2) = "Программа"
EndIf

; defines the paths to the language file. In this example, one file is used as the current GUI language
CompilerSelect #PB_Compiler_OS
	CompilerCase #PB_OS_Windows
; 		the file name is the same As the program name "MyProg_Lang.txt" (if compiled as MyProg.exe)
; 		PathLang$ = GetPathPart(ProgramFilename()) + GetFilePart(ProgramFilename(), #PB_FileSystem_NoExtension) + "_Lang.txt"
; 		file name by language number, for example 1049.txt, then you can have several languages ​​included with the program
		PathLang$ = GetPathPart(ProgramFilename()) + Str(UserIntLang) + ".txt"
    CompilerCase #PB_OS_Linux
		PathLang$ ="/usr/share/locale/" + UserIntLang$ + "/LC_MESSAGES/" + GetFilePart(ProgramFilename(), #PB_FileSystem_NoExtension) + ".txt"
CompilerEndSelect
; Debug PathLang$

; If the language file exists, use it. Each line contains one of the translations
If FileSize(PathLang$) > 100
	
	If ReadFile(0, PathLang$)
		i=0
	    While Eof(0) = 0        ; The loop is executed until the end of the file is reached. (Eof = 'End of file')
	    	tmp$ =  ReadString(0)
; 	    	If Left(tmp$, 1) = ";" ; skip commented lines
; 	    		Continue
; 	    	EndIf
	    	tmp$ = ReplaceString(tmp$ , #CR$ , "") ; correction if in Windows
	    	If Asc(tmp$) And Left(tmp$, 1) <> ";" ; skip commented lines
	    		i+1
	    		If i > #CountStrLang ; the Lng() array is already set, but if there are more lines than necessary, then we do not allow the excess
	    			Break
	    		EndIf
	    		Lng(i) = tmp$
	    	Else
	    		Continue
	    	EndIf
	    Wend
	    CloseFile(0)
	EndIf
; Else
; 	SaveFile_Buff(PathLang$, ?LangFile, ?LangFileend - ?LangFile) ; create an example language file
EndIf
; End => Language detection


If OpenWindow(0, 0, 0, 220, 100, Lng(2), #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
	ButtonGadget (1, 10, 60, 200, 30, Lng(1))

	Repeat
		Select WaitWindowEvent()
			Case #PB_Event_Gadget
				Select EventGadget()
					Case 1
						CloseWindow(0)
						End
				EndSelect
			Case #PB_Event_CloseWindow
				CloseWindow(0)
				End
		EndSelect
	ForEver
EndIf