PureBasic Forums - English

  Title = ReplaceString(GetGadgetText(strTitle)," ","%20")
  
  InitNetwork()

  If Val(GetGadgetText(strYear)) > 1900
    *buf = ReceiveHTTPMemory("http://www.omdbapi.com/?t=" + Title + "&y=" + GetGadgetText(strYear))
  Else
    *buf = ReceiveHTTPMemory("http://www.omdbapi.com/?t=" + Title)
  EndIf
  CSVString = PeekS(*buf,-1,#PB_Ascii)

Title":"Dust Up
Year":"2012
Rated":"UNRATED
Released":"28 Sep 2012
Runtime":"94 min
Genre":"Action, Adventure, Comedy
Director":"Ward Roberts
Writer":"Ward Roberts
Actors":"Amber Benson, Jeremiah Birkett, Aaron Gaffey, Devin Barry
Plot":"A former vigilante who has embraced his peaceful nature comes to the aid of a young mother in trouble with a cannibalistic drug lord.
Language":"English
Country":"USA
Awards":"N/A
Poster":"http://ia.media-imdb.com/images/M/MV5BM ... _SX300.jpg
Metascore":"N/A
imdbRating":"5.1
imdbVotes":"231
imdbID":"tt1991034
Type":"movie

Just used this to build a movie\DVD database for home use will post when a little more complete.

collectordave wrote:Thanks will post later

infratec wrote:Hi Fangbeast,

try this:

Code: Select all

EnableExplicit


Procedure.i HTTPGet2Mem(URL$)
  
  Protected.i ConnectionID, TimeOutCounter, Laenge, Pos, Received, HelpLength, Length, HeaderEndPos, HeaderFinished, Size
  Protected Server$, Header$, String$, Result$, Page$, Parameter$, Host$, *Buffer, *HelpBuffer
  
  
  If LCase(Left(URL$, 7)) <> "http://"
    URL$ = "http://" + URL$
  EndIf
  
  ;Host$ = GetURLPart(URL$, #PB_URL_Site)
  
  Host$ = Mid(URL$, 8, FindString(URL$, "/", 8) - 8)
  
  Page$ = "/" + GetURLPart(URL$, #PB_URL_Path)
  Parameter$ = GetURLPart(URL$, #PB_URL_Parameters)
  If Parameter$
    Page$ + "&" + Parameter$
  EndIf
  
  ;Debug Host$
  
  ConnectionID = OpenNetworkConnection(Host$, 80)
  
  If ConnectionID
    
    ;Build header
        
    Header$ = "GET " + Page$ + " HTTP/1.1" + #CRLF$
    Header$ + "Host: " + Host$ + #CRLF$
    ;Header$ + "Accept: text/html" + #CRLF$
    Header$ + "Content-Type: application/x-www-form-urlencoded" + #CRLF$    
    ;String$ + "Connection: close" + #CRLF$
    Header$ + #CRLF$
    ; header is finished
    
    ;Debug Header$
    

    SendNetworkString(ConnectionID, Header$)
    TimeOutCounter = 1000
    Repeat
      If NetworkClientEvent(ConnectionID) = #PB_NetworkEvent_Data
        Break
      EndIf
      Delay(10)
      TimeOutCounter -1
    Until TimeOutCounter = 0
    
    If TimeOutCounter <> 0
      #Size = 10000
      *HelpBuffer = AllocateMemory(#Size)
      
      If *HelpBuffer
        String$ = ""      
        Repeat
          HelpLength = ReceiveNetworkData(ConnectionID, *HelpBuffer, #Size)
          If HelpLength > 0
            *Buffer = ReAllocateMemory(*Buffer, Length + HelpLength)
            CopyMemory(*HelpBuffer, *Buffer + Length, HelpLength)
            Length + HelpLength
            
            ;Debug Length
            
            If Not HeaderFinished
              HeaderEndPos = FindString(PeekS(*Buffer), #CRLF$ + #CRLF$)
              If HeaderEndPos
                HeaderFinished = #True
                Pos = FindString(PeekS(*Buffer), "Content-Length:")
                If Pos
                  Size = Val(PeekS(*Buffer + Pos + 15)) + HeaderEndPos + 3
                  ;Debug Size
                EndIf
              EndIf
            EndIf
            
            ;String$ = PeekS(*HelpBuffer + HelpLength - 10, 10, #PB_UTF8)
            ;String$ + PeekS(*HelpBuffer, -1, #PB_UTF8)
            ;Debug String$
          EndIf
          If Size > 0
            If Length >= Size
              Received = #True
            EndIf
          Else
            If FindString(String$, "</html") > 0
              Received = #True
            EndIf
          EndIf
        Until Received
        FreeMemory(*HelpBuffer)
      EndIf
    EndIf
      
    CloseNetworkConnection(ConnectionID)
  EndIf
  
  ProcedureReturn *Buffer
  
EndProcedure




Define *Buffer, Size.i, HeaderPos.i

UseJPEGImageDecoder()
InitNetwork()

*Buffer = HTTPGet2Mem("http://ia.media-imdb.com/images/M/MV5BMjIxNjAzODQ0N15BMl5BanBnXkFtZTcwODY2MjMyNA@@._V1_SX300.jpg")
If *Buffer <> #Null
  Size = MemorySize(*Buffer)
  
  HeaderPos = FindString(PeekS(*Buffer, 1024), #CRLF$ + #CRLF$)
  
  OpenWindow(0, 0, 0, 800, 640, "Test")
  CatchImage(0, *Buffer + HeaderPos + 3)
  ImageGadget(0, 0, 0, 0, 0, ImageID(0))  
  FreeMemory(*Buffer)
  
  Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  
Else
  MessageRequester("Error", "Not downloaded")
EndIf

But it is only for picture addresses in the web
Since only than the picture data starts immediately after the http header.

Bernd

RamRat wrote: Hi, um I tried this and couldn't get it to work any thoughts on what I'm doing wrong?

elwood wrote:

RamRat wrote: Hi, um I tried this and couldn't get it to work any thoughts on what I'm doing wrong?

Tell more about your problem or nobody will be able to help. Any error? What is it doing?