List of structure items vs. Pointer list of structure items

[helpy]

Example:

Code: Select all

EnableExplicit

Structure tItem
	type.i
	id.s
	name.s
EndStructure

Define NewList ListOfItems.tItem()
Define NewList *ListOfItemPointers.tItem()

Procedure FillListOfItems(List Items.tItem(), SizeOfList=10)
	Protected i
	For i = 1 To SizeOfList
		AddElement(Items())
		With Items()
			\id = RSet(Str(i),8,"0")
			\name = "ListOfItems::0x" + RSet(Hex(i),8,"0")
			\type = Random($7FFFFFFF)
		EndWith
	Next
EndProcedure

Procedure FillListOfItemPointers(List *Items.tItem(), SizeOfList=10)
	Protected i, *item.tItem
	For i = 1 To SizeOfList
		*item = AllocateStructure(tItem)
		If *item
			With *item
				\id = RSet(Str(i),8,"0")
				\name = "ListOfItemPointers::0x" + RSet(Hex(i),8,"0")
				\type = Random($7FFFFFFF)
			EndWith
			AddElement(*Items())
			*Items() = *item
		EndIf
	Next
EndProcedure


Procedure DebugListOfItems(List Items.tItem())
	Debug ">>>>>>>>>> Debug ListOfItems >>>>>>>>>>"
	ForEach Items()
		Debug Items()\name
	Next
EndProcedure

Procedure DebugListOfItemPointers(List *Items.tItem())
	Debug ">>>>>>>>>> Debug ListOfItemPointers >>>>>>>>>>"
	ForEach *Items()
		Debug *Items()\name
	Next
EndProcedure


FillListOfItems(ListOfItems())
FillListOfItemPointers(*ListOfItemPointers())

DebugListOfItems(ListOfItems())
DebugListOfItemPointers(*ListOfItemPointers())

Debug ""
Debug ""
Debug "Wrong use of the procedures:"
Debug ""
DebugListOfItems(*ListOfItemPointers())
DebugListOfItemPointers(ListOfItems())

Shouldn't the compiler report, that a wrong list is passed to a procedure.

[mk-soft]

You can not switch the list

Code: Select all

;DebugListOfItems(*ListOfItemPointers())
;DebugListOfItemPointers(ListOfItems())
DebugListOfItems(ListOfItems())
DebugListOfItemPointers(*ListOfItemPointers())

Akzept only the same list type

[helpy]

You can not switch the list

I know!

My question is:
Shouldn't the compiler warn the user?

[mk-soft]

I believe in this case that it is too similar.
It is the same structure.

Compiler warning bug?

[normeus]

Smaller example showing that a list as a parameter in a procedure is just a pointer to a list.
look at my "Declare"

Code: Select all

EnableExplicit
NewList goodpeople()

NewList *good()

Declare procgoodpeople(List goodpeople())

Procedure procgoodpeople( List *good())

   AddElement(*good())
   *good()=1+*good()
   
EndProcedure
AddElement(*good())


procgoodpeople(goodpeople())

Debug goodpeople()
Debug ListSize(goodpeople())
Debug ListSize(*good())

Norm.

[helpy]

But the following lists are stored completley differently in memory:

Code: Select all

Define NewList ListOfItems.tItem()
Define NewList *ListOfItemPointers.tItem()

AddElement to ListOfItems will automatically allocate memory with SizeOf(tItem) for each element.
AddElement to *ListOfItemPointers will only allocate an integer for each new element.

The example of normeus is not the same!

Code: Select all

[code]NewList goodpeople()
NewList *good()

[/code]Both lists goodpeople() and *good() work the same because element size has the size of an integer for both lists!

[normeus]

Sorry to make it confusing.
I was trying to point out that when you define a parameter as a list of pointers then you can send any list to the procedure.
I used this "Feature" before. You can see that my declare does not match my procedure at all. Just be aware of this.

Code: Select all

EnableExplicit

Structure earth
   northAmerica.i
   SouthAmerica.i
   europe.i
   africa.i
   asia.i
EndStructure

Structure moon
moonpeople.s
EndStructure

NewList goodpeople()  

NewList *good.earth()

Declare procgoodpeople(List goodpeople.s())

Procedure procgoodpeople( List *good())

   AddElement(*good())
   *good()=1+*good()
   
EndProcedure
AddElement(*good())


procgoodpeople(goodpeople())

Debug goodpeople()
Debug ListSize(goodpeople())
Debug ListSize(*good())

Norm.