PureBasic Forums - English

Code: Select all

myArray()
  1     2     3     4
1 1.098 2.754 3.777 5.777
2 1.999 3.777 4.567
3 2.888 4.675
4 1.897

Code: Select all

; Read Log

; Simple, quick and dirty version for learning 
; Tutorial for user coming from other Basic
; Do this at home but dont do this at work ;-)
; Explain how to use StringField to split text line
; and Trim to remove unwanted char
; Array are Zero base, change if you want

; Classic array version (you can use small array too and use ReDim to expand)
; Array in PB use () instead of []
Dim Data_One$(100, 2)
Dim Data_Two$(100, 10)	; I use matrix 2 as string for easy fixed decimal (use Val() or ValF() after)

; ReadFile instead of OpenFile can open file (readonly) event if shared (windows only)
If ReadFile(0, "datas.log")
	
	While Not Eof(0)
		
		TmpLine$ = ReadString(0)
		id		 = Asc( Left(TmpLine$, 1) )		; ASCII value of first char of line	
		i + 1									; increment i (can be write as i = i + 1)
		
		Select id
				
			Case 34		
				; Double-quote 	
				Debug "Line " + Str(i) + " is Part 1      : " + TmpLine$
				; Trim (string, chr(34) while remove "" at beging and end of string
				Data_One$(D1, 0) = Trim( StringField(TmpLine$, 1, ","), Chr(34) )
				Data_One$(D1, 1) = Trim( StringField(TmpLine$, 2, ","), Chr(34) )
				D1 + 1
				
			Case 46  	
				; Dot
				Debug "Line " + Str(i) + " is a Separator : " + TmpLine$
				; Nothing to do here
				
			Case 48 To 57
				; number 0 to 9
				Debug "Line " + Str(i) + " is Part 2      : " + TmpLine$
				RTrim(TmpLine$)  ; remove spaces at end of line
				k = 1
				For j = 0 To CountString(TmpLine$, " ")
					Data_Two$(D2, j) = StringField(TmpLine$, k, " ")
					k + 1
				Next
				D2 + 1
				
		EndSelect
		
	Wend
	CloseFile(0)
	
Else 
	Debug "Uh? I can't find datafile :-/"
	End
EndIf

Debug "--------- Results ---------"
Debug "--- Matrix 1"
For i = 0 To D1 - 1
	Debug " "  + Data_One$(i, 0) + " - " + Data_One$(i, 1)	
Next i
Debug "--- Matrix 2"
For i = 0 To D2 - 1
	Debug " " + Data_Two$(i, 0) + " - " + Data_Two$(i, 1) + " - " + Data_Two$(i, 2) + " - " + Data_Two$(i, 3)
Next

End

Code: Select all

OpenFile(1, fileName)
For r = 1 To 3
  For i = 0 To 3
    WriteStringN(1, textArray(i))
  Next i
  For i = 0 To 9
    WriteDouble(1, doublesArray(i))
  Next i
Next r
CloseFile(1)

Code: Select all

OpenFile(1, fileName)
For r = 1 To 3
  For i = 1 To 4
    Debug ReadString(1)
  Next i
  For i = 1 To 10
    Debug StrD(ReadDouble(1))
  Next i
Next r
CloseFile(1)

Code: Select all

; Read Log 2.0

; Simple, quick and dirty version for learning 
; Tutorial for user coming from other Basic
; Do this at home but dont do this at work ;-)
; Explain how to use StringField to split text line
; and Trim to remove unwanted char
; Array are Zero base, change if you want

; Modified with new informations
n = 76

Dim dm$(n,n) 	; To use as fixed decimal, I store values as text. If you want decimal, use dm.f(n,n)	
Dim array1$(n)
Dim array2$(n)

; ReadFile instead of OpenFile can open file (readonly) event if shared (windows only)
If ReadFile(0, "example.txt")
	
	While Not Eof(0)
		
		TmpLine$ = ReadString(0)
		id		 = Asc( Left(TmpLine$, 1) )		; ASCII value of first char of line	
		i + 1									; increment i (can be write as i = i + 1)
		
		Select id
				
			Case 34		
				; Double-quote 	
				Debug "Line " + Str(i) + " Part 1 : " + TmpLine$			
				array1$(D1) = Trim( StringField(TmpLine$, 1, ","), Chr(34) )
				array2$(D1) = Trim( StringField(TmpLine$, 2, ","), Chr(34) )
				D1 + 1
				
			Case 48 To 57
				; number 0 to 9
				Debug "Line " + Str(i) + " Part 2 : " + TmpLine$
				RTrim(TmpLine$)  ; remove spaces at end of line
				k = 1
				For j = 0 To CountString(TmpLine$, " ")
					dm$(D2, j) = StringField(TmpLine$, k, " ")
					; decimal version below (need conversion ValF ou ValD)
					; dm(D2, j) = ValF(StringField(TmpLine$, k, " "))
					k + 1
				Next
				D2 + 1
				
		EndSelect
		
	Wend
	CloseFile(0)
	
Else 
	Debug "Uh? I can't find datafile :-/"
	End
EndIf

Debug "--------- Results ---------"
Debug "--------- Matrix 1"
For i = 0 To D1 - 1
	Debug "array1$(" + RSet(Str(i), 2) + ") = "  + LSet(array1$(i), 30) + " - array2$(" + RSet(Str(i), 2) + ") = " + array2$(i)	
Next i

Debug "--------- Matrix 2"
For i = 0 To D2 - 1
	Debug "--- dm(" + Str(i) + ") ---"
	For j = 0 To 11
		Debug " dm$(" + RSet(Str(i), 2) + "," + RSet(Str(j), 2) + ") : " + dm$(i, j)
		; Debug " dm(" + RSet(Str(i), 2) + "," + RSet(Str(j), 2) + ") : " + StrF(dm(i, j))
	Next j
Next i

End

Code: Select all

OpenFile(1,"example.TXT")
n = 0
While Eof(1) = 0
  String.s = ReadString(1)
  If FindString(String, ",")
    n = n + 1
     
  EndIf 
    
Wend
CloseFile(1)

Dim otu.s(n-1)
Dim otu2.s(n-1)
OpenFile(1,"example.TXT")
n = 0
While Eof(1) = 0
  String.s = ReadString(1)
  If FindString(String, ",")
    
    cp = FindString(String, ",")
    
    otu(n) = Trim(Left(String,cp-1),Chr(34))    ; store the part before comma into otu
    otu2(n) = Trim(Right(String,Len(String)-cp), Chr(34))  ; store the part after the comma into otu2
    n = n + 1
  EndIf 
    
Wend
CloseFile(1)


For k=0 To n-1
  Debug otu(k) + " " + otu2(k)
Next


Dim dm.f(n,n)

OpenFile(1,"example.TXT")
i = 1
While Eof(1) = 0
  String.s = Trim(ReadString(1))
  If FindString(String, ",") = 0 And String <> ""   
    num = CountString(String, "  ")
    For k= 1 To num+1
      dm(i,i+k) = ValF(StringField(String, k, "  "))
    Next
    i+1
    
  EndIf 
    
Wend
CloseFile(1)
For i =1 To n
  For j = 1 To n
    Debug dm(i,j)
    
  Next
  
Next