[PB5.31] Spin gadget accepting text

[marcoagpinto]

Hello!

Code: Select all

#Range = 10

If OpenWindow(0, 0, 0, 140, 70, "SpinGadget",#PB_Window_ScreenCentered)
    SpinGadget     (0, 20, 20, 100, 25, -#Range, #Range,#PB_Spin_Numeric)
    SetGadgetState (0, 0) : SetGadgetText(0, "0") 
    Repeat
      Event = WaitWindowEvent()
      
      
    Until Event = #PB_Event_CloseWindow
  EndIf

It allows to write text and characters in the text box.

Shouldn't #PB_Spin_Numeric allow only numbers?

[Demivec]

It allows to write text and characters in the text box.

Shouldn't #PB_Spin_Numeric allow only numbers?

This should be posted in the 'Coding Questions' and not as a bug report.

IMHO it isn't a bug.

According to the documentation:

#PB_Spin_Numeric : The SpinGadget will automatically update the text with value of the state, so SetGadgetText() is not needed.

The use of the flag does not limit what can be typed into the SpinGadget.

[ostapas]

Had the same problem just 20 minutes ago! So, in the main window event loop I put this:

Code: Select all

Case #PB_Event_Gadget
  
  If GadgetType(EventGadget()) = #PB_GadgetType_Spin  
    If Not Val(GetGadgetText(EventGadget()))
      SetGadgetState(EventGadget(), 1) ;Whatever default numeric value
    EndIf       
  EndIf

It prevents typing any letters into Spin gadget. Thanks to Fred's anticipation of all possible problems

[Tenaja]

...;Whatever default numeric value

To be user-friendly, you might consider storing the "current value", and if an invalid entry is made, restore it to the previous value. That way if their edit was accidental, they are relieved of the chore of trying to remember, and then re-entering the value.

Fortunately, the SpinGadget stores it for you...

Code: Select all

			Case #PB_Event_Gadget
				If GadgetType(EventGadget()) = #PB_GadgetType_Spin 
					If Not Val(GetGadgetText(EventGadget()))
						SetGadgetState(0,GetGadgetState(0))    ; reset text to its current numeric value
					EndIf       
				EndIf

[dibor]

Thanks for the trick, but he do not prevent to put text like 7ut, or 4r ....

[ChrisR]

For Windows, you can add ES_NUMBER style. It allows only digits to be entered into the edit control.
Note that, even with this set, it is still possible to paste non-digits into the edit control.

Code: Select all

SetWindowLongPtr_(GadgetID(#SpinGadget), #GWL_STYLE, GetWindowLongPtr_(GadgetID(#SpinGadget), #GWL_STYLE) | #ES_NUMBER)

[dibor]

Thank you.
But impossible to put negative numbers
Any other solution?
Also would like to know solution for MacOS.

[ChrisR]

You can try with something like that:

Code: Select all

EnableExplicit

Enumeration Window
  #Window_0
EndEnumeration

Enumeration Gadgets
  #Spin_1
EndEnumeration

Procedure Open_Window_0(X = 0, Y = 0, Width = 280, Height = 200)
  If OpenWindow(#Window_0, X, Y, Width, Height, "Title", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    SpinGadget(#Spin_1, 10, 20, 250, 24, -1000, 1000, #PB_Spin_Numeric)
    SetGadgetState(#Spin_1, 66)
  EndIf
EndProcedure

Open_Window_0()

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow
      Break
      
    Case #WM_CHAR
      If GetActiveGadget() = #Spin_1
        If EventwParam() = 45
          If FindString(GetGadgetText(#Spin_1), "-", 2)
            SetGadgetState(#Spin_1, GetGadgetState(#Spin_1))   
            ;SendMessage_(GadgetID(#Spin_1), #EM_SETSEL, Len(GetGadgetText(#Spin_1)), Len(GetGadgetText(#Spin_1)))
          EndIf
        ElseIf EventwParam() < 48 Or EventwParam() > 58
          SetGadgetState(#Spin_1, GetGadgetState(#Spin_1))
          ;SendMessage_(GadgetID(#Spin_1), #EM_SETSEL, Len(GetGadgetText(#Spin_1)), Len(GetGadgetText(#Spin_1)))
        EndIf
      EndIf
      
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Spin_1
          SetGadgetState(#Spin_1, GetGadgetState(#Spin_1))
      EndSelect
      
  EndSelect
ForEver

[dibor]

Thank you Chris.
Still find solution for MacOS.

Best Wishes.

[dibor]

With SetGadgetState every Gadget event do not need to do any manipulations.

Code: Select all

EnableExplicit

Enumeration Window
  #Window_0
EndEnumeration

Enumeration Gadgets
  #Spin_1
EndEnumeration

Procedure Open_Window_0(X = 0, Y = 0, Width = 280, Height = 200)
  If OpenWindow(#Window_0, X, Y, Width, Height, "Title", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    SpinGadget(#Spin_1, 10, 20, 250, 24, -1000, 1000, #PB_Spin_Numeric)
    SetGadgetState(#Spin_1, 66)
  EndIf
EndProcedure

Open_Window_0()

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow
      Break
    
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Spin_1
            SetGadgetState(#Spin_1, GetGadgetState(#Spin_1))
            Debug GetGadgetText(#Spin_1)
      EndSelect
      
  EndSelect
ForEver

[mk-soft]

Nice hack

[dibor]

In MacOS this trick doesn't works