PureBasic Forums - English

Code: Select all

DisableDebugger
#X=400:#Y=300
#Dampening=0.995 ;change this value to make the wave last longer (closer to 1)

Dim Buffer.f(#X*2-1,#Y-1)

If OpenWindow(0, 0, 0,#X, #Y, "2D Waves", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  CanvasGadget(0, 0, 0, #X, #Y, #PB_Canvas_Container)  
  ButtonGadget(1, 10, 10, 80, 30, "Clean up")
  CloseGadgetList()
  AddWindowTimer(0, 0, 32)
  
  Repeat
    Event = WaitWindowEvent()
    
    If Event = #PB_Event_Timer
      StartDrawing(CanvasOutput(0))
      
      For k=1 To #X-2
        i=k+#X
        For j=1 To #Y-2
          Buffer(i,j)=((Buffer(k-1,j)+Buffer(k+1,j)+Buffer(k,j-1)+Buffer(k,j+1))*0.5-Buffer(i,j))*#Dampening                
        Next
      Next
      
      For i=1 To #X-2
        k=i+#X
        For j=1 To #Y-2
          Buffer(i,j)=((Buffer(k-1,j)+Buffer(k+1,j)+Buffer(k,j-1)+Buffer(k,j+1))*0.5-Buffer(i,j))*#Dampening                
          Plot(i,j,$010101*Int(Buffer(i,j)*10))
        Next
      Next
      
      StopDrawing()
      
    ElseIf Event = #PB_Event_Gadget
      Select EventGadget() 
        Case 0
          If EventType() = #PB_EventType_LeftButtonDown Or (EventType() = #PB_EventType_MouseMove And GetGadgetAttribute(0, #PB_Canvas_Buttons) & #PB_Canvas_LeftButton)
            Buffer(GetGadgetAttribute(0, #PB_Canvas_MouseX), GetGadgetAttribute(0, #PB_Canvas_MouseY))=20
          EndIf
        Case 1
          FillMemory(@Buffer(0,0), #X*#Y<<3)
      EndSelect
      
    EndIf
  Until Event = #PB_Event_CloseWindow
EndIf