PureBasic Forums - English

Code: Select all

Procedure.s x_propercase(s.s) 
  Protected *p.l, f.l, b.l
  ;
  ; *** make all lowercase except for the first chars of each word
  ;
  *p = @s 
  f = 1 
  b = PeekB(*p) 
  While b <> 0 
    If b = 32 
      f = 1 
    ElseIf f = 1 And b >= 97 And b<=122 
      PokeB(*p,b & $DF) 
      f = 0 
    ElseIf f = 0 And b >= 65 And b <= 90 
      PokeB(*p,b | $20) 
    Else 
      f = 0 
    EndIf 
    *p = *p+1
    b = PeekB(*p) 
  Wend 
  ProcedureReturn s 
EndProcedure 

Code: Select all

;Note that either you have to change the Compiler/Compiler Options to allow
;Inline ASM Support for this code to compile correctly.

;Note that statements in ASM (Assembler) that refer to line lables have a "l_"
;(small L with underscore) added in front when referenced by an ASM instruction,
;and the characters must be in lower case.  The actual line labels can be in
;mixed case, as illustrated in this code.


Procedure.s x_propercase(s.s)  ;convert all groups of letters to Ucase form
    MOV eax, [esp]              ;string pointer on stack (pointed to by esp) into EAX reg      
    XOR dl, dl                  ;clear garbage for DL
  Cycle:                        ;return point to repeat for each character in string   
    MOV dh,dl                   ;save the last processed char in DH 
    MOV dl,[eax]                ;get the next character to process in DL
    TEST dl,dl                  ;set flags against same register to check value           
    JZ l_endstring              ;character is zero (Null), so exit process
    AND dx,$DFDF                ;get rid of lower case flag in DH and DL registers
    CMP dl, 'Z'                 ;compare the value in DL with 90 (ascii code for 'Z')  
    JA l_not_alpha              ;if above 'Z', it is not an Alpha character
    CMP dl, 'A'                 ;compare the value in DL with 65 (ascii code for 'A')
    JB l_not_alpha              ;if below 'A', it is not an Alpha character
    CMP dh, 'A'                 ;compare last character with 65 (ascii code for 'A')
    JB l_high                   ;if below 'A', we keep the current letter in UPPER case  
    CMP dh, 'Z'                 ;compare last character with 90 (ascii code for 'Z')
    JA l_high                   ;if above 'Z', we keep the current letter in UPPER case  
  Low:                          ;otherwise, we have two or more alpha characters in a row
    OR dl, $20                  ;and we force the current letter to lower case  
  High:                         ;and this is where the UPPER case letters merge in again  
    MOV [eax], dl               ;so that we can store the correct case letter back
  Not_Alpha::                   ;or we skipped if current character not an Alpha character
    INC eax                     ;we increment the string pointer for s.s to next character 
    JMP l_cycle                 ;and jump back to repeat for the next character  
  EndString: 
  ProcedureReturn s           ;we make sure the changes are returned. 
EndProcedure 

OpenConsole()
ConsoleColor(15,1)
PrintN(x_propercase("tHIS iS a tESt of pROper *C*a(se)s."))
While Inkey()=""
Wend

Code: Select all

structure TCharacter
  c.c[0]
endstructure

procedure.s ProperCase(text.s)
  protected *ptr.TCharacter
  protected.l c, f, i, length
  
  *ptr = @text
  length = MemoryStringLength(*ptr) - 1
  
  f = 1
  for i = 0 to length
    if *ptr\c[i] = 32
      f = 1
    elseif f = 1 and *ptr\c[i] >= 97 and *ptr\c[i] <= 122
      *ptr\c[i] = (*ptr\c[i] & $DF)
      f = 0
    elseif f = 0 and *ptr\c[i] >= 65 and *ptr\c[i] <= 90
      *ptr\c[i] = (*ptr\c[i] | $20)
    else
      f = 0
    endif
  next
  
  procedurereturn text
endprocedure

Code: Select all

Structure TCharacter
  c.c[0]
EndStructure

Procedure.s ProperCase(text.s)
  Protected *ptr.TCharacter
  Protected.l c, f, i, length
  
  *ptr = @text
  length = MemoryStringLength(*ptr) - 1
  
  f = 1
  For i = 0 To length
    If *ptr\c[i] = 32
      f = 1
    ElseIf f = 1 
      If *ptr\c[i] >= 97 And *ptr\c[i] <= 122
        *ptr\c[i] = (*ptr\c[i] & $DF)
      ElseIf *ptr\c[i] >= 127
        *ptr\c[i] = CharUpper_(*ptr\c[i])
      EndIf  
      f = 0
    ElseIf f = 0 
      If *ptr\c[i] >= 65 And *ptr\c[i] <= 90
        *ptr\c[i] = (*ptr\c[i] | $20)
      ElseIf *ptr\c[i] >= 127
        *ptr\c[i] = CharLower_(*ptr\c[i])
      EndIf  
    Else
      f = 0
    EndIf
  Next
  
  ProcedureReturn text
EndProcedure

Debug ProperCase("maria ágÁta")

Code: Select all

Procedure$ SF_TitleCase(s$)
  ; skywalk modified from luis, Little John
  ;   http://www.forums.purebasic.com/english/viewtopic.php?p=370491&sid=c211be8dff9e7412095071dd1feee541#p370491
  ; Capitalize 1st letter of each word found.
  ; Proper case capitalizes 1st letter of 1st word.
  ; Words defined with the following delimiters:
  ;   space , ! " # $ % & ' ( ) * + - . /
  ;   tab
  ;   : ; < = > ? @
  ;   [ \ ] ^ _ `
  Protected *p.Character = @s$
  Protected.i newWord = 1
  While *p\c
    If newWord
      *p\c = Asc(UCase(Chr(*p\c)))
      newWord = 0
    Else
      *p\c = Asc(LCase(Chr(*p\c)))
    EndIf
    If *p\c > 31 And *p\c < 48      ; space , ! " # $ % & ' ( ) * + - . /
      newWord = 1
    ElseIf *p\c = #TAB
      newWord = 2
    ElseIf *p\c > 57 And *p\c < 65  ; : ; < = > ? @
      newWord = 3
    ElseIf *p\c > 90 And *p\c < 97  ; [ \ ] ^ _ `
      newWord = 4
    EndIf
    *p + SizeOf(Character)
  Wend
  ProcedureReturn s$
EndProcedure
Debug SF_TitleCase("  hmm, w::w w[we are one]   we,  went to neW,"+Chr(9)+"yorK toDay. to buy       sausages  ")