[solution provided by mk-soft] gadget hidden or not?

[eck49]

Is there a way of knowing whether a gadget is hidden or not?

There may be many paths to a particular point in the code, some of which will leave the gadget hidden and some showing.

At this point, I want to fill the gadget (in this case a textgadget), show it and after a while restore its previous content and maybe hide it again. But hide it only if it was previously hidden. All very simple, except for the lack of a function to tell me whether a gadget is currently hidden.

Code: Select all

Protected.i hh
Protected.s st
st = GetGadgetText(#txtgad)
hh = IsVisible(#txtgad)     <<<< or something functionally equivalent
SetGadgetText(#txtgad, "Here is the latest news")
HideGadget(#txtgad, 0)
--do some other stuff--
HideGadget(#txtgad, hh)
SetGadgetText(#txtgad, st)

[Saki]

You can set a flag with SetGadgetData()

[eck49]

@Saki

Wouldn't the flag need to be set every time the gadget was Hidden/Shown? Could be a lot of work! Like having a dedicated variable for the task.

[Keya]

in Windows there is the IsWindowVisible(hWnd) API function, I'm not sure if it works with controls though

[eck49]

@Keya

Nice thought, but I'm on Linux.

[mk-soft]

Code: Select all

;-TOP

; IsGadgetVisible by mk-soft, v1.01.1, 05.06.2021, All OS

CompilerIf #PB_Compiler_OS = #PB_OS_Linux
  ImportC ""
    gtk_widget_is_visible(widget)
  EndImport
CompilerEndIf

Procedure IsGadgetVisible(Gadget)
  
  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Windows
      ProcedureReturn IsWindowVisible_(GadgetID(Gadget))
      
    CompilerCase #PB_OS_MacOS
      ProcedureReturn Bool(Not CocoaMessage(0, GadgetID(Gadget), "isHidden"))
      
    CompilerCase #PB_OS_Linux
      ProcedureReturn gtk_widget_is_visible(GadgetID(Gadget))
      
  CompilerEndSelect
  
EndProcedure

; ****

Enumeration Windows
  #Main
EndEnumeration

Enumeration Gadgets
  #Text
EndEnumeration

Enumeration Status
  #MainStatusBar
EndEnumeration

Procedure Main()
  
  #MainStyle = #PB_Window_SystemMenu | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
  
  If OpenWindow(#Main, #PB_Ignore, #PB_Ignore, 800, 600, "Window" , #MainStyle)
    
    TextGadget(#Text, 10, 10, 790, 25, "Hello World!")
    
    HideGadget(#Text, #True)
    r1 = IsGadgetVisible(#Text)
    Debug r1
    
    HideGadget(#Text, #False)
    r1 = IsGadgetVisible(#Text)
    Debug r1
     
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Break
      EndSelect
    ForEver
    
  EndIf
  
EndProcedure : Main()

[eck49]

@mk-soft

Thanks - great to have your expertise & knowledge on side.
I'll mark as solved although I can't personally vouch for Windows & Mac.

[BarryG]

I can't personally vouch for Windows

This is for Windows:

Code: Select all

Debug IsWindowVisible_(GadgetID(gad))