Enable and disable single tab in PanelGadget

[Shardik]

Code: Select all

EnableExplicit

ImportC ""
  SetTabEnabled(TabControlRef.L, TabToHilite.W, Enabled.L)
EndImport

Define Tab2State.L = #True

OpenWindow(0, 270, 100, 290, 170, "Enable/Disable Tab 2")
ButtonGadget(0, WindowWidth(0) / 2 - 55, WindowHeight(0) - 30, 110, 20, "Disable Tab 2")
PanelGadget(1, 10, 10, WindowWidth(0) - 20, WindowHeight(0) - 50)
AddGadgetItem (1, -1, "Tab 1")
AddGadgetItem(1, -1,"Tab 2")
ButtonGadget(2, GadgetWidth(1) / 2 - 40, 25, 80, 20, "Click me!")
AddGadgetItem(1, -1,"Tab 3")
SetGadgetState(1, 1)

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow
      Break
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 0
          Tab2State ! 1
          
          If Tab2State
            SetGadgetText(0, "Disable Tab 2")
          Else
            SetGadgetText(0, "Enable Tab 2")
            
            ; ----- If Tab 2 is disabled and selected, select Tab 1
            If GetGadgetState(1) = 1
              SetGadgetState(1, 0)
            EndIf
          EndIf
          
          SetTabEnabled(GadgetID(1), 2, Tab2State)
          Draw1Control_(GadgetID(1))
        Case 2
          Debug "Click onto 'Click me!' button detected!"
      EndSelect
  EndSelect
ForEver