Wishlist for Structure like in C?

[threedslider]

Can we have Structures in PB like C programming for example :

Code: Select all

Structure Type
  x.f
  y.f
  z.f
EndStructure

Procedure.Type init(_x.f, _y.f, _z.f)
  var.Type
  
  var\x = _x
  var\y = _y
  var\z = _z
  
  ProcedureReturn var
EndProcedure

other_var.Type

other_var = init(0.0, 0.0, 0.0)

it is a wishlist for everyone and can make more easier in programming !

Please adding this feature !

[DarkDragon]

There are structures like in C already?! Or do you mean structured return values? You can return a pointer.

[threedslider]

@DarkDragon : I need the function stuff for structure and return type as complex expression like to C but in PB

[DarkDragon]

@DarkDragon : I need the function stuff for structure and return type as complex expression like to C but in PB

Code: Select all

Structure Type
  x.f
  y.f
  z.f
EndStructure

Procedure.i init(_x.f, _y.f, _z.f)
  Protected *var.Type
  
  *var = AllocateStructure(Type)
  
  *var\x = _x
  *var\y = _y
  *var\z = _z
  
  ProcedureReturn *var
EndProcedure

Define *other_var.Type

*other_var = init(0.0, 1.0, 2.0)
If *other_var <> #Null
  Debug *other_var\x
  Debug *other_var\y
  Debug *other_var\z
  FreeStructure(*other_var)
EndIf

[threedslider]

Wow ! It is so flexible this PB !!

Thanks for your tips @DarkDragon !

[mk-soft]

Fast mode ...

Code: Select all

Structure sData
  x.f
  y.f
  z.f
EndStructure

DataSection
  mydefaultdata:
  Data.f 0.0, 1.0, 2.0
EndDataSection

Global myData.sData

CopyMemory(?mydefaultdata, @myData, SizeOf(myData))
Debug myData\x
Debug myData\y
Debug myData\z

[threedslider]

Nice @mk-soft !

Any is there to use a type of structure only without using the cost of memory ? For example returning only structure type without pointer ?

Thanks.

[mk-soft]

The struture type is only available at compile time.
There is no structure information at runtime. This means that no memory is used for it.

[sst]

Another solution:

Code: Select all

EnableExplicit

Structure Type
  x.f
  y.f
  z.f
EndStructure


Procedure init(_x.f,_y.f,_z.f, *a.Type)
  *a\x=_x.f
  *a\y=_y.f
  *a\z=_z.f
 EndProcedure
  
  
 Define other_var.Type
 
 init(1,2,3,@other_var)
 
 
 Debug other_var\x                             ;1.0
 Debug other_var\y                             ;2.0
 Debug other_var\z                             ;3.0

[threedslider]

@sst : Wow ! You are new and given the solution is great

Thank you a lot