PureBasic Forums - English

Code: Select all

InitEngine3D()
InitSprite()
InitKeyboard()

DeclareModule _PBTeam
	
	Structure _MyData
		bg.i
		fnt.i
		sw.i
		sh.i
		win.i
		tex.i
		cam.i
		light.i
		node.i
	EndStructure
	
	Structure _MyPar
		id.i
		x.i
		y.i
		z.i
		mat.i
	EndStructure
	
	Global md._MyData
	Global Dim par._MyPar(1)
	Global beam.i
	
	Declare MakeMyScreen()
	Declare MakeMyTex()
	Declare MakeMyPar()
	Declare MakeMyFnt()
	
EndDeclareModule

Module _PBTeam
	
	Procedure MakeMyScreen()
		ExamineDesktops()
		md\sw = DesktopWidth(0)
		md\sh = DesktopHeight(0)
		md\win = OpenWindow(#PB_Any, 0, 0, md\sw, md\sh,"Thank you", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
		OpenWindowedScreen(WindowID(md\win), 0, 0, md\sw, md\sh, 0, 0, 0, #PB_Screen_SmartSynchronization)
		md\cam = CreateCamera(#PB_Any, 0, 0, 100, 100)
		MoveCamera(md\cam, 0, 0, 100, #PB_Absolute)
		md\light = CreateLight(#PB_Any, $FFCCCC, 0, 10, 0)
	EndProcedure
	
	Procedure MakeMyTex()
		md\tex = CreateTexture(#PB_Any, 9, 9) 
		StartDrawing(TextureOutput(md\tex))
		DrawingMode(#PB_2DDrawing_Gradient) 
		FrontColor($1415F2)
    BackColor($14E8E9)
    CircularGradient(3, 3, 3) 
    Circle(4, 4, 4)
		StopDrawing()
	EndProcedure
	
	Procedure MakeMyFnt()
		Protected fnt.i
		md\fnt = CreateSprite(#PB_Any, 600,60,#PB_Sprite_AlphaBlending)
		fnt = LoadFont(#PB_Any, "Arial", 48)
		StartDrawing(SpriteOutput(md\fnt))
		DrawingFont(FontID(fnt))
		DrawText(0, 0, "THANK YOU TEAM!", $D18D64)
		StopDrawing()
		TransparentSpriteColor(md\fnt, 0)
		FreeFont(fnt)
	EndProcedure
	
	Procedure MakeMyPar()
		With par(0)
			\id = CreateParticleEmitter(#PB_Any, 100, 100, 300, #PB_Particle_Point)
			\mat = CreateMaterial(#PB_Any, TextureID(md\tex))
			DisableMaterialLighting(\mat, 1)
			MaterialBlendingMode(\mat, #PB_Material_Add)
			SetMaterialColor(\mat, #PB_Material_SelfIlluminationColor, $FF88EE)
	    MoveParticleEmitter(\id, -20, 0, 100, #PB_Absolute)
	    ParticleMaterial(\id, MaterialID(\mat))
	    ParticleEmissionRate(\id,300)
	    ParticleTimeToLive(\id, 2.2, 3.8)
	    ParticleSize(\id, 0.5, 0.5)
	    ParticleVelocity(\id, 0.2, 0.8)
	    ParticleEmitterDirection(\id, 0 , 0 , 1)
	  EndWith
	EndProcedure
EndModule


_PBTeam::MakeMyScreen()
_PBTeam::MakeMyTex()
_PBTeam::MakeMyPar()
_PBTeam::MakeMyFnt()

Repeat
	
	event = WindowEvent()
	
	RenderWorld()
	
	DisplayTransparentSprite(_PBTeam::md\fnt, (_PBTeam::md\sw / 2) - 300, _PBTeam::md\sh / 2)
	
	FlipBuffers()
	
	ExamineKeyboard()
	
Until KeyboardPushed(#PB_Key_Escape) Or event = #PB_Event_CloseWindow