PureBasic Forums - English

Code: Select all

Procedure ContextMenuAddAll(programfriendlyname$, programpath$, state=1, includefolders=0)
  ; netmaestro November 2007 
  Protected key.l = #HKEY_CLASSES_ROOT 
  Protected path$ = "*\shell\"+programfriendlyname$+"\command" 
  Protected value$ = "" 
  Protected string$ = programpath$+" "+Chr(34)+"%1"+Chr(34)  
  Protected keyresult.l 
  If state 
    RegCreateKey_(key,@path$,@keyresult) 
    RegSetValueEx_(keyresult,@value$,0,#REG_SZ,@string$,Len(string$)) 
    If includefolders
      path2$ = "directory\shell\"+programfriendlyname$+"\command"
      RegCreateKey_(key, @path2$, @keyresult)
      If RegSetValueEx_(keyresult,@value$,0,#REG_SZ,@string$,Len(string$)) = #ERROR_SUCCESS 
        result = 1
      Else
        result = 0
      EndIf
    EndIf
  Else 
    path$ = "*\shell\"+programfriendlyname$+"\command" 
    RegDeleteKey_(key,@path$) 
    path$ = "*\shell\"+programfriendlyname$ 
    result1 = RegDeleteKey_(key,@path$) 
    If includefolders
      path2$ = "directory\shell\"+programfriendlyname$+"\command"
      RegDeleteKey_(key,@path2$)     
      path2$ = "directory\shell\"+programfriendlyname$
      result2 = RegDeleteKey_(key,@path2$) 
      If result1 =#ERROR_SUCCESS And result2 = #ERROR_SUCCESS
        result = 1
      Else
        result = 0
      EndIf
    Else
      If result1 = #ERROR_SUCCESS
        result = 1
      Else
        result = 0
      EndIf
    EndIf
  EndIf 
  RegCloseKey_(keyresult)
  ProcedureReturn result
EndProcedure 

Code: Select all

;=======================================
;
;   Creating registry entries for
;   application file association &
;   updating associated file icons
;   
;   by TI-994A  -  6th April, 2012
;
;=======================================

#SHCNE_ASSOCCHANGED = $8000000
#SHCNF_IDLIST = $0

Define.s keyName, keyValue
Define.i Result, keyPtr

;creates an entry for your application
keyName = "MyApp"
keyValue = "My Application to do something"
Result = RegCreateKey_(#HKEY_CLASSES_ROOT, keyName, @keyPtr)
Result = RegSetValue_(keyPtr, "", #REG_SZ, @keyValue, 0)

;creates instructions for command-line launch
keyValue = ProgramFilename() + " %1"
Result = RegSetValue_(keyPtr, "Shell\Open\Command", #REG_SZ, @keyValue, #MAX_PATH)

;sets the associated file icons to match your application
;the icon keyValue can even be a direct icon, for eg: "c:\someIcon.ico"
keyValue = "C:\Users\user\Pictures\Iconos\Ico\konfabulator_icon.ico,-1"
Result = RegSetValue_(keyPtr, "DefaultIcon", #REG_SZ, @keyValue, #MAX_PATH)

;creates the actual file association for the specified extension
keyName = ".myp123"
keyValue = "MyApp"
Result = RegCreateKey_(#HKEY_CLASSES_ROOT, keyName, @keyPtr)
Result = RegSetValue_(keyPtr, "", #REG_SZ, @keyValue, 0)

;effects a system-wide notification of the changes
SHChangeNotify_(#SHCNE_ASSOCCHANGED, #SHCNF_IDLIST, 0, 0)

End

Code: Select all

;=======================================
;
; Creating registry entries for
; application file association &
; updating associated file icons
; 
; by TI-994A - 6th April, 2012
;
;=======================================

#SHCNE_ASSOCCHANGED = $8000000
#SHCNF_IDLIST = $0

Define.s keyName, keyValue
;Define.i Result, keyPtr

;creates an entry for your application
keyName = "MyApp" ;short name of your app
keyValue = "My Application to do something" ;long description of your app
Result = RegCreateKey_(#HKEY_CLASSES_ROOT, keyName, @keyPtr)
Result = RegSetValue_(keyPtr, "", #REG_SZ, @keyValue, 0)

;creates instructions for command-line launch
keyValue = "C:\Test.exe %1" ;replace with ProgramFilename() + " %1"
Result = RegSetValue_(keyPtr, "Shell\Open\Command", #REG_SZ, @keyValue, #MAX_PATH)

;sets the associated file icons to match your application
;the icon keyValue can even be a direct icon, for eg: "c:\someIcon.ico"
keyValue = ProgramFilename() 
Result = RegSetValue_(keyPtr, "DefaultIcon", #REG_SZ, @keyValue, #MAX_PATH)

;creates the actual file association for the specified extension
keyName = ".myext" ;can be anything, for eg: ".mp3"
keyValue = "MyApp"
Result = RegCreateKey_(#HKEY_CLASSES_ROOT, keyName, @keyPtr)
Result = RegSetValue_(keyPtr, "", #REG_SZ, @keyValue, 0)

;effects a system-wide notification of the changes
SHChangeNotify_(#SHCNE_ASSOCCHANGED, #SHCNF_IDLIST, 0, 0)

Code: Select all

RunProgram("ie4uinit -show")