[SOLVED] Very slow editor - independent of settings

[dangerfreak]

And for small files it works as expected ? The IDE has a file of 300 kb (preferences.pb) and it works very fast here.

The longer the source code, the slower is the IDE. So if I have a really short project (up to 20 kb), loading and editing is fast (still, there is the "open preferences" problem). Loading a 50kb project already takes about 5-10 seconds.

The preferences.pb of the IDE takes about 20 seconds to load. The code appears after 5 seconds, but until I can edit it (=the cursor appears) it takes another 15 seconds.

[ChrisR]

My result:
...
Total OpenPreferencesWindow Time = 1997

It's not 10 seconds but it's really not fast, with slowness everywhere.
Yet, you should be faster, given your PC's config, as Fred said, maybe a driver problem!

I compiled the IDE using the C backend ... You can test it and see it makes any differences (might be several mem misalignment issues or something)

I've been compiling like this with my additions for a while now, and everything seems to be working fine

[dangerfreak]

It's not 10 seconds but it's really not fast, with slowness everywhere.

Ok, I used a stopwatch now: It's exactly 7 seconds

[marc_256]

Hi,

As I remember me some tests I did long time ago to speed up IDE ...
What was slowing down PB for me:

1) How many programs do you have in your program bar to preload ...

2) I closed all Preferences for "AutoComplete" see images below


Marc,

PS: At that time I had have 3 different computers
1x Win 7
1x Win 8.1
1x Win 10 pro

And they all reacted differently with the PB IDE

[dangerfreak]

Hi,

As I remember me some tests I did long time go to speed up IDE ...
What was slowing down PB for me:

1) How many programs do you have in your program bar to preload ...

2) I closed all Preferences for "AutoComplete" see images below

Marc,

As I already mentioned I have several computers with a nearly identical setup (Windows, apps, Purebasic & settings, etc.) and a minimum number of installed apps or startup programs. However, just the computer with the lowest resources (CPU/RAM) works best, the editor is very fast there, it's perfect. On all other computers, the Purebasic IDE is very slow. That means, that all Purebasic preferences have nothing to do with the problem. Indeed, turning off autocomplete or folding has a very little effect when editing, it's hardly noticeable.

Meanwhile I even tried Purebasic version 4.x - no effect, same problems.

[PBJim]

On all other computers, the Purebasic IDE is very slow. That means, that all Purebasic preferences have nothing to do with the problem. Indeed, turning off autocomplete or folding has a very little effect when editing, it's hardly noticeable.

Meanwhile I even tried Purebasic version 4.x - no effect, same problems.

My observation, since working with PB for the past year or two, is that the IDE pane on the right side, which includes the tabs for Procedure viewer, Form and so on, is quite a performance bottleneck and I note that it performs heavy processing in background. I've had some problems with it appearing to pause my system, while it draws. My first system (a laptop running PB inside a VM) was more sensitive to this and used to freeze for a period of time, similar to what's been described in other posters' comments.

Is it possible to add an option to temporarily disable that pane and for those who experience this problem, see if it resolves? I wouldn't be surprised if it's related.

[dangerfreak]

I already disabled everything there - no effect.

[PBJim]

I already disabled everything there - no effect.

Right, I saw there's an option to hide the panel, but it's only a hide. There are a few forum members who've recompiled the IDE in the past, so I wonder if something is possible by way of complete removal, just to see.

[mk-soft]

Did you perhaps have files open on the network path?
If the path cannot be reached cleanly, starting the IDE can be very slow.

Clean-up tool.

Code: Select all

;-TOP

#ProgramTitle = "Purebasic Preferences Cleaner (No warranty)"
#ProgramCopyright = "©2022 by mk-soft (License MIT)"
#ProgramVersion = "v1.01.3"
#ProgramAbout = #ProgramTitle + #LF$ + #LF$ + #ProgramCopyright + #LF$ + #ProgramVersion

Enumeration Windows
  #Main
EndEnumeration

Enumeration MenuBar
  #MainMenu
EndEnumeration

Enumeration MenuItems
  #MainMenuAbout
  #MainMenuExit
EndEnumeration

Enumeration Gadgets
  #MainList
  #MainButtonRead
  #MainButtonCleanup
