NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)

Share your advanced PureBasic knowledge/code with the community.
hagibaba
Enthusiast
Enthusiast
Posts: 170
Joined: Fri Mar 05, 2004 2:55 am
Location: UK
Contact:

NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)

Post by hagibaba »

Code updated for 5.20+

This shows how to print 2D texture fonts in OpenGL.
You can get the "Font.bmp" and "Bumps.bmp" from the "lesson17.zip" here:
http://nehe.gamedev.net/data/lessons/vc/lesson17.zip

Last edited on 20 Feb 2007.

Code: Select all

;NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)
;http://nehe.gamedev.net
;Credits: Nico Gruener, Dreglor, traumatic
;Author: hagibaba
;Date: 12 Jan 2007
;Note: up-to-date with PB v4.02 (Windows)
;Note: requires bitmaps in paths "Data/Font.bmp", "Data/Bumps.bmp"

;Section for standard constants, structures, macros and declarations

CompilerIf #PB_Compiler_Unicode
  CompilerError "only works in ascii mode"  
CompilerEndIf


XIncludeFile #PB_Compiler_Home+"Examples\Sources - Advanced\OpenGL Cube\OpenGL.pbi" ;include the gl.h constants

;wingdi.h constants
#DM_BITSPERPEL=$40000
#DM_PELSWIDTH=$80000
#DM_PELSHEIGHT=$100000

;winuser.h constants
#CDS_FULLSCREEN=4
#DISP_CHANGE_SUCCESSFUL=0
#SC_MONITORPOWER=$F170

Structure AUX_RGBImageRec ;glaux.h structure
  sizeX.l : sizeY.l
  Data.l
EndStructure

Procedure.w LoWord(value.l) ;windef.h macro
  ProcedureReturn (value & $FFFF)
EndProcedure

Procedure.w HiWord(value.l) ;windef.h macro
  ProcedureReturn ((value >> 16) & $FFFF)
EndProcedure

;glaux.lib symbols
!public ___ftoll
!___ftoll dw 0
!public __imp__wsprintfA
!__imp__wsprintfA dw 0

Import "glaux.lib"
  CompilerIf #PB_Compiler_Unicode
    auxDIBImageLoad.l(filename.s) As "_auxDIBImageLoadW@4" ;loads a 24-bit Windows DIB
  CompilerElse
    auxDIBImageLoad.l(filename.s) As "_auxDIBImageLoadA@4" ;loads a 24-bit Windows DIB
  CompilerEndIf
EndImport

Import "glu32.lib"
  gluPerspective(fovy.d,aspect.d,zNear.d,zFar.d) ;sets up a perspective projection matrix
EndImport

Import "opengl32.lib"
  glClearDepth(depth.d) ;specifies the clear value for the depth buffer
  glOrtho(left.d,right.d,bottom.d,top.d,near.d,far.d) ;multiplies the current matrix by an orthographic matrix
  glTranslated(x.d,y.d,z.d) ;moves the current matrix to the point specified
EndImport

;Start of Lesson 17

Global hDC.l ;Private GDI Device Context
Global hRC.l ;Permanent Rendering Context
Global hWnd.l ;Holds Our Window Handle
Global hInstance.l ;Holds The Instance Of The Application

Global Dim keys.b(256) ;Array Used For The Keyboard Routine
Global active.b=#True ;Window Active Flag Set To TRUE By Default
Global fullscreen.b=#True ;Fullscreen Flag Set To Fullscreen Mode By Default

Global Dim texture.l(2) ;Storage For Our Font Texture
Global base.l ;Base Display List For The Font
Global loop.l ;Generic Loop Variable

Global cnt1.f ;1st Counter Used To Move Text & For Coloring
Global cnt2.f ;2nd Counter Used To Move Text & For Coloring

Declare.l WndProc(hWnd.l,uMsg.l,wParam.l,lParam.l) ;Declaration For WndProc

