Global shortcut

mk-soft · **Posted:** Wed Feb 08, 2012 7:33 am

I use a globale shortcut for my program. (ALT-C)
Have any where a sample?

Thanks
Michael

Guimauve · **Posted:** Wed Feb 08, 2012 12:39 pm

Hi,

To add a Shortcut inside a program you will have to do this :

Code:

AddKeyboardShortcut(#Your_window, #PB_Shortcut_ALT | #PB_ShortCut_C, #Related_Menu_Event_ID)

Best regards.
Guimauve

mk-soft · **Posted:** Wed Feb 08, 2012 1:28 pm

It´s only for active application...

Guimauve · **Posted:** Wed Feb 08, 2012 8:03 pm

What do you mean ?

You would like to use a Global shortcut to call another program ?

Best regards.
Guimauve

ts-soft · **Posted:** Wed Feb 08, 2012 8:24 pm

A hotkey that works on the system like

Code:

RegisterHotKey_(WindowID(Window), HotkeyID, fsModifiers, Keys)

in windows.
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

remi_meier · **Posted:** Wed Feb 08, 2012 10:34 pm

You can find an example in C for a global hotkey here:
http://lists.freedesktop.org/archives/x ... 51567.html

Shardik · **Posted:** Thu Feb 09, 2012 5:25 pm

Thank you Remi for your link. My first own Google searches only found global hotkey examples
which are bound to the desktop manager. So I thought the only way to realize a solution would
have been to write separate routines for the desktop managers KDE 3 + 4, Gnome 2 + 3 + Unity,
Xfce, LXDE...

But since all distributions are currently still using XWindow (until some of them will change to
Wayland) using XWindow API functions should be the most practical approach. Therefore I tried
to convert the posted C code to PB. Currently I have tested this code to detect the newly
established hotkey <Ctrl> + <Shift> + <K> successfully in Ubuntu 11.10, Kubuntu 11.10 and Linux
Mint 12. For non-Ubuntu based distributions (or pre 11.04 Ubuntu distributions) the path to the
Xlibs has to be changed!

Code:

; Converted from cheshirekow's C-Code:
; http://lists.freedesktop.org/archives/xorg/2010-October/051567.html

EnableExplicit

#ControlMask = 1 << 2
#GrabModeAsync = 1
#KeyPress = 2
#KeyPressMask = 1
#ShiftMask = 1
#XK_K = $004B

ImportC "/usr/lib/i386-linux-gnu/libX11.a"
; ImportC "/usr/lib/libX11.a"
  XCloseDisplay(*Display)
  XDefaultRootWindow(*Display)
  XGrabKey(*Display, KeyCode.I, Modifiers.I, GrabWindow.I, OwnerEvents.i, PointerMode.I, KeyboardMode.I)
  XKeysymToKeycode(*Display, KeySym.I)
  XNextEvent(*Display, *XEvent)
  XOpenDisplay(*Display)
  XSelectInput(*Display, Window.I, EventMask.I)
  XUngrabKey(*Display, KeyCode.I, Modifiers.I, GrabWindow.I)
EndImport

ImportC "/usr/lib/i386-linux-gnu/libxcb.a" : EndImport
; ImportC "/usr/lib/libxcb.a" : EndImport
ImportC "/usr/lib/i386-linux-gnu/libXau.a" : EndImport
; ImportC "/usr/lib/libXau.a" : EndImport
ImportC "/usr/lib/i386-linux-gnu/libXdmcp.a" : EndImport
; ImportC "/usr/lib/libXdmcp.a" : EndImport

Structure XEvent
  EventType.I
  SendEvent.I
  *Display
  EventWindow.I
  RootWindow.I
  ChildWindow.I
  Time.I
  x.I
  y.I
  x_root.I
  y_root.I
  Mask.I
  KeyCode.I
  SameScreen.I
EndStructure

Define *Display
Define Event.XEvent
Define KeyCode.I
Define RootWindow.I

*Display = XOpenDisplay(0)

If *Display
  RootWindow = XDefaultRootWindow(*Display)

  If RootWindow
    KeyCode = XKeysymToKeycode(*Display, #XK_K)
    XGrabKey(*Display, KeyCode, #ControlMask | #ShiftMask, RootWindow, #False, #GrabModeAsync, #GrabModeAsync)
    XSelectInput(*Display, RootWindow, #KeyPressMask)

    Repeat
      XNextEvent(*Display, @Event)

      If Event\EventType = #KeyPress
        MessageRequester("Info", "Global Hotkey <Ctrl> + <Shift> + <K> detected and removed!")
        XUngrabKey(*Display, KeyCode, #ControlMask | #ShiftMask, RootWindow)
        Break
      EndIf

      Delay(20)
    ForEver

    XCloseDisplay(*Display)
  EndIf
EndIf

mk-soft · **Posted:** Fri Feb 10, 2012 8:29 am

Thanks to all

GT :wink:

PureBasic Forum

Global shortcut

Who is online