PureBasic Forums - English

Code: Select all

;-Run this bit of code in a separate progam to create the encrupted key.

UseSHA2Fingerprint()

Debug StringFingerprint("G4112h78ab", #PB_Cipher_SHA2)

;-Use this in your actual program so a user can activate their software.

Activation.a = 0
BS.s = "048"

If OpenWindow(0, 0, 0, 310, 40, "Verify Key", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
 
  StringGadget(0, 10, 10, 200, 20, "")
  ButtonGadget(1, 210, 10, 100, 20, "Activate")
  Tri.s = "3"
  
    Repeat
     
      Event = WaitWindowEvent()
        Select Event
          Case #PB_Event_Gadget
            Select EventGadget()
              Case 1
                
                String1.s = StringFingerprint(GetGadgetText(0), #PB_Cipher_SHA2)
                String2.s = BS + Tri + Tri + Str(Val(Tri) * Val(Tri)) + "c50de4e5f29f5c91c7eba9c9a0a3e294fea0fa684193664f21f6c0a78c"
                If Activation = 0 ;-You will have to figure out how to store Activation if it equals 1 on your own.
                  If CompareMemoryString(@String2,@String1)
                    Debug "Incorrect Key"
                  Else
                    Debug "Yahoo!"
                  EndIf
                EndIf
            EndSelect
        EndSelect 
     
    Until Event = #PB_Event_CloseWindow
EndIf

Code: Select all

EnableExplicit

Procedure ValidateDate()
  Protected dir
  Protected date, mdate
  
  ;Get the date of the all entries in the Temp-Folder
  dir = ExamineDirectory(#PB_Any, GetTemporaryDirectory(), "*.*")
  If dir
    While NextDirectoryEntry(dir)
      mdate = DirectoryEntryDate(dir, #PB_Date_Modified)
      If mdate > date
        date = mdate
      EndIf
      mdate = DirectoryEntryDate(dir, #PB_Date_Accessed)
      If mdate > date
        date = mdate
      EndIf
      mdate = DirectoryEntryDate(dir, #PB_Date_Created)
      If mdate > date
        date = mdate
      EndIf
    Wend
    FinishDirectory(dir)
  EndIf
  
  ; current date older than Temp-Files?
  mdate = date - Date()
  If mdate > 60*60*24 ; little security-gab
    ProcedureReturn #Null
  EndIf
  
  ; older than compile-Time?
  If Date() < #PB_Compiler_Date 
    ProcedureReturn #Null
  EndIf
  
  ; it seems, that everything is all right
  
  ProcedureReturn Date()
EndProcedure

Structure License_File
  Serial.s
  UserName.s
  StartDate.l
  EndDate.l
EndStructure
 
 ;Generate Serial
 ;   for guid-code see https://www.purebasic.fr/english/viewtopic.php?f=12&t=74015
 ;   here is only the windows-code
Structure UUID
   data1.l
   data2.w
   data3.w
   data4.b[8]
 EndStructure
 Procedure.s GenerateSerial()
   Protected.uuid guid
   Protected.i pst
   Protected.s st
   
   If UuidCreate_(guid) = #RPC_S_OK
     If UuidToString_(guid, @pst) = #RPC_S_OK
       If pst
         st = PeekS(pst, -1, #PB_Unicode)
         RpcStringFree_(@pst)
       EndIf
     EndIf 
   EndIf
   
   ProcedureReturn st
 EndProcedure
 
 Procedure CreateLicenseFile(filename.s, *key, Name.s, Serial.s, startDate.l, endDate.l)
   
   Protected.License_File license_Data  
   
   ;Generate License-Structure
   license_Data\Serial = Serial
   license_Data\UserName = Name
   license_Data\StartDate = startDate
   license_Data\EndDate = endDate
   
   ;Transfer into json and generate a string from the structure
   Protected json, composed.s
   json = CreateJSON(#PB_Any)
   If json = 0
     ProcedureReturn #False
   EndIf
   InsertJSONStructure( JSONValue(json), license_Data, License_File)
   ComposeJSON(json)
   composed.s = ComposeJSON(json)
   
   ;encrypt structure
   Protected ByteLen = StringByteLength( composed + "*" ) ; "*" = Null-terminator
   Protected *out = AllocateMemory(ByteLen)
   If *out = #Null 
     ProcedureReturn #False
   EndIf
   AESEncoder(@composed, *out, ByteLen, *key, 256, #Null, #PB_Cipher_ECB)
   
   ;savefile
   Protected fout
   fout = CreateFile(#PB_Any,filename)
   If Not fout
     FreeMemory(*out)
     ProcedureReturn #False
   EndIf
   WriteData(fout, *out, ByteLen)
   CloseFile(fout)
   
   FreeMemory(*out)
   
   ProcedureReturn #True
   
 EndProcedure
 
 Procedure OpenLicenseFile(filename.s, *key, *ret.License_File)
   
   ; load file
   Protected fin
   Protected ByteLen
   Protected *in, *out
   fin = ReadFile(#PB_Any, filename)
   If Not fin 
     ProcedureReturn #False
   EndIf
   ByteLen = Lof(fin)
   *in = AllocateMemory(ByteLen)
   If *in = #Null
     CloseFile(fin)
     ProcedureReturn #False
   EndIf
   *out = AllocateMemory(ByteLen)
   If *out = #Null
     FreeMemory(*in)
     CloseFile(fin)
     ProcedureReturn #False
   EndIf
   ReadData(fin, *in, ByteLen)
   CloseFile(fin)
      
   ; decode
   AESDecoder(*in, *out, ByteLen, *key, 256, #Null, #PB_Cipher_ECB)
   FreeMemory(*in)
   Protected.s str = PeekS(*out,ByteLen)
   FreeMemory(*out)
   
   ; Create JSON
   Protected json = ParseJSON(#PB_Any,str)
   If Not json
     ProcedureReturn #False
   EndIf
   ExtractJSONStructure(JSONValue(json),*ret, License_File)   
   
 EndProcedure
 
 ;we create a license-file
 CreateLicenseFile("demo.lic", ?key, "Otto", GenerateSerial(), Date(), Date()+10000)
 
 ; now we read it
 Define.License_File license
 OpenLicenseFile("demo.lic", ?key, license)
 Debug "User:"+license\UserName
 Debug "Serial:"+license\Serial
 Debug "Start:"+FormatDate("%dd.%mm.%yyyy %hh:%ii:%ss", license\StartDate)
 Debug "End:"+FormatDate("%dd.%mm.%yyyy %hh:%ii:%ss", license\EndDate)
 
 ; check if the date is valid
 ; additional-check: Store the current date when the programms quits and check on start if the date is newer than the quit-date
 Define date = ValidateDate()
 If date >= license\StartDate And date <= license\EndDate
   Debug "Date is valid!"
 Else
   Debug "-- rejected - go to demo-mode"
 EndIf
 
 
 
  DataSection
    Key:; 256-bit-key - should be changed
    Data.b $06, $a9, $21, $40, $36, $b8, $a1, $5b, $51, $2e, $03, $d5, $34, $12, $00, $06
    Data.b $06, $a9, $21, $40, $36, $b8, $a1, $5b, $51, $2e, $03, $d5, $34, $12, $00, $06
  EndDataSection