[Solved] UnbindEvent() : Bug or not (Or i'm a bug :p)

[falsam]

■ Just for example : If I move a window, I unbind the callback for the current window. But it does not work.

Code: Select all

Declare Start()
Declare MoveWindow()
Declare Exit()

Start()

Procedure Start()
  OpenWindow(0, 0, 0, 400, 300, "Test", #PB_Window_SystemMenu)
  OpenWindow(1, 410, 0, 400, 300, "Test", #PB_Window_SystemMenu)
    
  ;Triggers
  BindEvent(#PB_Event_CloseWindow, @Exit())  
  BindEvent(#PB_Event_MoveWindow, @MoveWindow())
  
  Repeat : WaitWindowEvent() : ForEver
EndProcedure

Procedure MoveWindow()
  Protected Window = EventWindow()
  Debug "Move window " + Window
  UnbindEvent(#PB_Event_MoveWindow, @MoveWindow(), Window)
EndProcedure

Procedure Exit()  
  End
EndProcedure

■ The solution is to make a bind for each window.

Code: Select all

Declare Start()
Declare MoveWindow()
Declare Exit()

Start()

Procedure Start()
  OpenWindow(0, 0, 0, 400, 300, "Test", #PB_Window_SystemMenu)
  OpenWindow(1, 410, 0, 400, 300, "Test", #PB_Window_SystemMenu)
    
  ;Triggers
  BindEvent(#PB_Event_CloseWindow, @Exit())  
  
  BindEvent(#PB_Event_MoveWindow, @MoveWindow(), 0)
  BindEvent(#PB_Event_MoveWindow, @MoveWindow(), 1)
    
  Repeat : WaitWindowEvent() : ForEver
EndProcedure

Procedure MoveWindow()
  Protected Window = EventWindow()
  Debug "Move window " + Window
  UnbindEvent(#PB_Event_MoveWindow, @MoveWindow(), Window)
EndProcedure

Procedure Exit()  
  End
EndProcedure

So: Bug or not? Thanks.

[User_Russian]

In my opinion this is not a bug.

Code: Select all

Declare Start()
Declare MoveWindow()
Declare Exit()

Start()

Procedure Start()
  OpenWindow(0, 0, 0, 400, 300, "Test", #PB_Window_SystemMenu)
  OpenWindow(1, 410, 0, 400, 300, "Test", #PB_Window_SystemMenu)
    
  ;Triggers
  BindEvent(#PB_Event_CloseWindow, @Exit())  
  BindEvent(#PB_Event_MoveWindow, @MoveWindow())
  
  Repeat : WaitWindowEvent() : ForEver
EndProcedure

Procedure MoveWindow()
  Protected Window = EventWindow()
  Debug "Move window " + Window
  UnbindEvent(#PB_Event_MoveWindow, @MoveWindow())
EndProcedure

Procedure Exit()  
  End
EndProcedure

[falsam]

@User_Russian : Hello. Your example removes the callback for both windows. I wanted to remove the callback when you move the window 0 and after when you move the window 1.

My debug must be

Move window 0
Move window 1

This is not the result of your code

[Fred]

You can't unbind a general event for only one window. You need to register the event for each window if you plan to unbind them later

Code: Select all

Declare Start()
Declare MoveWindow()
Declare Exit()

Start()

Procedure Start()
  OpenWindow(0, 0, 0, 400, 300, "Test", #PB_Window_SystemMenu)
  OpenWindow(1, 410, 0, 400, 300, "Test", #PB_Window_SystemMenu)
   
  ;Triggers
  BindEvent(#PB_Event_CloseWindow, @Exit()) 
  BindEvent(#PB_Event_MoveWindow, @MoveWindow(), 0)
  BindEvent(#PB_Event_MoveWindow, @MoveWindow(), 1)
 
  Repeat : WaitWindowEvent() : ForEver
EndProcedure

Procedure MoveWindow()
  Protected Window = EventWindow()
  Debug "Move window " + Window
  UnbindEvent(#PB_Event_MoveWindow, @MoveWindow(), Window)
EndProcedure

Procedure Exit() 
  End
EndProcedure

[falsam]

You need to register the event for each window if you plan to unbind them later

Solved. Not a bug. Thanks Fred.