PureBasic Forums - English

Code: Select all

  ; Load the font
  ; Attempt to have the Font DPI at normal, even in higher DPI (PureBasic forum helped)
  Global igDpi.i = GetDeviceCaps_(GetDC_(0),#LOGPIXELSX)
  Global iFS10.i = ((10 * 100) / igDpi)
  Global igFontGui10.i=LoadFont(igFontGui10,"Arial",iFS10,#PB_Font_HighQuality+2)
  SetGadgetFont(#PB_Default, igFontGui10)

Code: Select all

Procedure InitScaleDPI() ;Windows 5.0 or higher needed for minimum functionality of this procedure.
  
  CompilerIf #PB_Compiler_OS = #PB_OS_Windows
    Protected dpiaware.l=#False,dc.i,lpx.i,lpy.i,dll.i,*SetProcessDPIAware,*IsProcessDPIAware,ncm.NONCLIENTMETRICS,font$,font.i
    CompilerIf #PB_Compiler_Exe ;Only use this in exes, as dlls inherit DPI from the calling process.
      dll=OpenLibrary(#PB_Any,"user32.dll")
      If dll
        *IsProcessDPIAware=GetFunction(dll,"IsProcessDPIAware")
        If *IsProcessDPIAware
          dpiaware=CallFunctionFast(*IsProcessDPIAware)
        EndIf
        If Not dpiaware
          *SetProcessDPIAware=GetFunction(dll,"SetProcessDPIAware")
          If *SetProcessDPIAware
            CallFunctionFast(*SetProcessDPIAware)
          EndIf
        EndIf
      EndIf
    CompilerEndIf
    dc=GetDC_(#Null)
    If dc
      lpx=GetDeviceCaps_(dc,#LOGPIXELSX)
      lpy=GetDeviceCaps_(dc,#LOGPIXELSY)
      
      If lpx>0
        _ScaleDPI_X_=lpx/#DefaultDPIX
      EndIf
      If lpy>0
        _ScaleDPI_Y_=lpy/#DefaultDPIY
      EndIf
      ReleaseDC_(#Null,dc)
    EndIf
    ncm\cbSize=SizeOf(NONCLIENTMETRICS)
    If SystemParametersInfo_(#SPI_GETNONCLIENTMETRICS,SizeOf(NONCLIENTMETRICS),ncm,#Null)
      font$=PeekS(@ncm\lfMessageFont\lfFaceName)
      
      ;InstallIncludedFont(?font1_start, ?font1_end-?font1_start, "Ubuntu-R.ttf")
      font$ = "Ubuntu"
      ;font$ = "Liberation Sans"
      ;font$ = "DroidSans"
      
      If lpx <= #DefaultDPIX And lpy <= #DefaultDPIY
        font=LoadFont(#PB_Any,font$,10, #PB_Font_HighQuality)
      Else
        font=LoadFont(#PB_Any,font$,9,#PB_Font_HighQuality)
      EndIf
    EndIf
  CompilerElseIf #PB_Compiler_OS = #PB_OS_Linux
    font$ = GetCurrentDirectory()+"Ubuntu-R.ttf"
    ;font$ = "Ubuntu"
    font=LoadFont(#PB_Any,font$,10,#PB_Font_HighQuality)
  CompilerEndIf
  
  If font
    SetGadgetFont(#PB_Default,FontID(font))
  EndIf
  
  Enumeration #PB_Compiler_EnumerationValue
    #Font
  EndEnumeration
  
  LoadFont(#Font,"Ubuntu", 12, #PB_Font_Bold)
  
  
EndProcedure

Code: Select all

Prototype proto_SetProcessDPIAware()

If OpenLibrary(0,"user32.dll")
    SetProcessDPIAware.proto_SetProcessDPIAware = GetFunction(0,"SetProcessDPIAware")
    If SetProcessDPIAware
        ;Debug "calling SetProcessDPIAware()"
        SetProcessDPIAware() ; Windows Vista+ / Windows Server 2008+
    EndIf
EndIf

Global _dpiScaleFactorX.d = GetDeviceCaps_(GetDC_(0),#LOGPIXELSX) / 96
Global _dpiScaleFactorY.d = GetDeviceCaps_(GetDC_(0),#LOGPIXELSY) / 96

Macro dpiX(_num_) : (_num_ * _dpiScaleFactorX) : EndMacro
Macro dpiY(_num_) : (_num_ * _dpiScaleFactorY) : EndMacro


; Load the font
t=LoadFont(1, "Arial", 10, #PB_Font_HighQuality) ;Load Arial Font, Size 10 - 28/NOV/2013
SetGadgetFont(#PB_Default, FontID(1))
If t=0 : MessageRequester("Error", "Can't load Arial font.") : EndIf  

If OpenWindow(0, dpiX(0), dpiY(0), dpiX(640), dpiY(325), "DPIaware - " + Str(_dpiScaleFactorX*100) +"%", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ButtonGadget(0, dpiX(10),dpiY( 10),dpiX(200),dpiY(25), "Standard Button")
    ButtonGadget(1, dpiX(10),dpiY( 40),dpiX(200),dpiY(25), "Left Button", #PB_Button_Left)
    ButtonGadget(2, dpiX(10),dpiY( 70),dpiX(200),dpiY(25), "Right Button", #PB_Button_Right)
    ButtonGadget(3, dpiX(10),dpiY(100),dpiX(200),dpiY(60), "Multiline Button  (longer text gets automatically wrapped)", #PB_Button_MultiLine)
    ButtonGadget(4, dpiX(10),dpiY(170),dpiX(200),dpiY(25), "Toggle Button", #PB_Button_Toggle)
    
    If CreateMenu(0,WindowID(0))
      MenuTitle("Project")
        MenuItem(1, "Open"   +Chr(9)+"Ctrl+O")
        MenuItem(2, "Save"   +Chr(9)+"Ctrl+S")
        MenuItem(3, "Save as"+Chr(9)+"Ctrl+A")
        MenuItem(4, "Close"  +Chr(9)+"Ctrl+C")
    EndIf
    
    CreateStatusBar(0,WindowID(0))
    AddStatusBarField(dpiX(320))
    AddStatusBarField(dpiX(320))
    StatusBarText(0, 0, "Field 1")
    StatusBarText(0, 1, "Field 2")

    
    ListViewGadget(5, dpiX(430),dpiY(10),dpiX(200),dpiy(185))
    For i = 0 To 100 : AddGadgetItem(5,-1,"Item "+i) : Next
    
    CanvasGadget(6, dpiX(220),dpiY(10),dpiX(200),dpiy(185))
    If StartDrawing( CanvasOutput(6) )
        Box(0,0,OutputWidth(),OutputHeight(),RGB($40,$40,$40))
        Line(dpiX( 0) ,dpiY(0), dpiX(200),dpiy(185),RGB($FF,$FF,$00))
        Line(dpiX(200),dpiY(0),-dpiX(200),dpiy(185),RGB($FF,$FF,$00))
        StopDrawing()
    EndIf
    
    If LoadImage(0,#PB_Compiler_Home+"Examples/Sources/Data/PureBasicLogo.bmp")
        ResizeImage(0,dpiX(ImageWidth(0)),dpiY(ImageHeight(0)))
        ImageGadget(7,dpiX(10),dpiY(205),dpiX(381),dpiY(68),ImageID(0))
    EndIf
    
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf