TreeGadget Event

[rndrei]

Why does the debugger message that the menu item so-and-so is selected every other time?

Code: Select all

#TREE=100
If OpenWindow(0, 0, 0, 355, 180, "TreeGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
       TreeGadget(#TREE, 10, 10, 160, 160)                                        
       AddGadgetItem (#TREE, -1, "Sub1 ", 0,0)       
         AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
         AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
       AddGadgetItem (#TREE, -1, "Sub2 ", 0, 0) 
         AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
         AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
         AddGadgetItem (#TREE, -1, "Sub 3 ",0,1)
         AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)    
         AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
       AddGadgetItem (#TREE, -1, "Sub 4 ", 0, 0) 
         AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
         AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
         AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)       
       Repeat : 
         EventID=WaitWindowEvent()  
           Select Eventid 
             Case #PB_Event_CloseWindow      
                  End
             Case #PB_Event_Gadget
              If EventGadget()=#TREE And EventType()=#PB_EventType_Change 
                Debug "#PB_EventType_change"
                SelectedItem=GetGadgetState(#TREE)
                Debug("select "+  GetGadgetItemText(#TREE,SelectedItem))
              EndIf
           EndSelect                                    
         Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

[TI-994A]

Why does the debugger message that the menu item so-and-so is selected every other time?

Because WaitWindowEvent() is being called twice in the loop. Fixed here:

Code: Select all

#TREE=100
If OpenWindow(0, 0, 0, 355, 180, "TreeGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  TreeGadget(#TREE, 10, 10, 160, 160)     
  
  AddGadgetItem(#TREE, -1, "Sub1 ", 0, 0)       
  AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
  AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
  
  AddGadgetItem(#TREE, -1, "Sub2 ", 0, 0) 
  AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
  AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
  
  AddGadgetItem(#TREE, -1, "Sub 3 ",0,1)
  AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)    
  AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)
  
  AddGadgetItem(#TREE, -1, "Sub 4 ", 0, 0) 
  AddGadgetItem(#TREE, -1, "Sub-Item 1", 0, 1)   
  AddGadgetItem(#TREE, -1, "Sub-Item 2", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 3", 0, 1)
  AddGadgetItem(#TREE, -1, "Sub-Item 4", 0, 1)   
  
  Repeat
    EventID=WaitWindowEvent()  
    Select EventID 
      Case #PB_Event_CloseWindow      
        End
      Case #PB_Event_Gadget
        If EventGadget()=#TREE And EventType()=#PB_EventType_Change 
          Debug "#PB_EventType_change"
          SelectedItem=GetGadgetState(#TREE)
          Debug("select "+  GetGadgetItemText(#TREE,SelectedItem))
        EndIf
    EndSelect                                    
  Until EventID = #PB_Event_CloseWindow
EndIf

[rndrei]

Got it! Everything works!