Remove the extension part of a file.

[Seldon]

Just a tiny function I needed. Maybe it can be useful for someone else.

Code: Select all

Declare.s RemoveExtensionPart(File$)

FileName$="pinco.exe"
Debug RemoveExtensionPart(FileName$)

Procedure.s RemoveExtensionPart(File$)
  Protected tmp$
  tmp$=GetExtensionPart(File$)
  If tmp$
    tmp$="."+tmp$
    ProcedureReturn(RemoveString(File$,tmp$))
  EndIf
  ProcedureReturn("")
EndProcedure

[ts-soft]

thx,

here a bit shorter (not a procedure)

Code: Select all

FileName$="pinco.exe"
Debug Left(FileName$, Len(FileName$)  -  Len(GetExtensionPart(FileName$))  - 1)

Greetings
Thomas

[Demivec]

There seem to be some inconsistencies with the version by Seldon and by ts-soft.

I did a variation of Seldon's code, calling it RemoveExtensionPart2(), that corrects the return value when there is no extension present.

Code: Select all

Procedure.s RemoveExtensionPart(File$)
  Protected tmp$
  tmp$=GetExtensionPart(File$)
  If tmp$
    tmp$="."+tmp$
    ProcedureReturn(RemoveString(File$,tmp$))
  EndIf
  ProcedureReturn("")
EndProcedure

Procedure.s RemoveExtensionPart2(File$)
  Protected tmp$
  tmp$=GetExtensionPart(File$)
  If tmp$
    tmp$="."+tmp$
    ProcedureReturn(RemoveString(File$,tmp$))
  EndIf
  ProcedureReturn File$
EndProcedure

Debug "filename: " + Chr(34) + filename$ + Chr(34)
filename$="pinco.exe"
Debug RemoveExtensionPart(filename$)
Debug RemoveExtensionPart2(filename$)
Debug Left(filename$, Len(filename$)  -  Len(GetExtensionPart(filename$))  - 1)

filename$="pinco."
Debug "filename: " + Chr(34) + filename$ + Chr(34)
Debug RemoveExtensionPart(filename$) ;fails
Debug RemoveExtensionPart2(filename$)
Debug Left(filename$, Len(filename$)  -  Len(GetExtensionPart(filename$))  - 1)

filename$="pinco"
Debug "filename: " + Chr(34) + filename$ + Chr(34)
Debug RemoveExtensionPart(filename$) ;fails
Debug RemoveExtensionPart2(filename$)
Debug Left(filename$, Len(filename$)  -  Len(GetExtensionPart(filename$))  - 1) ;fails

[Seymour Clufley]

Here's what I always do:

Code: Select all

ext.s = StringField(filename+".",2,".")

Safer:

Code: Select all

dots = CountString(filename,".")
ext.s = StringField(filename+".",dots+1,".")

[Little John]

I did a variation of Seldon's code, calling it RemoveExtensionPart2(), that corrects the return value when there is no extension present.

Yes, that correction was necessary.
Here is my variation:

Code: Select all

Procedure.s RemoveExtensionPart (file$)
   Protected lenExt

   lenExt = Len(GetExtensionPart(file$))
   If lenExt
      ProcedureReturn(Left(file$, Len(file$)-lenExt-1))
   Else
      ProcedureReturn file$
   EndIf
EndProcedure

Regards, Little John

[ts-soft]

saferversion:

Code: Select all

FileName$ = "pinco"
If GetExtensionPart(FileName$)
  Debug Left(FileName$, Len(FileName$)  -  Len(GetExtensionPart(FileName$))  - 1)
Else
  Debug FileName$
EndIf

[Little John]

saferversion:

Thomas, do you mean that this version is safer than mine? If so, why do you think so? Both versions are almost equal.

Regards, Little John

[ts-soft]

saferversion:

Thomas, do you mean that this version is safer than mine? If so, why do you think so? Both versions are almost equal.

Regards, Little John

Is Safer than my first version

[blueznl]

[breeze4me]

Windows only.

Code: Select all

file.s{1024} = "c:\my files\my data.ico file.ico"

PathRemoveExtension_(@file)

Debug file  ; c:\my files\my data.ico file

[Seldon]

Thanks for all suggestions. OK, I've just collected the best solutions (IMHO).

Code: Select all

Declare.s RemoveExtensionPart(File$)

FileName$="pinco.exe"
Debug RemoveExtensionPart(FileName$)

Procedure.s RemoveExtensionPart(File$)
CompilerIf #PB_Compiler_OS<>#PB_OS_Windows
  Protected extension_length
  extension_length=Len(GetExtensionPart(File$))
  If extension_length
    ProcedureReturn(Left(File$,Len(File$)-extension_length-1))
  EndIf
  ProcedureReturn(File$)
CompilerElse
  Protected tmp$=File$
  PathRemoveExtension_(@tmp$)
  ProcedureReturn(tmp$)
CompilerEndIf
EndProcedure

[Joakim Christiansen]

saferversion:

Code: Select all

FileName$ = "pinco"
If GetExtensionPart(FileName$)
  Debug Left(FileName$, Len(FileName$)  -  Len(GetExtensionPart(FileName$))  - 1)
Else
  Debug FileName$
EndIf

Also safe:

Code: Select all

filename$ = "this file has no extension"
Debug StringField(filename$,1,".")

filename$ = "this file has a extension.txt"
Debug StringField(filename$,1,".")

Can I get a cookie now?

sorry for fooling around, I coluld make a uber nice procedure another day

[Kaeru Gaman]

Also safe:

Code: Select all

filename$ = "this file has no extension"
Debug StringField(filename$,1,".")

filename$ = "this file has a extension.txt"
Debug StringField(filename$,1,".")

Code: Select all

filename$ = "Review 2009.09.23.doc"
Debug StringField(filename$,1,".")

pwned

Can I get a cookie now?

NOPE!

[Kurzer]

No, its not safe. Try this example:

FileName$ = "this file has a extension.txt but its a.doc"
Debug StringField(FileName$,1,".")

No cookie this time!

Edit: Yeah, frogs rulez!

[Hroudtwolf]

Hi,

Just another way...

Code: Select all

; 2009 Hroudtwolf
; PureBasic 4.x

Structure tChar
   StructureUnion
      c.c
      s.s {1}
   EndStructureUnion
EndStructure

Procedure.s removeExtensionPart (sSource.s)
   Protected *sourceStart           = @ sSource
   Protected *sourceEnd    .tChar   = *sourceStart 
   
   If Not (*sourceStart)
      ProcedureReturn sSource
   EndIf
   
   *sourceEnd + StringByteLength (sSource)
   
   While *sourceEnd > *sourceStart 
      
      If *sourceEnd\c = '.'
         *sourceEnd\c = #Null
         Break
      EndIf
      
      *sourceEnd - SizeOf (tChar)
   Wend
   
   ProcedureReturn sSource
EndProcedure

Debug removeExtensionPart ("thisismyfilename.ext.ext.bla.blup")

Regards
Wolf