EndEnumeration

Enumeration StatusBar
  #MainStatusBar
EndEnumeration

; ----

Global IsRead
Global ExplorerPath.s
Global HistorySize
Global ProjectSize
Global OpenedSize
Global OpenedProject.s

Global NewList RecentFiles.s()
Global NewList RecentProject.s()
Global NewList OpenedFiles.s()

; ----

Procedure AddInfo(Text.s)
  AddGadgetItem(#MainList, -1, Text)
EndProcedure

; ----

Procedure.s GetPreferencesPath()
  Protected path.s
  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Linux
      path = GetHomeDirectory()
      path + ".purebasic/"
  
    CompilerCase #PB_OS_MacOS
      path = GetHomeDirectory()
      path + ".purebasic/"
      
    CompilerCase #PB_OS_Windows
      path = GetUserDirectory(#PB_Directory_ProgramData)
      path + "purebasic/"
      
  CompilerEndSelect
  
  ProcedureReturn path
    
EndProcedure

; ----

Procedure IsNetPath(File.s)
  Protected r1, path.s
  
  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_MacOS
      path = "/Volumes/"
      If Left(File, 9) = path
        r1 = #True
      EndIf
    CompilerCase #PB_OS_Windows
      path = "\\"
      If Left(File, 2) = path
        r1 = #True
      EndIf
    CompilerCase #PB_OS_Linux
      path = "smb-share:"
      If FindString(File, path, 1, #PB_String_NoCase)
        r1 = #True
      EndIf
  CompilerEndSelect
  ProcedureReturn r1
EndProcedure

; ----

Procedure ReadPreferencesFile()
  Protected r1, filename.s, key.s, cnt, temp.s
  
  ExplorerPath = ""
  HistorySize = 0
  OpenedFiles = 0
  ClearList(RecentFiles())
  ClearList(RecentProject())
  ClearList(OpenedFiles())
  
  filename = GetPreferencesPath() + "purebasic.prefs"
  If OpenPreferences(filename)
    AddInfo("Explorer")
    If PreferenceGroup("Explorer")
      ExplorerPath = ReadPreferenceString("path", "")
      If IsNetPath(ExplorerPath)
        AddInfo("! Path: " + ExplorerPath)
      Else
        AddInfo("- Path: " + ExplorerPath)
      EndIf  
    EndIf
    
    AddInfo("RecentFiles")
    If PreferenceGroup("RecentFiles")
      HistorySize = ReadPreferenceInteger("HistorySize", 0)
      AddInfo("- HistorySize: " + HistorySize)
      cnt = 0
      Repeat
        cnt + 1
        key = "RecentFile_" + cnt
        temp = ReadPreferenceString(key, "")
        If temp
          AddElement(RecentFiles())
          RecentFiles() = temp
          If IsNetPath(temp)
            AddInfo("! " + key + ": " + temp)
          Else
            AddInfo("- " + key + ": " + temp)
          EndIf  
        Else
          Break
        EndIf
      ForEver
      cnt = 0
      Repeat
        cnt + 1
        key = "RecentProject_" + cnt
        temp = ReadPreferenceString(key, "")
        If temp
          AddElement(RecentProject())
          RecentProject() = temp
          If IsNetPath(temp)
            AddInfo("! " + key + ": " + temp)
          Else
            AddInfo("- " + key + ": " + temp)
          EndIf  
        Else
          Break
        EndIf
      ForEver
      ProjectSize = ListSize(RecentProject())
    EndIf
    
    AddInfo("OpenedFiles")
    If PreferenceGroup("OpenedFiles")
      OpenedSize = ReadPreferenceInteger("Count", 0)
      AddInfo("- Count: " + OpenedSize)
      cnt = 0
      Repeat
        cnt + 1
        key = "OpenedFile_" + cnt
        temp = ReadPreferenceString(key, "")
        If temp
          AddElement(OpenedFiles())
          OpenedFiles() = temp
          If IsNetPath(temp)
            AddInfo("! " + key + ": " + temp)
          Else
            AddInfo("- " + key + ": " + temp)
          EndIf  
        Else
          Break
        EndIf
      ForEver
      key = "OpenedProject"
      OpenedProject = ReadPreferenceString(key, "")
      If IsNetPath(OpenedProject)
        AddInfo("! " + key + ": " + temp)
      Else
        AddInfo("- " + key + ": " + temp)
      EndIf  
    EndIf
    ClosePreferences()
    r1 = #True
  Else
    AddInfo("Can't open preferences file!")
    r1 = #False
  EndIf
  
  ProcedureReturn r1
  
EndProcedure

; ----

Procedure CleanUpPreferencesFile()
  Protected r1, filename.s, key.s, cnt, temp.s, path.s, len, do
  
  AddInfo("Start CleanUp ...")
  
  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_MacOS
      path = "/Volumes/"
      len = Len(path)
      
    CompilerCase #PB_OS_Windows
      path = #PS$ + #PS$
      len = Len(path)
      
    CompilerCase #PB_OS_Linux
      path = "smb-share:"
      len = 0
      
  CompilerEndSelect
  
  filename = GetPreferencesPath() + "purebasic.prefs"
  If OpenPreferences(filename)
    AddInfo("Explorer")
    If PreferenceGroup("Explorer")
      If IsNetPath(ExplorerPath)
        ExplorerPath = GetHomeDirectory()
        WritePreferenceString("path", ExplorerPath)
        AddInfo("- Update Path: " + ExplorerPath)
      Else
        AddInfo("- No change")
      EndIf
    EndIf
    
    AddInfo("RecentFiles")
    If PreferenceGroup("RecentFiles")
      do = #False
      ForEach RecentFiles()
        If IsNetPath(RecentFiles())
          DeleteElement(RecentFiles())
          do = #True
        EndIf
      Next
      If do
        For cnt = 1 To HistorySize
          key = "RecentFile_" + cnt
          RemovePreferenceKey(key)
        Next
        HistorySize = ListSize(RecentFiles())
        WritePreferenceInteger("HistorySize", HistorySize)
        AddInfo("- Update HistorySize: " + HistorySize)
        
        cnt = 0
        ForEach RecentFiles()
          cnt + 1
          key = "RecentFile_" + cnt
          temp = RecentFiles()
          WritePreferenceString(key, temp)
          AddInfo("- Update " + key + ": " + temp)
        Next
      Else
        AddInfo("- No change recent files")
      EndIf
      
      do = #False
      ForEach RecentProject()
        If IsNetPath(RecentProject())
          DeleteElement(RecentProject())
          do = #True
        EndIf
      Next
      If do
        For cnt = 1 To ProjectSize
          key = "RecentProject_" + cnt
          RemovePreferenceKey(key)
        Next
        cnt = 0
        ForEach RecentProject()
          cnt + 1
          key = "RecentProject_" + cnt
          temp = RecentProject()
          WritePreferenceString(key, temp)
          AddInfo("- Update " + key + ": " + temp)
        Next
      Else
        AddInfo("- No change recent projects")
      EndIf
        
    EndIf
    
    AddInfo("OpenedFiles")
    If PreferenceGroup("OpenedFiles")
      do = #False
      ForEach OpenedFiles()
        If IsNetPath(OpenedFiles())
          DeleteElement(OpenedFiles())
          do = #True
        EndIf
      Next
      If do
        For cnt = 1 To OpenedSize
          key = "OpenedFile_" + cnt
          RemovePreferenceKey(key)
        Next
        OpenedSize = ListSize(OpenedFiles())
        WritePreferenceInteger("Count", OpenedSize)
        AddInfo("- Update Count: " + OpenedSize)
        
        cnt = 0
        ForEach OpenedFiles()
          cnt + 1
          key = "OpenedFile_" + cnt
          temp = OpenedFiles()
          WritePreferenceString(key, temp)
          AddInfo("- Update " + key + ": " + temp)
        Next
      Else
        AddInfo("- No change opened files")
      EndIf
      If IsNetPath(OpenedProject)
        key = "OpenedProject"
        temp = "[Nothing]"
        WritePreferenceString(key, "")
        AddInfo("- Clear OpenedProject " + key + ": " + temp)
      Else
        AddInfo("- No change opened project")
      EndIf
    EndIf
    ClosePreferences()
    r1 = #True
    AddInfo("Finished CleanUp.")
  Else
    AddInfo("Can't open preferences file!")
    r1 = #False
  EndIf
  
  ProcedureReturn r1
  
EndProcedure

Procedure UpdateWindow()
  Protected dx, dy
  dx = WindowWidth(#Main)
  dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
  ; Resize gadgets
  ResizeGadget(#MainList, 5, 5, dx -10, dy - 45)
  ResizeGadget(#MainButtonRead, 10, dy - 35, 120, 30)
  ResizeGadget(#MainButtonCleanup, dx - 130, dy - 35, 120, 30)
  EndProcedure

Procedure Main()
  Protected dx, dy
  Protected r1
  
  #MainStyle = #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
  
  If OpenWindow(#Main, #PB_Ignore, #PB_Ignore, 800, 600, #ProgramTitle , #MainStyle)
    ; Menu
    CreateMenu(#MainMenu, WindowID(#Main))
    MenuTitle("&File")
    CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
      MenuItem(#PB_Menu_About, "")
    CompilerElse
      MenuItem(#MainMenuAbout, "About")
      MenuBar()
    CompilerEndIf
    
    MenuItem(#MainMenuExit, "E&xit")
    
    ; StatusBar
    CreateStatusBar(#MainStatusBar, WindowID(#Main))
    AddStatusBarField(#PB_Ignore)
    
    ; Gadgets
    dx = WindowWidth(#Main)
    dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
    ListViewGadget(#MainList, 5, 5, dx - 10, dy - 45)
    ButtonGadget(#MainButtonRead, 10, dy - 35, 120, 30, "Read")
    ButtonGadget(#MainButtonCleanup, dx - 130, dy - 35, 120, 30, "CleanUp")
    
    ; Bind Events
    BindEvent(#PB_Event_SizeWindow, @UpdateWindow(), #Main)
    
    ; Event Loop
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Select EventWindow()
            Case #Main
              Break
              
          EndSelect
          
        Case #PB_Event_Menu
          Select EventMenu()
            CompilerIf #PB_Compiler_OS = #PB_OS_MacOS   
              Case #PB_Menu_About
                PostEvent(#PB_Event_Menu, #Main, #MainMenuAbout)
                
              Case #PB_Menu_Preferences
                
              Case #PB_Menu_Quit
                PostEvent(#PB_Event_CloseWindow, #Main, #Null)
                
            CompilerEndIf
            
          Case #MainMenuAbout
            MessageRequester("About", #ProgramAbout, #PB_MessageRequester_Info)
              
          Case #MainMenuExit
            PostEvent(#PB_Event_CloseWindow, #Main, #Null)
            
          EndSelect
          
        Case #PB_Event_Gadget
          Select EventGadget()
            Case #MainButtonRead
              ClearGadgetItems(#MainList)
              IsRead = ReadPreferencesFile()
              
            Case #MainButtonCleanup
              If IsRead
                r1 = MessageRequester("Question", "Start Preferences CleanUp?", #PB_MessageRequester_Warning | #PB_MessageRequester_YesNo)
                If r1 = #PB_MessageRequester_Yes
                  ClearGadgetItems(#MainList)
                  CleanUpPreferencesFile()
                EndIf
              EndIf
              
          EndSelect
          
      EndSelect
    ForEver
    
  EndIf
  
EndProcedure : Main()

[dangerfreak]

Result:

Start CleanUp ...
Explorer
- No change
RecentFiles
- No change recent files
- No change recent projects
OpenedFiles
- No change opened files
- No change opened project
Finished CleanUp.

No effect.

[ChrisR]

Maybe you can take a look with Process Monitor
By adding filters: Process Name is PureBasic.exe include, operation is CreateFile include
And capturing PureBasic.exe startup + menu File > Preference and then stopping it once the Preference window is displayed.
Then take a look at "Time of day" column if it's fluid and also to Result <> "SUCCESS"

[dangerfreak]

Nothing unusual when opening preferences:

07:30:44,3189619 PureBasic.exe CreateFile ...\Purebasic64\Catalogs Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3190354 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Compiler.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3301233 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Debugger.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3354263 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Editor.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3459113 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Libraries.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3501917 PureBasic.exe CreateFile ...\Purebasic64\Catalogs Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3502521 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Deutsch Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3503095 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Deutsch\Compiler.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3559357 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Deutsch\Debugger.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3596502 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Deutsch\Editor.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3677622 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Deutsch\Libraries.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3715290 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Francais Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3715846 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Francais\Compiler.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3772746 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Francais\Debugger.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3813707 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Francais\Editor.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3898721 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Francais\Libraries.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3936764 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Italian Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3937317 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Italian\Compiler.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,3973641 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Italian\Debugger.Catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,4020696 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Italian\Editor.Catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,4106737 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Italian\Libraries.Catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,4145112 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Spanish Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,4145615 PureBasic.exe CreateFile ...\Purebasic64\Catalogs\Spanish\Editor.catalog Desired Access: Generic Read/Write, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,5853535 PureBasic.exe CreateFile ...\Purebasic64\Themes Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,5854382 PureBasic.exe CreateFile ...\Purebasic64\Themes\SilkTheme.zip Desired Access: Generic Read, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: None, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:30:44,8135166 PureBasic.exe CreateFile ...\AppData\Roaming\PureBasic Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS

...and nothing unusual when opening my project file:

07:36:45,0628845 PureBasic.exe CreateFile ...\myProgram\myProgram117test.pb Desired Access: Generic Read, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: None, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1199013 PureBasic.exe CreateFile ...\myProgram Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1200323 PureBasic.exe CreateFile ...\myProgram Desired Access: Read Data/List Directory, Synchronize, Disposition: Open, Options: Directory, Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1201130 PureBasic.exe CreateFile ...\myProgram\myProgram117test.pb Desired Access: Generic Read, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: N, ShareMode: Read, AllocationSize: n/a SHARING VIOLATION
07:36:45,1203471 PureBasic.exe CreateFile C:\Windows\System32\policymanager.dll Desired Access: Read Attributes, Disposition: Open, Options: Open Reparse Point, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1204135 PureBasic.exe CreateFile C:\Windows\System32\policymanager.dll Desired Access: Read Data/List Directory, Execute/Traverse, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: n/a, ShareMode: Read, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1204844 PureBasic.exe CreateFile C:\ Desired Access: Generic Read, Disposition: Open, Options: , Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1208478 PureBasic.exe CreateFile ...\Purebasic64\msvcp110_win.dll Desired Access: Read Attributes, Disposition: Open, Options: Open Reparse Point, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a NAME NOT FOUND
07:36:45,1210679 PureBasic.exe CreateFile C:\Windows\System32\msvcp110_win.dll Desired Access: Read Attributes, Disposition: Open, Options: Open Reparse Point, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1211252 PureBasic.exe CreateFile C:\Windows\System32\msvcp110_win.dll Desired Access: Read Data/List Directory, Execute/Traverse, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Non-Directory File, Attributes: n/a, ShareMode: Read, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1211941 PureBasic.exe CreateFile C:\ Desired Access: Generic Read, Disposition: Open, Options: , Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1225190 PureBasic.exe CreateFile C:\ Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1226174 PureBasic.exe CreateFile C:\DF Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1226955 PureBasic.exe CreateFile C:\DF\TOOLS Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1228183 PureBasic.exe CreateFile C:\DF\TOOLS\LANG Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1229018 PureBasic.exe CreateFile C:\DF\TOOLS\LANG\PureBasic Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1229864 PureBasic.exe CreateFile ... Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS
07:36:45,1230673 PureBasic.exe CreateFile ...\myProgram Desired Access: Read Data/List Directory, Read Attributes, Synchronize, Disposition: Open, Options: Synchronous IO Non-Alert, Attributes: n/a, ShareMode: Read, Write, Delete, AllocationSize: n/a, OpenResult: Opened SUCCESS

[AZJIO]

How many files are opened? My 24 files also open in a few seconds, this is normal. This is not your personal problem.

[dangerfreak]

How many files are opened? My 24 files also open in a few seconds, this is normal. This is not your personal problem.

Only 1 file (297kb, takes 20 seconds until the cursor appears after opening the file)

[AZJIO]

I opened 1 file PureAutoIt.pbi (248 kb). Then I closed the IDE. I open it again with this one file and the cursor is available after 7 seconds.
CPU G3260 3.3 GHz
Win10 x64

If I add a file to an open IDE editor, it is available in a second and a half.