Allow to change a structure of a pointer

infratec · **Posted:** Fri Jan 20, 2012 2:27 pm

Hi,

it would be nice if something like this is possible:

Code:

If Type = 1
  *ptr.Type1Str = *Buffer
else
  *ptr.Type2Str = *Buffer
endif

Bernd

ts-soft · **Posted:** Fri Jan 20, 2012 4:22 pm

This is possible :wink:

//edit
not to create a structure at runtime, but to use different structures

Fred · **Posted:** Fri Jan 20, 2012 4:29 pm

Well, if you can change the structure at runtime, how will you access the fields if the structure have different fiels ? It needs to known at compile time, as PB isn't an interpreted language.

STARGÅTE · **Posted:** Fri Jan 20, 2012 4:42 pm

use structure union:

Code:

Structure BothTypes
   StructureUnion
      Type1.Type1Str
      Type2.Type2Str
   EndStructureUnion
EndStructure

*ptr.BothTypes = *Buffer
If Type = 1
  *ptr\Type1\...
Else
  *ptr\Type2\...
EndIf 

infratec · **Posted:** Fri Jan 20, 2012 7:05 pm

@Stargate

That's clear, but not what I need.
In your case I have to use the whole time a different name to access the structure. :cry:

At the moment I solve it this way:

Code:

If ChannelRecordSize = 100
  ReadChannel.Prototype_ReadChannel = @ReadChannel100()
ElseIf ChannelRecordSize = 476
  ReadChannel.Prototype_ReadChannel = @ReadChannel476()
EndIf

Than I can call the 'same' procedure: ReadChannel(*Buffer + Ptr) for the rest of the program :wink:

But I need 2 procedures which are completely identical up to the structure which I use for the pointer:

Code:

Procedure ReadChannel100(*Channel.Channel100Str)

Code:

Procedure ReadChannel476(*Channel.Channel476Str)

Bernd

helpy · **Joined:** Sat Jun 28, 2003 12:01 am **Posts:** 349

Hi,

I do not see any way to do this in PureBasic, if both structures are completely different.

If both structures are extended from a base structure and the procedure only uses the base elements, you could do the following:

Code:

Structure ChannelBase
   ; base elements
EndStructure

Structure Channel100Str Extends ChannelBase
   ; 100Str specific elements
EndStructure

Structure Channel476Str Extends ChannelBase
   ; 476Str specific elements
EndStructure

Procedure ReadChannel( *Channel.ChannelBase )
   ; ....
EndProcedure

; ....

ReadChannel( *ptr100Str )

; ....

ReadChannel( *ptr476Str )

; ....

After all there maybe is a way ... hmmm ....
You could create a standardized structure and COPY all elements from the original structure to the standardized one, which is handled by the Procedure ReadChannel(*Channel.ChannelStandardized).

cu,
guido

breeze4me · **Posted:** Sat Jan 21, 2012 8:25 am

I think anonymous structure union will be more useful.

Something like this.

Code:

Structure BothTypes
  StructureUnion
    AnonymousStructure Type1Str
    AnonymousStructure Type2Str
  EndStructureUnion
EndStructure

*ptr.BothTypes = *Buffer

or

Code:

Structure BothTypes
  StructureUnion
    AnonymousStructure   ;Type1Str
      ......
    EndAnonymousStructure
    AnonymousStructure   ;Type2Str
      ......
    EndAnonymousStructure
  EndStructureUnion
EndStructure

Edit:
Never mind.
This way has a problem.

Trond · **Posted:** Sat Jan 21, 2012 9:14 am

infratec wrote:

But I need 2 procedures which are completely identical up to the structure which I use for the pointer:

Code:

Procedure ReadChannel100(*Channel.Channel100Str)

Code:

Procedure ReadChannel476(*Channel.Channel476Str)

Bernd

If what you say is true (the procedures are actually, truly, identical) then, by definition, one structure must be a subset of the other, else field lookup wouldn't work. In this case, just pass in the address of the variable + the offset in the structure where the subset starts, and it will work regardless of declared structure.

It would help if you showed us the structures.

If you want runtime duck typing then make your structure contain a single map and shove all your members in there.

infratec · **Posted:** Sat Jan 21, 2012 4:16 pm

Hi Trond,

Here is what you want:

Code:

Structure Channel100Str
  Name.s{32}
  Dummy0.a[12]
  Transponder.a
  Dummy1.a[15]
  ServiceID.u
EndStructure

Structure Channel476Str
  Name.s{32}
  Dummy0.a[12]
  Transponder.a
  Dummy1.a[391]
  ServiceID.u
EndStructure

Prototype Prototype_ReadChannel(*Channel)
Global ReadChannel.Prototype_ReadChannel

Procedure ReadChannel100(*Channel.Channel100Str)
  Channel$ = *Channel\Name + #LF$
  Channel$ + Str(*Channel\Transponder) + #LF$
  Channel$ + Str(*Channel\ServiceID)
  AddGadgetItem(0, -1, Channel$)
EndProcedure


Procedure ReadChannel476(*Channel.Channel476Str)
  Channel$ = *Channel\Name + #LF$
  Channel$ + Str(*Channel\Transponder) + #LF$
  Channel$ + Str(*Channel\ServiceID)
  AddGadgetItem(0, -1, Channel$)
EndProcedure

Depending on the 'version' of the file which I process, I use one or the other:

Code:

:
:
:
If ChannelRecordSize = 100
  ReadChannel.Prototype_ReadChannel = @ReadChannel100()
ElseIf ChannelRecordSize = 476
  ReadChannel.Prototype_ReadChannel = @ReadChannel476()
EndIf

ClearGadgetItems(0)
For i = 1 To Channels
  ReadChannel(*Buffer + Ptr)
  Ptr + ChannelRecordSize
Next i
:
:
:

My solution works, but it's 'ugly'.

Bernd

Trond · **Posted:** Sat Jan 21, 2012 5:47 pm

If it's coming from somewhere, the format is fixed and you can't do much about it.

But If you can swap the two last fields in both structures, or make both structures extend from one, with the field Dummy1 as the only field in each used structure, this can be solved elegantly:

Code:

Structure ChannelStr
  Name.s{32}
  Dummy0.a[12]
  Transponder.a
  ServiceID.u
  Dummy1_.a[0]
EndStructure

Structure Channel100Str Extends ChannelStr
  Dummy1.a[15]
EndStructure

Structure Channel476Str Extends ChannelStr
  Dummy1.a[391]
EndStructure

Procedure ReadChannel(*Channel.ChannelStr)
  Channel$ = *Channel\Name + #LF$
  Channel$ + Str(*Channel\Transponder) + #LF$
  Channel$ + Str(*Channel\ServiceID)
  AddGadgetItem(0, -1, Channel$)
EndProcedure

ClearGadgetItems(0)
For i = 1 To Channels
  ReadChannel(*Buffer + Ptr)
  Ptr + ChannelRecordSize
Next i

skywalk · **Posted:** Sat Jan 21, 2012 6:25 pm

Trond wrote:

Code:

Structure ChannelStr
  Name.s{32}
  Dummy0.a[12]
  Transponder.a
  ServiceID.u
  ;
  Dummy1_.a[0]    ;<-- If you omit this, I assume the code will fail?
  ;
EndStructure

Structure Channel100Str Extends ChannelStr
  Dummy1.a[15]
EndStructure

Structure Channel476Str Extends ChannelStr
  Dummy1.a[391]
EndStructure

Nice.

I noticed this behavior a while back and thought it was a mistake.
Even though you don't reference the extended structure, the fields are there for the taking.

PureBasic Forum

Allow to change a structure of a pointer

Who is online