How to make the pause button work in below program

[Allen]

Hi,

In below code, when I press the PAUSE button, the program did not pause. Any suggestion?

Thanks

Allen

Code: Select all

Enumeration FormWindow
  #Main
  #Start
  #Pause
EndEnumeration

Procedure Events(event)
  Define.b stop
  Define.i i
  Select event
    Case #PB_Event_CloseWindow
      ProcedureReturn #False
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Start
          Repeat
            i=12 ; main operation here
          Until stop
          MessageRequester("Pause","Pause pressed")
          Stop=#False
        Case #Pause
          Stop=#True
      EndSelect
  EndSelect
EndProcedure

MainWindow=OpenWindow(#Main, 100, 100, 100, 100, "Test", #PB_Window_SystemMenu | #PB_Window_MinimizeGadget)
ButtonGadget(#Start,10,10,50,20,"Start"):ButtonGadget(#Pause,10,30,50,20,"Pause")

Repeat 
  event = WaitWindowEvent()
  Events (event)
Until event = #PB_Event_CloseWindow 

[Mindphazer]

First thing i see, when you click on Start, you enter an infinite loop :

Code: Select all

Repeat
  i = 12
until stop

Stop never assigns a value, so you never leave the loop

Second point, your MessageRequester should be inside Case #Pause lik this :

Code: Select all

Case #Pause
    MessageRequester("Pause","Pause pressed")
    Stop=#True
EndSelect

[skywalk]

You set the stop variable only in the pause button.
The start gui is in an infinite loop.

Search for mk-soft, infratec examples of PostEvent() using custom messages.

[mk-soft]

Never stop or interrupt the EventLoop, otherwise no more events will be processed.
Also do not use Delay(), otherwise the events will jam.

To process something served in the MainLoop, you can work via Windows Timer, or outsource it in a thread. With threads one must consider however one more.

See example: Mini Thread Control

Code: Select all

Enumeration FormWindow
  #Main
  #Start
  #Pause
EndEnumeration

Procedure DoAny()
  Static cnt
  cnt + 1
  Debug cnt
EndProcedure

Procedure Events(event)
  Define.b stop
  Define.i i
  Select event
    Case #PB_Event_CloseWindow
      ProcedureReturn #False
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Start
          Stop=#False
          AddWindowTimer(#Main, 1, 1000)
          
        Case #Pause
          Stop=#True
          RemoveWindowTimer(#Main, 1)
      EndSelect
      
    Case #PB_Event_Timer
      Select EventTimer()
        Case 1
          DoAny()
          
      EndSelect
      
  EndSelect
EndProcedure

MainWindow=OpenWindow(#Main, 100, 100, 100, 100, "Test", #PB_Window_SystemMenu | #PB_Window_MinimizeGadget)
ButtonGadget(#Start,10,10,50,20,"Start"):ButtonGadget(#Pause,10,30,50,20,"Pause")

Repeat 
  event = WaitWindowEvent()
  Events (event)
Until event = #PB_Event_CloseWindow 

[Allen]

Thanks everyone for all the advice. I shall study and learn from your examples.

Allen