WebGadget disappears

[wombats]

Hi,

Sometimes when the window is maximized/restored, the WebGadget will disappear until the window is resized again. It doesn't happen on macOS, but it does on Windows.

Is there a way to force the WebGadget to reappear?

Code: Select all

If OpenWindow(0, 0, 0, 600, 300, "WebGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget)
  ContainerGadget(1, 0, 0, 580, 280, #PB_Container_Single)
  WebGadget(0, 0, 0, 580, 280, "http://www.purebasic.com")
  CloseGadgetList()
  StringGadget(2, 0, 0, 0, 0, "...")
  SplitterGadget(3, 0, 0, WindowWidth(0), WindowHeight(0), 2, 1, #PB_Splitter_Vertical | #PB_Splitter_FirstFixed)
  SetGadgetState(3, 150)
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        End
      Case #PB_Event_SizeWindow
        ResizeGadget(3, 0, 0, WindowWidth(0), WindowHeight(0))
        ResizeGadget(0, 0, 0, GadgetWidth(1), GadgetHeight(1))
    EndSelect
  ForEver
EndIf

[TI-994A]

...when the window is maximized/restored, the WebGadget will disappear until the window is resized again....

Works perfectly fine (PureBasic v5.62, Windows 10).

[wombats]

The thing is, though...it doesn't always happen. Sometimes it happens frequently and other times not.

[the.weavster]

For me it works if you take out the container:

Code: Select all

If OpenWindow(0, 0, 0, 600, 300, "WebGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget)
  ;ContainerGadget(1, 0, 0, 580, 280, #PB_Container_Single)
  WebGadget(0, 0, 0, 580, 280, "http://www.purebasic.com")
  ;CloseGadgetList()
  StringGadget(2, 0, 0, 0, 0, "...")
  SplitterGadget(3, 0, 0, WindowWidth(0), WindowHeight(0), 2, 0, #PB_Splitter_Vertical | #PB_Splitter_FirstFixed)
  SetGadgetState(3, 150)
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        End
      Case #PB_Event_SizeWindow
        ResizeGadget(3, 0, 0, WindowWidth(0), WindowHeight(0))
        ;ResizeGadget(0, 0, 0, GadgetWidth(1), GadgetHeight(1))
    EndSelect
  ForEver
EndIf

Otherwise the WebGadget doesn't refresh when you move the splitter

[TI-994A]

The thing is, though...it doesn't always happen. Sometimes it happens frequently and other times not.

weavster's right; the web gadget disappears when resizing with the splitter, although still only occasionally.

And removing the container seems to solve the issue.

[the.weavster]

Changing the ContainerGadget() to a CanvasGadget() with the #PB_Canvas_Container flag set works for me:

Code: Select all

If OpenWindow(0,0,0,600,300,"WebGadget",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget)
  ;ContainerGadget(1,0,0,580,280,#PB_Container_Single)
  CanvasGadget(1,0,0,580,280,#PB_Canvas_Container)
  WebGadget(0,0,0,580,280,"http://www.purebasic.com")
  CloseGadgetList()
  StringGadget(2,0,0,0,0,"...")
  SplitterGadget(3,0,0,WindowWidth(0),WindowHeight(0),2,1,#PB_Splitter_Vertical|#PB_Splitter_FirstFixed)
  SetGadgetState(3,150)
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        End
      Case #PB_Event_SizeWindow
        ResizeGadget(3,0,0,WindowWidth(0),WindowHeight(0))
        ResizeGadget(0,0,0,GadgetWidth(1),GadgetHeight(1))

    EndSelect
  ForEver
EndIf

Edit:
Actually I take that back, it doesn't quite work because resizing with the splitter doesn't always make the container fill all the available width but the WebGadget() is now being redrawn.

[wombats]

Changing it to a CanvasGadget with the #PB_Canvas_Container flag is definitely better. It still happens occasionally, but not nearly as often. I guess that's acceptable.

It was only in a ContainerGadget for the border the ContainerGadget provides. It's not a big deal to draw it manually with the CanvasGadget.

Thanks.

[the.weavster]

Even better:

Code: Select all

If OpenWindow(0,0,0,600,300,"WebGadget",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget)
  ;ContainerGadget(1,0,0,580,280,#PB_Container_Single)
  CanvasGadget(1,0,0,580,280,#PB_Canvas_Container)
  WebGadget(0,0,0,580,280,"http://www.purebasic.com")
  CloseGadgetList()
  StringGadget(2,0,0,0,0,"...")
  SplitterGadget(3,0,0,WindowWidth(0),WindowHeight(0),2,1,#PB_Splitter_Vertical|#PB_Splitter_FirstFixed)
  SetGadgetState(3,150)
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        End
      Case #PB_Event_SizeWindow
        ResizeGadget(3,0,0,WindowWidth(0),WindowHeight(0))
        
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 1
            If EventType() = #PB_EventType_Resize
              ResizeGadget(0,0,0,GadgetWidth(1),GadgetHeight(1))
            EndIf
        EndSelect

    EndSelect
  ForEver
EndIf

[RASHAD]

If the problems appears with windows only

Code: Select all

Global Oldproc
CompilerIf #PB_Compiler_OS = #PB_OS_Windows
  Procedure SplitCB(hWnd,uMsg,wParam,lParam)
     Select uMsg
        Case #WM_LBUTTONUP
          ResizeGadget(0, 0, 0, GadgetWidth(1), GadgetHeight(1))
  
     EndSelect   
     ProcedureReturn CallWindowProc_(Oldproc,hWnd,uMsg,wParam,lParam)
  EndProcedure
CompilerEndIf

If OpenWindow(0, 0, 0, 600, 300, "WebGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget)
  ContainerGadget(1, 0, 0, 580, 280, #PB_Container_Single)
    WebGadget(0, 0, 0, 580, 280, "http://www.purebasic.com")
  CloseGadgetList()
  StringGadget(2, 0, 0, 0, 0, "...")
  SplitterGadget(3, 0, 0, WindowWidth(0), WindowHeight(0), 2, 1, #PB_Splitter_Vertical | #PB_Splitter_FirstFixed)
  SetGadgetState(3, 150)
 
  CompilerIf #PB_Compiler_OS = #PB_OS_Windows
    Oldproc = SetWindowLongPtr_(GadgetID(3),#GWL_WNDPROC,@SplitCB())
  CompilerEndIf

  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        End
         
      Case #PB_Event_SizeWindow
        ResizeGadget(3, 0, 0, WindowWidth(0), WindowHeight(0))
        ResizeGadget(0, 0, 0, GadgetWidth(1), GadgetHeight(1))
    EndSelect
  ForEver
EndIf