Procedure.l LoadBMP(Filename.s) ;Loads A Bitmap Image
  
  Protected File.l=#Null ;File Handle
  
  If Filename="" ;Make Sure A Filename Was Given
    ProcedureReturn #Null ;If Not Return NULL
  EndIf
  
  File=ReadFile(#PB_Any,Filename) ;Check To See If The File Exists
  
  If File ;Does The File Exist?
    CloseFile(File) ;Close The Handle
    ProcedureReturn auxDIBImageLoad(Filename) ;Load The Bitmap And Return A Pointer
  EndIf
  
  ProcedureReturn #Null ;If Load Failed Return NULL
  
EndProcedure

Procedure.l LoadGLTextures() ;Load Bitmaps And Convert To Textures
  
  Protected Status.l=#False ;Status Indicator
  Protected Dim *TextureImage.AUX_RGBImageRec(2) ;Create Storage Space For The Textures
  
  *TextureImage(0)=LoadBMP("Data/Font.bmp")
  *TextureImage(1)=LoadBMP("Data/Bumps.bmp")
  If *TextureImage(0) And *TextureImage(1)
    Status=#True ;Set The Status To TRUE
    
    glGenTextures_(2,@texture(0)) ;Create Two Textures
    
    For loop=0 To 2-1
      glBindTexture_(#GL_TEXTURE_2D,texture(loop))
      glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MAG_FILTER,#GL_LINEAR)
      glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MIN_FILTER,#GL_LINEAR)
      glTexImage2D_(#GL_TEXTURE_2D,0,3,*TextureImage(loop)\sizeX,*TextureImage(loop)\sizeY,0,#GL_RGB,#GL_UNSIGNED_BYTE,*TextureImage(loop)\Data)
    Next
  EndIf
  
  For loop=0 To 2-1
    If *TextureImage(loop) ;If Texture Exists
      If *TextureImage(loop)\Data ;If Texture Image Exists
        ;FreeMemory(*TextureImage(loop)\Data) ;Free The Texture Image Memory
      EndIf
      ;FreeMemory(*TextureImage(loop)) ;Free The Image Structure
    EndIf
  Next
  
  ProcedureReturn Status ;Return The Status
  
EndProcedure

Procedure BuildFont() ;Build Our Font Display List
  
  Protected cx.f ;Holds Our X Character Coord
  Protected cy.f ;Holds Our Y Character Coord
  Protected modx.l ;modulus for x coord
  
  base=glGenLists_(256) ;Creating 256 Display Lists
  
  glBindTexture_(#GL_TEXTURE_2D,texture(0)) ;Select Our Font Texture
  
  For loop=0 To 256-1 ;Loop Through All 256 Lists
    modx=loop % 16 ;Note: can't use % with floats
    cx=modx/16.0 ;X Position Of Current Character
    cy=Int(loop/16)/16.0 ;Y Position Of Current Character
    
    glNewList_(base+loop,#GL_COMPILE) ;Start Building A List
    glBegin_(#GL_QUADS) ;Use A Quad For Each Character
    glTexCoord2f_(cx,1-cy-0.0625) ;Texture Coord (Bottom Left)
    glVertex2i_(0,0) ;Vertex Coord (Bottom Left)
    glTexCoord2f_(cx+0.0625,1-cy-0.0625) ;Texture Coord (Bottom Right)
    glVertex2i_(16,0) ;Vertex Coord (Bottom Right)
    glTexCoord2f_(cx+0.0625,1-cy) ;Texture Coord (Top Right)
    glVertex2i_(16,16) ;Vertex Coord (Top Right)
    glTexCoord2f_(cx,1-cy) ;Texture Coord (Top Left)
    glVertex2i_(0,16) ;Vertex Coord (Top Left)
    glEnd_() ;Done Building Our Quad (Character)
    glTranslated(10,0,0) ;Move To The Right Of The Character
    glEndList_() ;Done Building The Display List
  Next ;Loop Until All 256 Are Built
  
EndProcedure

Procedure KillFont() ;Delete The Font From Memory
  
  glDeleteLists_(base,256) ;Delete All 256 Display Lists
  
EndProcedure

Procedure glPrint(x.l,y.l,string.s,set.l) ;Where The Printing Happens
  
  If set : set=1 : EndIf ;Is set True? If So, Make set Equal One
  
  glBindTexture_(#GL_TEXTURE_2D,texture(0)) ;Select Our Font Texture
  
  glDisable_(#GL_DEPTH_TEST) ;Disables Depth Testing
  glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
  glPushMatrix_() ;Store The Projection Matrix
  glLoadIdentity_() ;Reset The Projection Matrix
  glOrtho(0,640,0,480,-1,1) ;Set Up An Ortho Screen
  glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
  glPushMatrix_() ;Store The Modelview Matrix
  glLoadIdentity_() ;Reset The Modelview Matrix
  glTranslated(x,y,0) ;Position The Text (0,0 - Bottom Left)
  glListBase_(base-32+(128*set)) ;Choose The Font Set (0 or 1)
  glCallLists_(Len(string),#GL_BYTE,string) ;Write The Text To The Screen
  glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
  glPopMatrix_() ;Restore The Old Projection Matrix
  glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
  glPopMatrix_() ;Restore The Old Projection Matrix
  glEnable_(#GL_DEPTH_TEST) ;Enables Depth Testing
  
EndProcedure

Procedure ReSizeGLScene(width.l,height.l) ;Resize And Initialize The GL Window
  
  If height=0 : height=1 : EndIf ;Prevent A Divide By Zero Error
  
  glViewport_(0,0,width,height) ;Reset The Current Viewport
  
  glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
  glLoadIdentity_() ;Reset The Projection Matrix
  
  gluPerspective(45.0,Abs(width/height),0.1,100.0) ;Calculate The Aspect Ratio Of The Window
  
  glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
  glLoadIdentity_() ;Reset The Modelview Matrix
  
EndProcedure

Procedure.l InitGL() ;All Setup For OpenGL Goes Here
  
  If LoadGLTextures()=0 ;Jump To Texture Loading Routine
    ProcedureReturn #False ;If Textures Didn't Load Return FALSE
  EndIf
  
  BuildFont() ;Build The Font
  
  glClearColor_(0.0,0.0,0.0,0.0) ;Clear The Background Color To Black
  glClearDepth(1.0) ;Enables Clearing Of The Depth Buffer
  glDepthFunc_(#GL_LEQUAL) ;The Type Of Depth Test To Do
  glBlendFunc_(#GL_SRC_ALPHA,#GL_ONE) ;Select The Type Of Blending
  glShadeModel_(#GL_SMOOTH) ;Enables Smooth Color Shading
  glEnable_(#GL_TEXTURE_2D) ;Enable 2D Texture Mapping
  
  ProcedureReturn #True ;Initialization Went OK
  
EndProcedure

Procedure.l DrawGLScene() ;Here's Where We Do All The Drawing
  
  glClear_(#GL_COLOR_BUFFER_BIT | #GL_DEPTH_BUFFER_BIT) ;Clear The Screen And The Depth Buffer
  glLoadIdentity_() ;Reset The Modelview Matrix
  
  glBindTexture_(#GL_TEXTURE_2D,texture(1)) ;Select Our Second Texture
  
  glTranslatef_(0.0,0.0,-5.0) ;Move Into The Screen 5 Units
  
  glRotatef_(45.0,0.0,0.0,1.0) ;Rotate On The Z Axis 45 Degrees (Clockwise)
  glRotatef_(cnt1*30.0,1.0,1.0,0.0) ;Rotate On The X & Y Axis By cnt1 (Left To Right)
  
  glDisable_(#GL_BLEND) ;Disable Blending Before We Draw In 3D
  
  glColor3f_(1.0,1.0,1.0) ;Bright White
  
  glBegin_(#GL_QUADS) ;Draw Our First Texture Mapped Quad
  glTexCoord2f_(0.0,0.0) : glVertex2f_(-1.0, 1.0) ;First Texture Coord and Vertex
  glTexCoord2f_(1.0,0.0) : glVertex2f_( 1.0, 1.0) ;Second Texture Coord and Vertex
  glTexCoord2f_(1.0,1.0) : glVertex2f_( 1.0,-1.0) ;Third Texture Coord and Vertex
  glTexCoord2f_(0.0,1.0) : glVertex2f_(-1.0,-1.0) ;Fourth Texture Coord and Vertex
  glEnd_() ;Done Drawing The First Quad
  
  glRotatef_(90.0,1.0,1.0,0.0) ;Rotate On The X & Y Axis By 90 Degrees (Left To Right)
  
  glBegin_(#GL_QUADS) ;Draw Our Second Texture Mapped Quad
  glTexCoord2f_(0.0,0.0) : glVertex2f_(-1.0, 1.0) ;First Texture Coord and Vertex
  glTexCoord2f_(1.0,0.0) : glVertex2f_( 1.0, 1.0) ;Second Texture Coord and Vertex
  glTexCoord2f_(1.0,1.0) : glVertex2f_( 1.0,-1.0) ;Third Texture Coord and Vertex
  glTexCoord2f_(0.0,1.0) : glVertex2f_(-1.0,-1.0) ;Fourth Texture Coord and Vertex
  glEnd_() ;Done Drawing Our Second Quad
  
  glEnable_(#GL_BLEND) ;Enable Blending
  
  glLoadIdentity_() ;Reset The View
  
  ;Pulsing Colors Based On Text Position
  glColor3f_(1.0*Cos(cnt1),1.0*Sin(cnt2),1.0-0.5*Cos(cnt1+cnt2))
  glPrint((280+250*Cos(cnt1)),235+200*Sin(cnt2),"NeHe - "+StrF(cnt1,2),0) ;Print GL Text To The Screen
  
  glColor3f_(1.0*Sin(cnt2),1.0-0.5*Cos(cnt1+cnt2),1.0*Cos(cnt1));
  glPrint((280+230*Cos(cnt2)),235+200*Sin(cnt1),"OpenGL",1) ;Print GL Text To The Screen
  
  glColor3f_(0.0,0.0,1.0) ;Set Color To Blue
  glPrint(240+200*Cos((cnt2+cnt1)/5),2,"Giuseppe D'Agata",0)
  glColor3f_(1.0,1.0,1.0) ;Set Color To White
  glPrint(242+200*Cos((cnt2+cnt1)/5),2,"Giuseppe D'Agata",0)
  
  cnt1+0.002 ;Increase The First Counter
  cnt2+0.0016 ;Increase The Second Counter
  
  ProcedureReturn #True ;Keep Going
  
EndProcedure

Procedure KillGLWindow() ;Properly Kill The Window
  
  If fullscreen ;Are We In Fullscreen Mode?
    ChangeDisplaySettings_(#Null,0) ;If So Switch Back To The Desktop
    ShowCursor_(#True) ;Show Mouse Pointer
  EndIf
  
  If hRC ;Do We Have A Rendering Context?
    If wglMakeCurrent_(#Null,#Null)=0 ;Are We Able To Release The DC And RC Contexts?
      MessageBox_(#Null,"Release Of DC And RC Failed.","SHUTDOWN ERROR",#MB_OK | #MB_ICONINFORMATION)
    EndIf
    If wglDeleteContext_(hRC)=0 ;Are We Able To Delete The RC?
      MessageBox_(#Null,"Release Rendering Context Failed.","SHUTDOWN ERROR",#MB_OK | #MB_ICONINFORMATION)
    EndIf
    hRC=#Null ;Set RC To NULL
  EndIf
  
  If hDC And ReleaseDC_(hWnd,hDC)=0 ;Are We Able To Release The DC
    MessageBox_(#Null,"Release Device Context Failed.","SHUTDOWN ERROR",#MB_OK | #MB_ICONINFORMATION)
    hDC=#Null ;Set DC To NULL
  EndIf
  
  If hWnd And DestroyWindow_(hWnd)=0 ;Are We Able To Destroy The Window?
    MessageBox_(#Null,"Could Not Release hWnd.","SHUTDOWN ERROR",#MB_OK | #MB_ICONINFORMATION)
    hWnd=#Null ;Set hWnd To NULL
  EndIf
  
  If UnregisterClass_("OpenGL",hInstance)=0 ;Are We Able To Unregister Class
    MessageBox_(#Null,"Could Not Unregister Class.","SHUTDOWN ERROR",#MB_OK | #MB_ICONINFORMATION)
    hInstance=#Null ;Set hInstance To NULL
  EndIf
  
  KillFont() ;Destroy The Font
  
EndProcedure

;This Code Creates Our OpenGL Window. Parameters Are:
;title - Title To Appear At The Top Of The Window
;width - Width Of The GL Window Or Fullscreen Mode
;height - Height Of The GL Window Or Fullscreen Mode
;bits - Number Of Bits To Use For Color (8/16/24/32)
;fullscreenflag - Use Fullscreen Mode (TRUE) Or Windowed Mode (FALSE)

Procedure.b CreateGLWindow(title.s,width.l,height.l,bits.l,fullscreenflag.b)
  
  Protected PixelFormat.l ;Holds The Results After Searching For A Match
  Protected wc.WNDCLASS ;Windows Class Structure
  Protected dwExStyle.l ;Window Extended Style
  Protected dwStyle.l ;Window Style
  Protected WindowRect.RECT ;Grabs Rectangle Upper Left / Lower Right Values
  Protected wpos.POINT ;Window position
  
  WindowRect\left=0 ;Set Left Value To 0
  WindowRect\right=width ;Set Right Value To Requested Width
  WindowRect\top=0 ;Set Top Value To 0
  WindowRect\bottom=height ;Set Bottom Value To Requested Height
  
  fullscreen=fullscreenflag ;Set The Global Fullscreen Flag
  
  hInstance=GetModuleHandle_(#Null) ;Grab An Instance For Our Window
  
  wc\style=#CS_HREDRAW | #CS_VREDRAW | #CS_OWNDC ;Redraw On Size, And Own DC For Window
  wc\lpfnWndProc=@WndProc() ;WndProc Handles Messages
  wc\cbClsExtra=0 ;No Extra Window Data
  wc\cbWndExtra=0 ;No Extra Window Data
  wc\hInstance=hInstance ;Set The Instance
  wc\hIcon=LoadIcon_(#Null,#IDI_WINLOGO) ;Load The Default Icon
  wc\hCursor=LoadCursor_(#Null,#IDC_ARROW) ;Load The Arrow Pointer
  wc\hbrBackground=#Null ;No Background Required For GL
  wc\lpszMenuName=#Null ;We Don't Want A Menu
  wc\lpszClassName=@"OpenGL" ;Set The Class Name 
  
  If RegisterClass_(wc)=0 ;Attempt To Register The Window Class
    MessageBox_(#Null,"Failed To Register The Window Class.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  If fullscreen ;Attempt Fullscreen Mode?
    
    Protected dmScreenSettings.DEVMODE ;Device Mode
    dmScreenSettings\dmSize=SizeOf(DEVMODE) ;Size Of The Devmode Structure
    dmScreenSettings\dmFields=#DM_BITSPERPEL | #DM_PELSWIDTH | #DM_PELSHEIGHT ;bit flags to specify the members of DEVMODE that were initialized
    dmScreenSettings\dmBitsPerPel=bits ;Selected Bits Per Pixel
    dmScreenSettings\dmPelsWidth=width ;Selected Screen Width in pixels
    dmScreenSettings\dmPelsHeight=height ;Selected Screen Height in pixels
    
    ;Try To Set Selected Mode And Get Results. Note: CDS_FULLSCREEN Gets Rid Of Start Bar
    If ChangeDisplaySettings_(dmScreenSettings,#CDS_FULLSCREEN)<>#DISP_CHANGE_SUCCESSFUL
      ;If The Mode Fails, Offer Two Options. Quit Or Use Windowed Mode
      If MessageBox_(#Null,"The Requested Fullscreen Mode Is Not Supported By"+Chr(10)+"Your Video Card. Use Windowed Mode Instead?","NeHe GL",#MB_YESNO | #MB_ICONEXCLAMATION)=#IDYES
        fullscreen=#False ;Windowed Mode Selected.  Fullscreen = FALSE
      Else
        ;Pop Up A Message Box Letting User Know The Program Is Closing
        MessageBox_(#Null,"Program Will Now Close.","ERROR",#MB_OK | #MB_ICONSTOP)
        ProcedureReturn #False
      EndIf
    EndIf
    
  EndIf
  
  If fullscreen ;Are We Still In Fullscreen Mode?
    dwExStyle=#WS_EX_APPWINDOW ;Window Extended Style
    dwStyle=#WS_POPUP ;Windows Style
    ShowCursor_(#False) ;Hide Mouse Pointer
  Else
    dwExStyle=#WS_EX_APPWINDOW | #WS_EX_WINDOWEDGE ;Window Extended Style
    dwStyle=#WS_OVERLAPPEDWINDOW ;Windows Style
  EndIf
  
  AdjustWindowRectEx_(WindowRect,dwStyle,#False,dwExStyle) ;Adjust Window To True Requested Size
  
  If fullscreen=0 ;if not fullscreen mode calculate screen centered window
    wpos\x=(GetSystemMetrics_(#SM_CXSCREEN)/2)-((WindowRect\right-WindowRect\left)/2)
    wpos\y=(GetSystemMetrics_(#SM_CYSCREEN)/2)-((WindowRect\bottom-WindowRect\top)/2)
  EndIf
  
  ;CreateWindowEx_(Extended Window Style, Class Name, Window Title, Window Style, Window X Position, Window Y Position, Width, Height, No Parent Window, No Menu, Instance, No Creation Data)
  hWnd=CreateWindowEx_(dwExStyle,"OpenGL",title,dwStyle | #WS_CLIPSIBLINGS | #WS_CLIPCHILDREN,wpos\x,wpos\y,WindowRect\right-WindowRect\left,WindowRect\bottom-WindowRect\top,#Null,#Null,hInstance,#Null)
  If hWnd=0
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Window Creation Error.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  Protected pfd.PIXELFORMATDESCRIPTOR ;pfd Tells Windows How We Want Things To Be
  pfd\nSize=SizeOf(PIXELFORMATDESCRIPTOR) ;Size Of This Structure
  pfd\nVersion=1 ;Version Number
  pfd\dwFlags=#PFD_SUPPORT_OPENGL | #PFD_DOUBLEBUFFER | #PFD_DRAW_TO_WINDOW ;Format Must Support Window, OpenGL, Double Buffering
  pfd\iPixelType=#PFD_TYPE_RGBA ;Request An RGBA Format
  pfd\cColorBits=bits ;Select Our Color Depth
  pfd\cRedBits=0 ;Color Bits Ignored
  pfd\cRedShift=0
  pfd\cGreenBits=0
  pfd\cGreenShift=0
  pfd\cBlueBits=0
  pfd\cBlueShift=0
  pfd\cAlphaBits=0 ;No Alpha Buffer
  pfd\cAlphaShift=0 ;Shift Bit Ignored
  pfd\cAccumBits=0 ;No Accumulation Buffer
  pfd\cAccumRedBits=0 ;Accumulation Bits Ignored
  pfd\cAccumGreenBits=0
  pfd\cAccumBlueBits=0
  pfd\cAccumAlphaBits=0
  pfd\cDepthBits=16 ;16Bit Z-Buffer (Depth Buffer)
  pfd\cStencilBits=0 ;No Stencil Buffer
  pfd\cAuxBuffers=0 ;No Auxiliary Buffer
  pfd\iLayerType=#PFD_MAIN_PLANE ;Main Drawing Layer
  pfd\bReserved=0 ;Reserved
  pfd\dwLayerMask=0 ;Layer Masks Ignored
  pfd\dwVisibleMask=0
  pfd\dwDamageMask=0
  
  hDC=GetDC_(hWnd)
  If hDC=0 ;Did We Get A Device Context?
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Can't Create A GL Device Context.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  PixelFormat=ChoosePixelFormat_(hDC,pfd)
  If PixelFormat=0 ;Did Windows Find A Matching Pixel Format?
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Can't Find A Suitable PixelFormat.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  If SetPixelFormat_(hDC,PixelFormat,pfd)=0 ;Are We Able To Set The Pixel Format?
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Can't Set The PixelFormat.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  hRC=wglCreateContext_(hDC)
  If hRC=0 ;Are We Able To Get A Rendering Context?
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Can't Create A GL Rendering Context.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  If wglMakeCurrent_(hDC,hRC)=0 ;Try To Activate The Rendering Context
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Can't Activate The GL Rendering Context.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  ShowWindow_(hWnd,#SW_SHOW) ;Show The Window
  SetForegroundWindow_(hWnd) ;Slightly Higher Priority
  SetFocus_(hWnd) ;Sets Keyboard Focus To The Window
  ReSizeGLScene(width,height) ;Set Up Our Perspective GL Screen
  
  If InitGL()=0 ;Initialize Our Newly Created GL Window
    KillGLWindow() ;Reset The Display
    MessageBox_(#Null,"Initialization Failed.","ERROR",#MB_OK | #MB_ICONEXCLAMATION)
    ProcedureReturn #False
  EndIf
  
  ProcedureReturn #True ;Success
  
EndProcedure

Procedure.l WndProc(hWnd.l,uMsg.l,wParam.l,lParam.l)
  
  Select uMsg ;Check For Windows Messages
      
    Case #WM_ACTIVATE ;Watch For Window Activate Message
      If HiWord(wParam)=0 ;Check Minimization State
        active=#True ;Program Is Active
      Else
        active=#False ;Program Is No Longer Active
      EndIf
      ProcedureReturn 0 ;Return To The Message Loop
      
    Case #WM_SYSCOMMAND ;Intercept System Commands
      Select wParam ;Check System Calls
        Case #SC_SCREENSAVE ;Screensaver Trying To Start?
          ProcedureReturn 0 ;Prevent From Happening
        Case #SC_MONITORPOWER ;Monitor Trying To Enter Powersave?
          ProcedureReturn 0 ;Prevent From Happening
      EndSelect
      
    Case #WM_CLOSE ;Did We Receive A Close Message?
      PostQuitMessage_(0) ;Send A Quit Message
      ProcedureReturn 0 ;Jump Back
      
    Case #WM_KEYDOWN ;Is A Key Being Held Down?
      keys(wParam)=#True ;If So, Mark It As TRUE
      ProcedureReturn 0 ;Jump Back
      
    Case #WM_KEYUP ;Has A Key Been Released?
      keys(wParam)=#False ;If So, Mark It As FALSE
      ProcedureReturn 0 ;Jump Back
      
    Case #WM_SIZE ;Resize The OpenGL Window
      ReSizeGLScene(LoWord(lParam),HiWord(lParam)) ;LoWord=Width, HiWord=Height
      ProcedureReturn 0 ;Jump Back
      
  EndSelect
  
  ;Pass All Unhandled Messages To DefWindowProc
  ProcedureReturn DefWindowProc_(hWnd,uMsg,wParam,lParam)
  
EndProcedure

Procedure.l WinMain() ;Main Program
  
  Protected msg.MSG ;Windows Message Structure
  Protected done.b ;Bool Variable To Exit Loop
  
  ;Ask The User Which Screen Mode They Prefer
  If MessageBox_(#Null,"Would You Like To Run In Fullscreen Mode?","Start FullScreen?",#MB_YESNO | #MB_ICONQUESTION)=#IDNO
    fullscreen=#False ;Windowed Mode
  EndIf
  
  If CreateGLWindow("NeHe & Giuseppe D'Agata's 2D Font Tutorial",640,480,16,fullscreen)=0 ;Create The Window
    ProcedureReturn 0 ;Quit If Window Was Not Created
  EndIf
  
  While done=#False ;Loop That Runs While done=FALSE
    
    If PeekMessage_(msg,#Null,0,0,#PM_REMOVE) ;Is There A Message Waiting?
      
      If msg\message=#WM_QUIT ;Have We Received A Quit Message?
        done=#True ;If So done=TRUE
      Else ;If Not, Deal With Window Messages
        TranslateMessage_(msg) ;Translate The Message
        DispatchMessage_(msg) ;Dispatch The Message
      EndIf
      
    Else ;If There Are No Messages
      
      ;Draw The Scene. Watch For ESC Key And Quit Messages From DrawGLScene()
      If (active And DrawGLScene()=0) Or keys(#VK_ESCAPE) ;Active? Was There A Quit Received?
        done=#True ;ESC or DrawGLScene Signalled A Quit
      Else ;Not Time To Quit, Update Screen
        Delay(10)
        SwapBuffers_(hDC) ;Swap Buffers (Double Buffering)
      EndIf
      
      If keys(#VK_F1) ;Is F1 Being Pressed?   
        keys(#VK_F1)=#False ;If So Make Key FALSE
        KillGLWindow() ;Kill Our Current Window
        fullscreen=~fullscreen & 1 ;Toggle Fullscreen / Windowed Mode
        ;Recreate Our OpenGL Window
        If CreateGLWindow("NeHe & Giuseppe D'Agata's 2D Font Tutorial",640,480,16,fullscreen)=0
          ProcedureReturn 0 ;Quit If Window Was Not Created
        EndIf
      EndIf
      
    EndIf
    
  Wend
  
  ;Shutdown
  KillGLWindow() ;Kill The Window
  End ;Exit The Program
  
EndProcedure

WinMain() ;run the main program
Last edited by hagibaba on Sun Jul 01, 2007 11:16 pm, edited 9 times in total.
dige
Addict
Addict
Posts: 1247
Joined: Wed Apr 30, 2003 8:15 am
Location: Germany
Contact:

Post by dige »

Seems not work correctly here. the text is not readable. there are
only colored boxes
THCM
Enthusiast
Enthusiast
Posts: 276
Joined: Fri Apr 25, 2003 5:06 pm
Location: Gummersbach - Germany
Contact:

Post by THCM »

Just convert the 8bit bmp-files to 24bit bmp-files and everything works fine!
The Human Code Machine / Masters' Design Group
hagibaba
Enthusiast
Enthusiast
Posts: 170
Joined: Fri Mar 05, 2004 2:55 am
Location: UK
Contact:

Post by hagibaba »

Yes, the "Font.bmp" is an 8-bit bitmap. The NeheLoadBitmap procedure uses LoadImage_() which can only load 24-bit bitmaps.
The original tutorials were written using the glAux.dll which can load 8-bit and 24-bit bitmaps.
mpz
Enthusiast
Enthusiast
Posts: 494
Joined: Sat Oct 11, 2008 9:07 pm
Location: Germany, Berlin > member German forum

Re: NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)

Post by mpz »

Hello,

next code actualised for x86/x64, PB 5.73.

Sorry, but you "must" get the original texture from the internet, i have not purebasic textures for that

P.S:I think the code can work with linux and mac Osx too.


Greetings Michael

C Code and texture
iamyaker.googlepages.com/17_ImageFont.rar

Code: Select all

;NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)
;http://nehe.gamedev.net 
;https://nehe.gamedev.net/tutorial/2d_texture_font/18002/
;Credits: Nico Gruener, Dreglor, traumatic, hagibaba
;Author: MPz
;Date: 05 Oct 2021
;Note: up-to-date with PB v5.73 (Windows)

Global hDC.i ;Private GDI Device Context

Global Dim texture.l(2) ;Storage For Our Font Texture
Global base.l ;Base Display List For The Font
Global LOOP.l ;Generic Loop Variable

Global cnt1.f ;1st Counter Used To Move Text & For Coloring
Global cnt2.f ;2nd Counter Used To Move Text & For Coloring

Procedure LoadGLTextures(Names.s,Names2.s)
  
  LoadImage(0, Names) ; Load texture with name
  *pointer1 = EncodeImage(0, #PB_ImagePlugin_BMP,0,24);  
  FreeImage(0)
  
  LoadImage(0, Names2) ; Load texture with name
  *pointer2 = EncodeImage(0, #PB_ImagePlugin_BMP,0,24);  
  FreeImage(0)
  
  glGenTextures_(2, @Texture(0)) ;Create Two Textures
  
  glBindTexture_(#GL_TEXTURE_2D, Texture(0));
  glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MAG_FILTER,#GL_LINEAR)
  glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MIN_FILTER,#GL_LINEAR)
  glTexImage2D_(#GL_TEXTURE_2D, 0, 3, PeekL(*pointer1+18),PeekL(*pointer1+22), 0, #GL_BGR_EXT, #GL_UNSIGNED_BYTE, *pointer1+54);
  FreeMemory(*pointer1)
  
  glBindTexture_(#GL_TEXTURE_2D, Texture(1));
  glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MAG_FILTER,#GL_LINEAR)
  glTexParameteri_(#GL_TEXTURE_2D,#GL_TEXTURE_MIN_FILTER,#GL_LINEAR)
  glTexImage2D_(#GL_TEXTURE_2D, 0, 3, PeekL(*pointer2+18),PeekL(*pointer2+22), 0, #GL_BGR_EXT, #GL_UNSIGNED_BYTE,  *pointer2+54);
  FreeMemory(*pointer2)
  
EndProcedure

Procedure BuildFont() ;Build Our Font Display List
  
  Protected cx.f ;Holds Our X Character Coord
  Protected cy.f ;Holds Our Y Character Coord
  Protected modx.l ;modulus for x coord
  
  base=glGenLists_(256) ;Creating 256 Display Lists
  
  glBindTexture_(#GL_TEXTURE_2D,texture(0)) ;Select Our Font Texture
  
  For LOOP=0 To 256-1 ;Loop Through All 256 Lists
    modx=LOOP % 16 ;Note: can't use % with floats
    cx=modx/16.0 ;X Position Of Current Character
    cy=Int(LOOP/16)/16.0 ;Y Position Of Current Character
    
    glNewList_(base+LOOP,#GL_COMPILE) ;Start Building A List
    glBegin_(#GL_QUADS) ;Use A Quad For Each Character
    glTexCoord2f_(cx,1-cy-0.0625) ;Texture Coord (Bottom Left)
    glVertex2i_(0,0) ;Vertex Coord (Bottom Left)
    glTexCoord2f_(cx+0.0625,1-cy-0.0625) ;Texture Coord (Bottom Right)
    glVertex2i_(16,0) ;Vertex Coord (Bottom Right)
    glTexCoord2f_(cx+0.0625,1-cy) ;Texture Coord (Top Right)
    glVertex2i_(16,16) ;Vertex Coord (Top Right)
    glTexCoord2f_(cx,1-cy) ;Texture Coord (Top Left)
    glVertex2i_(0,16) ;Vertex Coord (Top Left)
    glEnd_() ;Done Building Our Quad (Character)
    glTranslated_(10,0,0) ;Move To The Right Of The Character
    glEndList_() ;Done Building The Display List
  Next ;Loop Until All 256 Are Built
  
EndProcedure

Procedure KillFont() ;Delete The Font From Memory
  
  glDeleteLists_(base,256) ;Delete All 256 Display Lists
  
EndProcedure

Procedure glPrint(x.l,y.l,string.s,set.l) ;Where The Printing Happens
  
  If set : set=1 : EndIf ;Is set True? If So, Make set Equal One
  
  glBindTexture_(#GL_TEXTURE_2D,texture(0)) ;Select Our Font Texture
  
  glDisable_(#GL_DEPTH_TEST) ;Disables Depth Testing
  glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
  glPushMatrix_() ;Store The Projection Matrix
  glLoadIdentity_() ;Reset The Projection Matrix
  glOrtho_(0,640,0,480,-1,1) ;Set Up An Ortho Screen
  glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
  glPushMatrix_() ;Store The Modelview Matrix
  glLoadIdentity_() ;Reset The Modelview Matrix
  glTranslated_(x,y,0) ;Position The Text (0,0 - Bottom Left)
  glListBase_(base-32+(128*set)) ;Choose The Font Set (0 or 1)
  
  *pointer = Ascii(string)
  ;glCallLists_(Len(string),#GL_UNSIGNED_BYTE,string) ;Write The Text To The Screen
  glCallLists_(Len(string),#GL_BYTE,*pointer) ;Write The Text To The Screen
  FreeMemory(*pointer)
  
  
  glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
  glPopMatrix_() ;Restore The Old Projection Matrix
  glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
  glPopMatrix_() ;Restore The Old Projection Matrix
  glEnable_(#GL_DEPTH_TEST) ;Enables Depth Testing
  
EndProcedure

Procedure ReSizeGLScene(width.l,height.l) ;Resize And Initialize The GL Window

 If height=0 : height=1 : EndIf ;Prevent A Divide By Zero Error
 
 ResizeGadget(0, 0, 0, width, height)
 
 glViewport_(0,0,width,height) ;Reset The Current Viewport
 
 glMatrixMode_(#GL_PROJECTION) ;Select The Projection Matrix
 glLoadIdentity_() ;Reset The Projection Matrix
 
 gluPerspective_(45.0,Abs(width/height),0.1,100.0) ;Calculate The Aspect Ratio Of The Window
 
 glMatrixMode_(#GL_MODELVIEW) ;Select The Modelview Matrix
 glLoadIdentity_() ;Reset The Modelview Matrix
 
EndProcedure

Procedure.l InitGL() ;All Setup For OpenGL Goes Here

  BuildFont() ;Build The Font
  
  glClearColor_(0.0,0.0,0.0,0.0) ;Clear The Background Color To Black
  glClearDepth_(1.0) ;Enables Clearing Of The Depth Buffer
  glDepthFunc_(#GL_LEQUAL) ;The Type Of Depth Test To Do
  glBlendFunc_(#GL_SRC_ALPHA,#GL_ONE) ;Select The Type Of Blending
  glShadeModel_(#GL_SMOOTH) ;Enables Smooth Color Shading
  glEnable_(#GL_TEXTURE_2D) ;Enable 2D Texture Mapping
 
 ProcedureReturn #True ;Initialization Went OK
 
EndProcedure

Procedure DrawScene(Gadget)
   SetGadgetAttribute(Gadget, #PB_OpenGL_SetContext, #True)
glClear_(#GL_COLOR_BUFFER_BIT | #GL_DEPTH_BUFFER_BIT) ;Clear The Screen And The Depth Buffer
  glLoadIdentity_() ;Reset The Modelview Matrix
  
  glBindTexture_(#GL_TEXTURE_2D,texture(1)) ;Select Our Second Texture
  
  glTranslatef_(0.0,0.0,-5.0) ;Move Into The Screen 5 Units
  
  glRotatef_(45.0,0.0,0.0,1.0) ;Rotate On The Z Axis 45 Degrees (Clockwise)
  glRotatef_(cnt1*30.0,1.0,1.0,0.0) ;Rotate On The X & Y Axis By cnt1 (Left To Right)
  
  glDisable_(#GL_BLEND) ;Disable Blending Before We Draw In 3D
  
  glColor3f_(1.0,1.0,1.0) ;Bright White
  
  glBegin_(#GL_QUADS) ;Draw Our First Texture Mapped Quad
  glTexCoord2f_(0.0,0.0) : glVertex2f_(-1.0, 1.0) ;First Texture Coord and Vertex
  glTexCoord2f_(1.0,0.0) : glVertex2f_( 1.0, 1.0) ;Second Texture Coord and Vertex
  glTexCoord2f_(1.0,1.0) : glVertex2f_( 1.0,-1.0) ;Third Texture Coord and Vertex
  glTexCoord2f_(0.0,1.0) : glVertex2f_(-1.0,-1.0) ;Fourth Texture Coord and Vertex
  glEnd_() ;Done Drawing The First Quad
  
  glRotatef_(90.0,1.0,1.0,0.0) ;Rotate On The X & Y Axis By 90 Degrees (Left To Right)
  
  glBegin_(#GL_QUADS) ;Draw Our Second Texture Mapped Quad
  glTexCoord2f_(0.0,0.0) : glVertex2f_(-1.0, 1.0) ;First Texture Coord and Vertex
  glTexCoord2f_(1.0,0.0) : glVertex2f_( 1.0, 1.0) ;Second Texture Coord and Vertex
  glTexCoord2f_(1.0,1.0) : glVertex2f_( 1.0,-1.0) ;Third Texture Coord and Vertex
  glTexCoord2f_(0.0,1.0) : glVertex2f_(-1.0,-1.0) ;Fourth Texture Coord and Vertex
  glEnd_() ;Done Drawing Our Second Quad
  
  glEnable_(#GL_BLEND) ;Enable Blending
  
  glLoadIdentity_() ;Reset The View
  
  ;Pulsing Colors Based On Text Position
  glColor3f_(1.0*Cos(cnt1),1.0*Sin(cnt2),1.0-0.5*Cos(cnt1+cnt2))
  glPrint((280+250*Cos(cnt1)),235+200*Sin(cnt2),"NeHe - "+StrF(cnt1,2),0) ;Print GL Text To The Screen
  
  glColor3f_(1.0*Sin(cnt2),1.0-0.5*Cos(cnt1+cnt2),1.0*Cos(cnt1));

  glPrint((280+230*Cos(cnt2)),235+200*Sin(cnt1),"OpenGL",1) ;Print GL Text To The Screen
  
  glColor3f_(0.0,0.0,1.0) ;Set Color To Blue
  glPrint(240+200*Cos((cnt2+cnt1)/5),2,"Giuseppe D'Agata",0)
  glColor3f_(1.0,1.0,1.0) ;Set Color To White
  glPrint(242+200*Cos((cnt2+cnt1)/5),2,"Giuseppe D'Agata",0)
  
  cnt1+0.002 ;Increase The First Counter
  cnt2+0.0016 ;Increase The Second Counter
 
 SetGadgetAttribute(Gadget, #PB_OpenGL_FlipBuffers, #True)
EndProcedure

Procedure CreateGLWindow(title.s,WindowWidth.l,WindowHeight.l,bits.l=16,fullscreenflag.b=0,Vsync.b=0)
  
  If InitKeyboard() = 0 Or InitSprite() = 0 Or InitMouse() = 0
    MessageRequester("Error", "Can't initialize Keyboards or Mouse", 0)
    End
  EndIf

  If fullscreenflag
    hWnd = OpenWindow(0, 0, 0, WindowWidth, WindowHeight, title, #PB_Window_BorderLess|#PB_Window_Maximize )
    OpenWindowedScreen(WindowID(0), 0, 0,WindowWidth(0),WindowHeight(0)) 
  Else  
    hWnd = OpenWindow(0, 1, 1, WindowWidth, WindowHeight, title,#PB_Window_MinimizeGadget |  #PB_Window_MaximizeGadget | #PB_Window_SizeGadget ) 
    OpenWindowedScreen(WindowID(0), 1, 1, WindowWidth,WindowHeight) 
  EndIf
  
  If bits = 24
    OpenGlFlags + #PB_OpenGL_24BitDepthBuffer
  EndIf
  
  If Vsync = 0
    OpenGlFlags + #PB_OpenGL_NoFlipSynchronization
  EndIf
  
  OpenGLGadget(0, 0, 0, WindowWidth(0),WindowHeight(0),OpenGlFlags)
  
  SetActiveGadget(0) 
  
  ReSizeGLScene(WindowWidth(0),WindowHeight(0))
  ;hDC = GetDC_(hWnd)
  
EndProcedure

CreateGLWindow("NeHe & Giuseppe D'Agata's 2D Font Tutorial (Lesson 17)",640,480,16,0)

InitGL()

LoadGLTextures("Data/Font.bmp","Data/Bumps.bmp")

Repeat

  Repeat 
    Event = WindowEvent()
    
    Select Event
      Case #PB_Event_CloseWindow
        Quit = 1
      Case #PB_Event_SizeWindow  
        ReSizeGLScene(WindowWidth(0),WindowHeight(0)) ;LoWord=Width, HiWord=Height
    EndSelect
  
  Until Event = 0
  
  ExamineKeyboard()
        
  If KeyboardPushed(#PB_Key_Escape)    ; // push ESC key
    Quit = 1                              ; // This is the end
  EndIf
  
  DrawScene(0)
  Delay(10)
Until Quit = 1


Working on - MP3D Library - PB 5.73 version ready for download
Post Reply