[PB 4.1 B4] Textgadget & Events (solved, no pb-bug)

[Kiffi]

Hello,

after a doubleclick with the left mousebutton on the textgadget the
following code shows #PB_EventType_LeftClick and
#PB_EventType_RightClick instead of #PB_EventType_LeftDoubleClick.

Why?

TIA & Greetings ... Kiffi

Code: Select all

OpenWindow(0, #PB_Ignore, #PB_Ignore, 200, 30, "")
CreateGadgetList(WindowID(0))
TextGadget(1, 5, 5, 190, 20, "Click here!", #PB_Text_Border | #SS_NOTIFY)

Repeat
  
  WWE = WaitWindowEvent()
  
  If WWE=#PB_Event_Gadget And EventGadget()=1

    Select EventType()
      Case #PB_EventType_LeftClick        : Debug "#PB_EventType_LeftClick"
      Case #PB_EventType_RightClick       : Debug "#PB_EventType_RightClick"
      Case #PB_EventType_LeftDoubleClick  : Debug "#PB_EventType_LeftDoubleClick"
      Case #PB_EventType_RightDoubleClick : Debug "#PB_EventType_RightDoubleClick"
      Case #PB_EventType_Focus            : Debug "#PB_EventType_Focus"
      Case #PB_EventType_LostFocus        : Debug "#PB_EventType_LostFocus"
      Case #PB_EventType_Change           : Debug "#PB_EventType_Change"
      Case #PB_EventType_DragStart        : Debug "#PB_EventType_DragStart"
    EndSelect
    
  EndIf
  
  
Until WWE=#PB_Event_CloseWindow

[gnozal]

Iirc, #PB_EventType_LeftDoubleClick never worked with static controls (even with #SS_NOTIFY style).
It works with subclassing though.

Code: Select all

Procedure StaticCallback(hwnd, uMsg, wParam, lParam) 
  Protected Result.l
  Shared OldProc
  Result = CallWindowProc_(OldProc, hwnd, uMsg, wParam, lParam) 
  ;
  If uMsg = #WM_LBUTTONDBLCLK
    Debug "Double-click"
  EndIf
  ;
  ProcedureReturn Result
EndProcedure 


OpenWindow(0, #PB_Ignore, #PB_Ignore, 200, 30, "") 
CreateGadgetList(WindowID(0)) 
TextGadget(1, 5, 5, 190, 20, "Click here!", #PB_Text_Border | #SS_NOTIFY) 
OldProc = SetWindowLong_(GadgetID(1), #GWL_WNDPROC, @StaticCallback())  

Repeat 
  WWE = WaitWindowEvent() 
Until WWE=#PB_Event_CloseWindow

[freak]

#SS_NOTIFY is not a PB flag...

[Fred]

A TextGadget() doesn't support any event officially.

[Kiffi]

@Fred & freak: Thanks for your info! I changed the subject of this thread.

@gnozal: Thanks for your solution!

Greetings ... Kiffi