How can i draw transparent text?

[Wolfram]

I would expect that the text in this example is light gray but it is black.
How can I draw the text transparent?

Code: Select all

Global Window_0, canvas


Procedure OpenWindow_0(x = 0, y = 0, width = 440, height = 220)
  Window_0 = OpenWindow(#PB_Any, x, y, width, height, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  canvas = CanvasGadget(#PB_Any, 20, 40, 400, 160)
  
  If StartDrawing(CanvasOutput(canvas))
    
    DrawingMode(#PB_2DDrawing_AlphaChannel)
    
    FrontColor(RGBA(0,0,0, 200))
    BackColor(RGBA(255,255,255, 255))
    
    DrawText(20, 20, "Hello Wold")
    Box(120, 20, 60, 60, RGBA(0,0,0, 128))
    
    StopDrawing()
  EndIf

EndProcedure

Procedure Window_0_Events(event)
  Select event
    Case #PB_Event_CloseWindow
      ProcedureReturn #False

    Case #PB_Event_Menu
      Select EventMenu()
	Case #PB_Menu_Quit
          ProcedureReturn #False
      EndSelect

    Case #PB_Event_Gadget
      Select EventGadget()
        Case canvas
          If EventType() = #PB_EventType_LeftClick
            
          EndIf
      EndSelect
  EndSelect
  ProcedureReturn #True
EndProcedure

OpenWindow_0()

Repeat
  event = WaitWindowEvent()
Until Window_0_Events(event) = #False

[Paul]

The help file says...

The CanvasGadget() does not have an alpha channel so the #PB_2DDrawing_AlphaChannel modes of the DrawingMode() function will have no effect and the #PB_2DDrawing_AllChannels mode will be equivalent to #PB_2DDrawing_Default

[Wolfram]

How can I draw a text so that I can see 50% of the background? In case of a white background a black text will be 50% gray.
If you like you can do it on an image instead of a canvas.

by the way: the background color of the text does what I expect.

[Paul]

This is what your example looks like here under Win7, Win8 & Win10 compiled with PB5.62 x64 & x86
(and I had to comment out the #PB_Menu parts since your code snippet is incomplete)



If I comment out DrawingMode(#PB_2DDrawing_AlphaChannel) then I get



This tells me either the Help file is incorrect stating that "DrawingMode() function will have no effect " or there is a bug

[STARGÅTE]

Code: Select all

    
    DrawingMode(#PB_2DDrawing_AlphaBlend|#PB_2DDrawing_Transparent)
    
    FrontColor(RGBA(0,0,0, 128))
    BackColor(RGBA(255,255,255, 255))
    
    DrawText(20, 20, "Hello Wold")
    Box(120, 20, 60, 60, RGBA(0,0,0, 128))

[Paul]

You're right Stargate, that works... so just wrong use of DrawingMode() in this situation.
(assuming he only wanted to blend his text with the background instead of just modifying the alpha channel... in which case the Help file would be correct)

Code: Select all

If OpenWindow(#PB_Any,0,0,440,220,"",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  canvas = CanvasGadget(#PB_Any, 20, 40, 400, 160)  
  If StartDrawing(CanvasOutput(canvas))    
    DrawingMode(#PB_2DDrawing_Default)
    Box(140,0,200,100,$ff0000)  
  
    DrawingMode(#PB_2DDrawing_AlphaBlend|#PB_2DDrawing_Transparent)    
    FrontColor(RGBA(0,0,0, 128))
    BackColor(RGBA(255,255,255, 255))    
    DrawText(20, 20, "Hello World")
    Box(120, 20, 60, 60, RGBA(0,0,0, 128))
    
    StopDrawing()
  EndIf
  
  Repeat:Until WaitWindowEvent()=#PB_Event_CloseWindow
EndIf

[Wolfram]

Thanks for you help, but here on OSX the text is always black.

Must be a Bug.

Tested on PB 5.42x64 and PB 5.61 x64

[netmaestro]

On OSX a workaround might involve affecting the components to an image and then setting that image to the canvas.