Create Comments Editor - Updated

[Lubos]

Code: Select all

If Trim(Text$)<>""
        lc = CountGadgetItems(#CommentEditor)
        If lc=0 Or Trim(GetGadgetText(#CommentEditor))="" ;see NOTE 1:
          ClearGadgetItems(#CommentEditor)
          SetGadgetText(#CommentEditor, Text$)
          OrgText$=Test$
        Else
          SendMessage_(GadgetID(#CommentEditor), #WM_PASTE,0,0) ;this method allows you to choose where you want to paste the text.
        EndIf
      EndIf

There is only one line with variable Test$ in last version:
OrgText$ = Test$
I am afraid that it is the same as:
OrgText$= ""
I cannot find any initialization of Test$ elsewhere. Maybe I am wrong.

[yrreti]

Hi Lubos

Now I finally see what your questioning about. It's a typo. Test$ is suppose to be Text$.
In both places it's found, OrgText$=Test$ should be OrgText$=Text$
OrgText$ is just used to store the original pasted text in case you want to undo back to it.
Good observation!

It has been corrected in my posts, but can't edit Tenaja's code.

Try the new code, as I think you will like it better.

yrreti

[Kiffi]

It's a typo.

That's why EnableExplicit isn't a bad thing.

Greetings ... Kiffi

[Lubos]

Nice work. Thanks yrreti. I'd like two more buttons: Copy from file + Copy to file. Sometimes it can be handy.

Thanks for update. Although two more buttons are still missing, nice work anyway.

I tried add these desiderable buttons myself. Maybe not desirable for anyone else. But maybe they are.

Code: Select all

#DefaultCommentString = "; "

Enumeration
  #CommentWin
EndEnumeration

Enumeration
  #PreCommentEditor
  #Container_1
  #CommentEditor
  #ClrTxt_btn
  #CpyFromClpBd_btn
  #Cut_btn
  #Copy_btn
  #Paste_btn
  #Undo_txt
  #CmntChars_txt
  #CmntChars_str
  #CmntLines_btn
  #CmntLines_txt
  #Cpy2ClpBd_btn
  #Exit_btn
  #POPUP
  #Ctrl_v;disable these to allow only copy, paste, and cut functions through the pop up menu
  #Ctrl_C;so it uses the paste input formating there.
  #Ctrl_x
  
  #CtrlAltv;To display version info
  
  #SaveFile
  #LoadFile
EndEnumeration

Define.l Event, EventWindow, EventGadget, EventType, EventMenu
Global point.POINT
Podadr$ ="" ; subdirectory
;-
Procedure OpenWindow_CommentWin()
  xx=10
  xxx=27
  xxxx=31
  ;First line was used for testing, so I could see what was happening in the #PreCommentEditor window.
  ;If OpenWindow(#CommentWin, 10, 198, 1230, 397, Space(65)+"Create Comments Editor", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_TitleBar)
  If OpenWindow(#CommentWin, 450, 198, 615, 397, Space(65)+"Create Comments Editor", #PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_TitleBar|#PB_Window_WindowCentered)
    ButtonGadget(#ClrTxt_btn, 8, 355, 40, 32, "Clear Text", #PB_Button_MultiLine)
    ButtonGadget(#CpyFromClpBd_btn, 65-xx, 352, 66, 32, "Copy from Clipboard", #PB_Button_MultiLine)
    ButtonGadget(#Copy_btn, 200-xx, 352, 35, 32, "Copy", #PB_Button_MultiLine)
    ButtonGadget(#LoadFile, 135-xx, 352, 66, 32, "Load from memoryfile", #PB_Button_MultiLine)
    ButtonGadget(#Paste_btn, 240-xx, 352, 35, 32, "Paste", #PB_Button_MultiLine)
    ButtonGadget(#Cut_btn, 280-xx, 352, 35, 32, "Cut", #PB_Button_MultiLine)
    TextGadget(#Undo_txt,225-xx,384,80,16,"Ctrl z = Undo");,#PB_Text_Border )
    
    TextGadget(#CmntChars_txt, 335-xxx, 355, 35, 16, "Chars:", #PB_Text_Center)
    StringGadget(#CmntChars_str, 335-xxx, 370, 35, 16, #DefaultCommentString)
    ButtonGadget(#CmntLines_btn, 381-xxxx, 352, 74, 32, "Comment/Un Lines", #PB_Button_MultiLine)
    TextGadget(#CmntLines_txt, 371-xxxx, 384, 120, 16, "Lines UnCommented");,#PB_Text_Border )
    
    ButtonGadget(#Cpy2ClpBd_btn, 460-xxxx, 352, 66, 32, "Copy to Clipboard", #PB_Button_MultiLine)
    ButtonGadget(#SaveFile, 530-xxxx, 352, 62, 32, "Save Clipboard", #PB_Button_MultiLine)
    ButtonGadget(#Exit_btn, 565, 355, 40, 32, "Exit")
    
    
      DisableGadget(#SaveFile,1)
    
    
    Font1 = LoadFont(#PB_Any, "Lucida Console"  ,  8)
    ;Both EditorGadgets are set to the same dimentions.
    ;See the notes by the comment button code below, to see why and how they are both needed and used.
    EditorGadget(#PreCommentEditor, 621, 2, 592, 335)
    W=592 ;Window width
    H=335 ;Window height
    LM=25 ;Left margin
    TM=0 ;Top margin
    RM=W-LM ;Right margin (and wordwrap if enabled)
    BM=H ;Bottom margin
    Editor2Rect.RECT\left = LM
    Editor2Rect\top = TM
    Editor2Rect\right = RM
    Editor2Rect\bottom = BM
    SendMessage_(GadgetID(#PreCommentEditor),#EM_SETRECT,0,Editor2Rect)
    SendMessage_(GadgetID(#PreCommentEditor), #EM_SETTARGETDEVICE, 0, 0)
    SetGadgetFont(#PreCommentEditor, FontID(Font1))
    ;For testing the #PreCommentEditor window, comment out this next line.
    HideGadget(#PreCommentEditor, 1)
    
    ContainerGadget(#Container_1, 6, 1, 600, 345, #PB_Container_Raised)
    EditorGadget(#CommentEditor, 1, 2, 592, 335)
    W=592 ;Window width
    H=335 ;Window height
    LM=25 ;Left margin
    TM=0 ;Top margin
    RM=W-LM ;Right margin (and wordwrap if enabled)
    BM=H ;Bottom margin
    EditorRect.RECT\left = LM
    EditorRect\top = TM
    EditorRect\right = RM
    EditorRect\bottom = BM
    SendMessage_(GadgetID(#CommentEditor),#EM_SETRECT,0,EditorRect)
    SendMessage_(GadgetID(#CommentEditor), #EM_SETTARGETDEVICE, 0, 0)
  CloseGadgetList()
    ; If you don't set the Font after the paste, the pasted text will be the font it was pasted with.
    SetGadgetFont(#CommentEditor, FontID(Font1))
    
    If CreatePopupMenu(#POPUP)
      MenuItem(1, "Copy")
      MenuItem(2, "Paste")
      MenuItem(3, "Cut")
    EndIf
    
    ;This section is used to disable Ctrl V, Ctrl C, and Ctrl X, so you have to use pop up menu
    AddKeyboardShortcut(0, #PB_Shortcut_Control|#PB_Shortcut_V, #Ctrl_v);dissable Ctrl V so you have to use pop up menu
    AddKeyboardShortcut(0, #PB_Shortcut_Control|#PB_Shortcut_C, #Ctrl_C);dissable Ctrl C so you have to use pop up menu
    AddKeyboardShortcut(0, #PB_Shortcut_Control|#PB_Shortcut_X, #Ctrl_x);dissable Ctrl X so you have to use pop up menu
 
  EndIf
EndProcedure

OpenWindow_CommentWin()

comment=0

;{- Event loop
;-Event loop
Repeat
    
  ;NOTE 1:  This part keeps original pasted text when you use Ctrl z or undo, up to the original edit.
  lc = CountGadgetItems(#CommentEditor)
  If lc=0 Or Trim(GetGadgetText(#CommentEditor))=""
    ClearGadgetItems(#CommentEditor)
    SetGadgetText(#CommentEditor, OrgText$)
  EndIf
  
  Event = WaitWindowEvent(5)
  Select Event
    
  Case #WM_RBUTTONDOWN
    ;Debug "RBUTTON"
    GetCursorPos_(@point)
    DisplayPopupMenu(#POPUP, WindowID(#CommentWin))
    
  Case #PB_Event_Gadget
    EventGadget = EventGadget()
    EventType = EventType()
    
    If EventGadget = #Container_1
    ElseIf EventGadget = #CommentEditor
      
    ElseIf EventGadget = #ClrTxt_btn  ;clear the text window
      ClearGadgetItems(#CommentEditor)
      OrgText$=""
      
    ElseIf EventGadget= #LoadFile ;LOAD FROM MEMORYFILE **********************
      If IsFile(224)
          CloseFile(224)
        EndIf

        If OpenFile(224,Podadr$+"memoryfile.txt")
          OrgText$=""
          
          While Eof(224) = 0 
            Radek$ =ReadString(224)
           
            OrgTexT$= Orgtext$+Radek$+Chr(13)
          Wend
          Text$=OrgText$
          SetGadgetText(#CommentEditor,Text$)
          CloseFile(224)
          

          EndIf
        ; **************************************************************
        
        ElseIf EventGadget= #SaveFile ; SAVE TO MEMORYFILE ++++++++++++++++++++
        If IsFile(223)
        CloseFile(223)
      EndIf

      If CreateFile(223, podadr$+"memoryfile.txt")
       
        WriteStringN(223, Text$)
        CloseFile(223)
        DisableGadget(#SaveFile,1)
      EndIf ; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
        
      
    ElseIf EventGadget = #CpyFromClpBd_btn  ;paste clipboard text into edit window
      Text$ = GetClipboardText()
       
      If Trim(Text$)<>""
        lc = CountGadgetItems(#CommentEditor)
        If lc=0 Or Trim(GetGadgetText(#CommentEditor))="" ;see NOTE 1:
          ClearGadgetItems(#CommentEditor)
          SetGadgetText(#CommentEditor, Text$)
          OrgText$=Text$
        Else
          SendMessage_(GadgetID(#CommentEditor), #WM_PASTE,0,0) ;this method allows you to choose where you want to paste the text.
        EndIf
      EndIf
      
    ElseIf EventGadget = #Cut_btn
      SendMessage_(GadgetID(#CommentEditor), #WM_COPY,0,0)
      SendMessage_(GadgetID(#CommentEditor), #WM_CUT,0,0)
      
    ElseIf EventGadget = #Copy_btn
      SendMessage_(GadgetID(#CommentEditor), #WM_COPY,0,0)
      
    ElseIf EventGadget = #Paste_btn
      Font1 = LoadFont(#PB_Any, "Lucida Console"  ,  8)
      ;Paste text from clipboard
      CopyCBText$ = GetClipboardText()                 ;Get the text from the clipboard
      If Trim(CopyCBText$)<>""
        If Trim(GetGadgetText(#CommentEditor))="" ;see NOTE 1:
          SetGadgetText(#CommentEditor,CopyCBText$)
          ; If you don't set the Font after the paste, the pasted text will be the font it was pasted with.
          SetGadgetFont(#CommentEditor, FontID(Font1))
          OrgText$=GetGadgetText(#CommentEditor)
        Else
          SendMessage_(GadgetID(#CommentEditor), #WM_CLEAR,0,0)   ;If text is selected in destination, remove it
          SendMessage_(GadgetID(#CommentEditor), #WM_PASTE,0,0)   ;Paste the clipboard text at cursor posn
          ; If you don't set the Font after the paste, the pasted text will be the font it was pasted with.
          SetGadgetFont(#CommentEditor, FontID(Font1))
        EndIf
        ;EndIf
        SetActiveGadget(#CommentEditor)
      EndIf
      
      
    ElseIf EventGadget = #CmntLines_btn ;comment the lines
      CommentString$ = GetGadgetText(#CmntChars_str)
      CommentLen = Len(CommentString$)
      comment=comment+1
      If comment=1
        
        ; This whole part works in an unusual and unique way when you Comment and
        ; Uncomment the lines. Word wrap is accomplished by the margin settings.
        
        ; When you select Comment. It copies line by line, from the Comment Editor
        ; window, removing any found Chr(10)'s and Chr(13)'s, from each line. And then
        ; and copies each line with a Chr(10) at the end of each line to the PreComment
        ; Editor window.
        ; This removes any line continuations from the text, caused by pasting and
        ; editing and the action of the margin adjustments.
        ; Then the Comment Editor window is cleared, and then its margin is decreased
        ; by the length of the comments character your using * 5.  (min = 5 or @ 5
        ; characters max can be used for comments.  Default is "; ")
        ; Then the lines from the PreComment Editor are copied with the comment
        ; characters added and copied line by line to the Comment Editor window.
        
        ; When you select UnComment, it just removes the added comment characters and
        ; sets the Comment Editor window margins back to their default setting.
        
        ; It seems to work pretty well, as long as the comment characters your using
        ; are 5 or less. Otherwise you will need to do some additional editing as they
        ; will cause any line that's at the max length to word wrap because the minimum
        ;margin is set to 5.
        
        
        SetGadgetText(#CmntLines_txt,"Lines Commented")
        ClearGadgetItems(#PreCommentEditor)
        lc = CountGadgetItems(#CommentEditor)
        For x=0 To lc-1;  -1 because  lc is numbered from 1, where as the EditorGadget items are numbered from 0.
          dat$=GetGadgetItemText(#CommentEditor,x)
          dat$=ReplaceString(dat$,Chr(13)," ",1);have to remove LF's and CR's
          dat$=ReplaceString(dat$,Chr(10)," ",1)
          SetGadgetItemText(#PreCommentEditor,x,dat$+Chr(10))
        Next x
        ClearGadgetItems(#CommentEditor)
        lc = CountGadgetItems(#PreCommentEditor)
        For x=0 To lc-1;  -1 because  lc is numbered from 1, where as the EditorGadget items are numbered from 0.
          dat$=GetGadgetItemText(#PreCommentEditor,x)
          SetGadgetItemText(#CommentEditor,x,dat$+Chr(10))
        Next x
        W=592 ;Window width
        H=335 ;Window height
        LM=25-(CommentLen*5) ;Left margin
        If LM<5:LM=5:EndIf
        TM=0 ;Top margin
        RM=W-LM ;Right margin (and wordwrap if enabled)
        BM=H ;Bottom margin
        EditorRect.RECT\left = LM
        EditorRect\top = TM
        EditorRect\right = RM
        EditorRect\bottom = BM
        SendMessage_(GadgetID(#CommentEditor),#EM_SETRECT,0,EditorRect)
        SendMessage_(GadgetID(#CommentEditor), #EM_SETTARGETDEVICE, 0, 0)
        
        lc = CountGadgetItems(#CommentEditor)
        For x=0 To lc-1;  -1 because  lc is numbered from 1, where as the EditorGadget items are numbered from 0.
          dat$=GetGadgetItemText(#CommentEditor,x); Get the specified line text.
          If Left(dat$,CommentLen)<>CommentString$ And Trim(dat$)<>"" ;just add comment only if line isn't commented already.
            dat$=CommentString$+dat$
          EndIf
          SetGadgetItemText(#CommentEditor, x, dat$)
        Next x
      Else
        SetGadgetText(#CmntLines_txt,"Lines UnCommented")
        lc = CountGadgetItems(#CommentEditor)
        For x=0 To lc-1;  -1 because  lc is numbered from 1, where as the EditorGadget items are numbered from 0.
          dat$=GetGadgetItemText(#CommentEditor,x); Get the specified line text.
          If Left(dat$,CommentLen)=CommentString$ ;just remove comment that was added. Note: existing indented comments are not removed.
            dat$=Mid(dat$,1 + CommentLen)   ; CG: was (...,2)
          EndIf
          SetGadgetItemText(#CommentEditor, x, dat$)
        Next x
        W=592 ;Window width
        H=335 ;Window height
        LM=25 ;Left margin
        TM=0 ;Top margin
        RM=W-LM ;Right margin (and wordwrap if enabled)
        BM=H ;Bottom margin
        EditorRect.RECT\left = LM
        EditorRect\top = TM
        EditorRect\right = RM
        EditorRect\bottom = BM
        SendMessage_(GadgetID(#CommentEditor),#EM_SETRECT,0,EditorRect)
        SendMessage_(GadgetID(#CommentEditor), #EM_SETTARGETDEVICE, 0, 0)
        comment=0
      EndIf
      
    ElseIf EventGadget = #Cpy2ClpBd_btn
      DisableGadget(#SaveFile,0)
      Text$ = GetGadgetText(#CommentEditor)
      ClearClipboard()
      SetClipboardText(Text$)
      
    ElseIf EventGadget = #Exit_btn
      CloseWindow(#CommentWin)
      End
    EndIf
    
  Case #PB_Event_Menu
    ;I could have used the direct ID method like I did above for the Copy Cut and Paste Buttons.
    ;But I'd like to keep this next code here for a known future reference, as it's some useful code.
    gdc_ID = GetDlgCtrlID_(WindowFromPoint_(point\y << 32 + point\x))
    Select EventMenu()
    Case 1  ;copy
      If IsGadget(gdc_ID)
        Gadget_is = GadgetType(gdc_ID)
        If Gadget_is = #PB_GadgetType_Editor
          ;Copy selected text only to clipboard
          SendMessage_(GadgetID(gdc_ID), #WM_COPY,0,0)
        EndIf
      EndIf
      
    Case 2  ;paste
      If IsGadget(gdc_ID)
        Gadget_is = GadgetType(gdc_ID)
        If Gadget_is = #PB_GadgetType_Editor
          Font1 = LoadFont(#PB_Any, "Lucida Console"  ,  8)
          ;Paste text from clipboard
          CopyCBText$ = GetClipboardText()                 ;Get the text from the clipboard
          If Trim(CopyCBText$)<>""
            If Trim(GetGadgetText(#CommentEditor))="" ;see NOTE 1:
              SetGadgetText(#CommentEditor,CopyCBText$)
              ; If you don't set the Font after the paste, the pasted text will be the font it was pasted with.
              SetGadgetFont(#CommentEditor, FontID(Font1))
              OrgText$=GetGadgetText(#CommentEditor)
            Else
              SendMessage_(GadgetID(gdc_ID), #WM_CLEAR,0,0)   ;If text is selected in destination, remove it
              SendMessage_(GadgetID(gdc_ID), #WM_PASTE,0,0)   ;Paste the clipboard text at cursor posn
              ; If you don't set the Font after the paste, the pasted text will be the font it was pasted with.
              SetGadgetFont(#CommentEditor, FontID(Font1))
            EndIf
            ;EndIf
            SetActiveGadget(#CommentEditor)
          EndIf
        EndIf
      EndIf
      
    Case 3  ;cut
      If IsGadget(gdc_ID)
        Gadget_is = GadgetType(gdc_ID)
        If Gadget_is = #PB_GadgetType_Editor
          ;Copy selected text only to clipboard
          SendMessage_(GadgetID(gdc_ID), #WM_COPY,0,0)
          SendMessage_(GadgetID(gdc_ID), #WM_CUT,0,0)
        EndIf
      EndIf
      
    EndSelect
    
  Case #PB_Event_CloseWindow
    EventWindow = EventWindow()
    If EventWindow = #CommentWin
      CloseWindow(#CommentWin)
      Break
    EndIf
  EndSelect
ForEver
;}



 
 
 
 

[yrreti]

Hi Lubos

What ever reason you may have to save a copy, perhaps maybe for later use. You can't save it that way.
It needs to be saved, and loaded line by line. My suggestion as a very simple solution for what you want to do,
is to use

Code: Select all

RunProgram("notepad.exe")

for the Save Clipboard button.
This will open notepad, where you can just paste the text into it, and easily save it where you want, and you can
give it a 'meaningful name' too.
As to the load part. I suggest you either use OpenFileRequester() to locate and open the file you need,
or just open the file you saved, using notepad. If it needs to be edited or changed again. You can just edit it there,
or copy and paste it into the Comment Editor again. Much less hassle I think.

Later: Actually just playing with that idea. I renamed the Save button to 'Save as File'
and the modified the ElseIf to:

Code: Select all

    ElseIf EventGadget= #SaveFile ; SAVE TO A TXTFILE ++++++++++++++++++++
      RunProgram("notepad.exe")

It works quite well!, and it's not actually a bad idea in some cases in which you may have a use for it later.
I removed the other button though, because for the extra code hassle, I just don't see much use for it,
when you can just use notepad to open your 'already commented file', and copy and paste from it.
Elsewise, not a bad idea!

yrreti

[Lubos]

What ever reason you may have to save a copy, perhaps maybe for later use. You can't save it that way.

Why? I tried my code and IMHO: It works well.

Anyway, I agree with you in issue of Notepad. My code is rather clumsy. My original idea was: Avoid Notepad
It was not such a good idea as I thought. The solution with Notepad is more friendly.

[Tenaja]

I have edited the code in my post to fix the test$ typo.

[yrreti]

Thanks Tenaja

I saw a small querk when pasting some text from an rtf file that had some text centered in it.
The following simple code with explanation, can be added to remove it from the Text$ before
putting the text into the Comment Editor.

Code: Select all

    ElseIf EventGadget = #CpyFromClpBd_btn  ;paste clipboard text into edit window
      Text$ = GetClipboardText()
      If FindString(Text$,"\qc",1)>0
        ReplaceString(Text$,"\qc","",1)
        ;"\qc" is the rtf command for centering text. 
        ;If pasting from some rtf text that has some text centered, this removes it 
        ;from the text so it won't mess with your editing.
      EndIf

yrreti

[yrreti]

Hi all

To make it simpler with less confusion,
I will always put my latest version that I am using at the first post on page 1.
But please.
If you find some interesting mods to make it better. Please post it here
to help improve the program for everyone.

Thanks
yrreti

[Lubos]

;Lobos for his idea

Hi yrreti,
a nice piece of work again. I found just one typo (fortunately in my nickname only). Lubos

[Korolev Michael]

Aaand?
Where is description. How I can use this? What is this created for?

[Karellen]

Aaand?
Where is description. How I can use this? What is this created for?

It's a tool for the IDE which helps you to insert multi line comments avoiding unwanted formatting of keywords. It's explained in this post:
http://www.purebasic.fr/english/viewtop ... 48#p392357