hostname to ip

FanOfGun · **Joined:** Thu Feb 07, 2013 1:04 pm **Posts:** 1

Hi, I need to convert hostname to ip in Linux, how can I do this? Snx in advance.

Shardik · **Posted:** Sat May 11, 2013 11:03 am

The following example code displays all IP addresses belonging to a given host name. I have tested the cross-platform code successfully on these operating systems:
- Kubuntu 12.04 x64 with PB 5.11 x64 in ASCII and Unicode mode
- MacOS X 10.6.8 (Snow Leopard) with PB 5.11 x86 and x64 in ASCII and Unicode mode
- Windows 7 SP1 x64 with PB 5.11 x86 and x64 in ASCII and Unicode mode

Code:

CompilerIf Defined(HOSTENT, #PB_Structure) = #False
  Structure hostent
    *h_name
    *h_aliases
    h_addrtype.L
    h_length.L
    *h_addr_list
  EndStructure
CompilerEndIf

InitNetwork()

Procedure GetIPAddressesFromHostname(Hostname.S)
  Protected *HostInfos.hostent
  Protected *HostnameBuffer

  *HostNameBuffer = AllocateMemory(StringByteLength(Hostname, #PB_Ascii))
  PokeS(*HostnameBuffer, Hostname, MemorySize(*HostnameBuffer), #PB_Ascii)
  *HostInfos = gethostbyname_(*HostnameBuffer)
  FreeMemory(*HostnameBuffer)
 
  If *HostInfos = 0
    Debug "Error: unable to find host name!"
  Else
    Debug "Hostname: " + PeekS(*HostInfos\h_name, -1, #PB_Ascii)

    If *HostInfos\h_length = 4
      IPType = #PB_Network_IPv4
    Else
      IPType = #PB_Network_IPv6
    EndIf
   
    Debug "IP addresses:"
    *IP = *HostInfos\h_addr_list
   
    While PeekI(*IP) <> 0
      Debug IPString(PeekI(PeekI(*IP)), IPType)
      *IP + SizeOf(Integer)
    Wend
  EndIf

  Debug ""
EndProcedure

GetIPAddressesFromHostname("www.google.com")
GetIPAddressesFromHostname("www.purebasic.com")

Update: I have modified the previous code to also run on Windows.

Bisonte · **Joined:** Tue Oct 09, 2007 2:15 am **Posts:** 249

the function

Code:

gethostbyname_(*HostnameBuffer)

is crossplatform ???

Shardik · **Posted:** Sat May 11, 2013 2:43 pm

Bisonte wrote:

the function

Code:

gethostbyname_(*HostnameBuffer)

is crossplatform ???

No, it's a Unix API function. But the core of MacOS X is a BSD Unix, therefore most Unix API functions also work for MacOS X... :wink:

ts-soft · **Posted:** Sat May 11, 2013 2:49 pm

Shardik wrote:

No, it's a Unix API function. But the core of MacOS X is a BSD Unix, therefore most Unix API functions also work for MacOS X... :wink:

And it is a windows-API :wink:

Shardik · **Posted:** Sat May 11, 2013 3:00 pm

ts-soft wrote:

And it is a windows-API :wink:

Too slow... :twisted:

Thomas is right. Before being able to reboot from MacOS into Windows 7 and being able to test, he posted already his remark. When looking up the structure hostent I wondered already why the structure was also described in a MSDN link... :lol:

I modified my above code example to also run in Windows without any modification.

Bisonte · **Joined:** Tue Oct 09, 2007 2:15 am **Posts:** 249

I'm impressed

The first API call that does on all OS the same ...

PureBasic Forum

hostname to ip

Who is online