DrawVectorText() can also multiline output

[Saki]

Hello, everyone,
I notice,
DrawVectorText() can be multiline

This is wrong in the documentary :
"This function draws single lines of text only. Multiple calls must be made to draw multiple lines."

Code: Select all

Define window = OpenWindow(#PB_Any, 0, 0, 600, 300, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
Define canvas = CanvasGadget(#PB_Any, 0, 0, 800, 600)

Define font = LoadFont(#PB_Any, "", 36, #PB_Font_Bold)

Define text$ = "DrawVectorText()"+#LF$+"can also multiline"+#LF$+"output !"+#LF$+"Best regards - Saki"

StartVectorDrawing(CanvasVectorOutput(canvas))

VectorFont(FontID(font))
VectorSourceColor($FFFF0000)

MovePathCursor (100, 10)
DrawVectorText(text$)
StopVectorDrawing()

Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow

[wombats]

It isn't on macOS.

[skywalk]

Interesting
Is this a bug or can we rely on this behavior?

wombats - Can you try #CR$ instead of #LF$?

[Shardik]

Can you try #CR$ instead of #LF$?

No, changing #CR$ to #LF$ or #CRLF$ doesn't change anything on MacOS (PB 5.72 x86 on High Sierra).

[wombats]

Interesting
Is this a bug or can we rely on this behavior?

wombats - Can you try #CR$ instead of #LF$?

Same result.

On Linux, GTK is multiline and Qt is not (tested both #LF$ and #CR$).

[freak]

Only single-line text is supported everywhere. If it works on some OS you cannot rely on it because this may change in the future.

[Danilo]

For multiline:

Code: Select all

Procedure DrawVectorTextPro(text$)
    ;
    ; Multi-line DrawVectorText(). Lines separated by #LF$.
    ;
    Protected count = CountString(text$,#LF$)
    Protected height.d = VectorTextHeight(text$)
    Protected i, x = PathCursorX(), y = PathCursorY()
    For i = 0 To count
        MovePathCursor(x,y+(i*height))
        DrawVectorText(StringField(text$,i+1,#LF$))
    Next
EndProcedure

Define window = OpenWindow(#PB_Any, 0, 0, 600, 300, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
Define canvas = CanvasGadget(#PB_Any, 0, 0, 800, 600)

Define font = LoadFont(#PB_Any, "", 36, #PB_Font_Bold)

Define text$ = "DrawVectorText()"+#LF$+"can also multiline"+#LF$+"output !"+#LF$+"Best regards - Saki"

StartVectorDrawing(CanvasVectorOutput(canvas))

VectorFont(FontID(font))
VectorSourceColor($FFFF0000)

MovePathCursor (100, 10)
RotateCoordinates(100, 10, 20)
DrawVectorTextPro(text$)
StopVectorDrawing()

Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow

[mk-soft]

Now update my DrawTextBox to DrawVectorTextBox

Link: viewtopic.php?f=12&t=75341

[Saki]

Many thanks Danielo.
Its a little but important new function

@MK-Soft:
This is a very nice work
Replacing the line breaks is also amazing

[IdeasVacuum]

Multiline is very useful (Using Danilo's Procedure today!), thanks for sharing guys.

[Saki]

You can do a lot more now

viewtopic.php?f=13&t=75332

Best regards Saki

Code: Select all

; By Danilo
Procedure.d VectorTextWidthPro(text$, flags=#PB_VectorText_Default)
  ; Returns the VectorTextWidth() of the longest line (separated by #LF$)
  ;
  Protected i, width.d, result.d = 0.0, count = CountString(text$,#LF$)
  For i = 0 To count
    width = VectorTextWidth(StringField(text$,i+1,#LF$),flags)
    If width > result
      result = width
    EndIf
  Next
  Debug result
  ProcedureReturn result
EndProcedure

; By Danilo
Procedure.d VectorTextHeightPro(text$, flags=#PB_VectorText_Default)
  ;
  ; Returns the VectorTextHeight() of all lines (separated by #LF$)
  ;
  ProcedureReturn VectorTextHeight(text$, flags) * (CountString(text$,#LF$) + 1)
EndProcedure

; By Danilo
Procedure DrawVectorTextPro(text$, x, y)
  ;
  ; Multi-line DrawVectorText(). Lines separated by #LF$.
  ;
  Protected count = CountString(text$,#LF$)
  Protected height.d = VectorTextHeight(text$)
  Protected i
  For i = 0 To count
    MovePathCursor(x,y+(i*height))
    DrawVectorText(StringField(text$,i+1,#LF$))
  Next
EndProcedure

Define window = OpenWindow(#PB_Any, 0, 0, 800, 600, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
Define canvas = CanvasGadget(#PB_Any, 0, 0, 800, 600)

Define font = LoadFont(#PB_Any, "", 21, #PB_Font_Bold)

Define text$ = "DrawVectorText()"+#LF$+"can also multiline"+#LF$+"output !"+#LF$+"Best regards - Saki"

Define x=200
Define y=0

StartVectorDrawing(CanvasVectorOutput(canvas))

VectorFont(FontID(font))

MovePathCursor (x, y)

RotateCoordinates(y, y, 20)

VectorSourceColor($FF00FFFF)

Define padding=VectorTextwidthPro(Space(6))

AddPathBox(x-padding, y - padding, VectorTextWidthPro(text$) + padding * 2, VectorTextHeightPro(text$))

FillPath()

VectorSourceColor($FF0000FF)

AddPathBox(x-padding, y - padding, VectorTextWidthPro(text$) + padding * 2, VectorTextHeightPro(text$))

StrokePath(6)

VectorSourceColor($FFFF0000)

DrawVectorTextPro(text$, x, y)

StopVectorDrawing()

Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow

[Danilo]

@Saki: You need to change

Code: Select all

AddPathBox(x-padding, y - padding, VectorTextWidthPro(text$) + padding * 2, VectorTextHeightPro(text$))

to

Code: Select all

AddPathBox(x-padding, y - padding, VectorTextWidthPro(text$) + padding * 2, VectorTextHeightPro(text$) + padding * 2)

(2 times)

[Saki]

Hi Danielo,
make a try, its because,
the height calculating is a litte strange

[Danilo]

Hi Danielo,
make a try, its because,
the height calculating is a litte strange

It works on macOS, but maybe you get strange results because you loaded font "". Try to use a font name like "Arial".

[mk-soft]

Unfortunately the font sizes fall differently to the OS.

Part of DrawVectorTextBox example ...

Code: Select all

Define hfont = LoadFont(0, "Arial", 12);, #PB_Font_Bold)
    
    If  StartVectorDrawing(output)
      
      ResetCoordinatesDPI()
      
      CompilerSelect #PB_Compiler_OS
        CompilerCase #PB_OS_Windows
          VectorFont(hfont, 13)
        CompilerCase #PB_OS_MacOS
          VectorFont(hfont, 16)
        CompilerCase #PB_OS_Linux
          VectorFont(hfont, 12)
      CompilerEndSelect