How to do Log2 ?

TeraByte · **Joined:** Wed May 09, 2012 12:40 am **Posts:** 28

I need the function Log2 and came up with the following:

Code:

Define x.d, num.d
x = 8
num = Log(x)/Log(2)

which gives num = 2.99999999999996 which is close but not exact. The exact answer is 3 which is 2^3 = 8 or Log2(8) = 3. Perhaps this difference is due to floating point error.

QUESTION:
Is there a better way to calculate Log2 than the above?

Thank you.

skywalk · **Posted:** Tue May 29, 2012 11:06 pm

You already have the correct answer for a double.

Code:

Define x.d, num.d
x = 8
num = Log(x)/Log(2)
Debug num
x = 3 * 6.1 / 2 / 6.1 * 2
Debug x
x = 3
Debug x

Shield · **Joined:** Fri Jan 21, 2011 8:25 am **Posts:** 549

Code:

#Log2 = 0.6931471805599453094

Define x.d
Define num.d

x = 8
num = Log(x) / #Log2

debug num

STARGÅTE · **Posted:** Tue May 29, 2012 11:14 pm

if you want to use it for quads and use only integers:

Code:

Procedure Log2(Quad.q)
   While Quad <> 0
      Result + 1
      Quad>>1
   Wend
   ProcedureReturn Result-1
EndProcedure

Debug Log2(8)
Debug Log2(1024)

wilbert · **Posted:** Wed May 30, 2012 5:10 am

Code:

Procedure.d Log2(x.d)
  Protected l.d = x
  !fld1
  !fld qword [p.v_l]
  !fyl2x
  !fstp qword [p.v_l]
  ProcedureReturn l
EndProcedure

TeraByte · **Joined:** Wed May 09, 2012 12:40 am **Posts:** 28

Thank you for your excellent replies.

Little John · **Posted:** Wed May 30, 2012 3:52 pm

2wilbert:
Very cool!

What is the minimal required prozessor for running this code?

Regards, Little John

wilbert · **Posted:** Wed May 30, 2012 4:22 pm

Little John, an old 486 processor should be sufficient.

Little John · **Posted:** Wed May 30, 2012 4:26 pm

Great, thank you!

jack · **Joined:** Fri Apr 25, 2003 11:10 pm **Posts:** 852

a little shorter :twisted:

Code:

Procedure.d Log2(x.d)
  !fld1
  !fld qword [p.v_x]
  !fyl2x
  ProcedureReturn
EndProcedure

return value can be left in st(0)

wilbert · **Posted:** Thu May 31, 2012 6:34 am

jack wrote:

a little shorter

I know it's shorter.
The main reason why I did it a bit different is that I wasn't sure your solution would work on x64 since that officially expects a floating point value to be returned in xmm0.
I figured if I would PureBasic let handle the way it returns the value that that might be a more stable option. But maybe I'm wrong

Another option, if you only need the integer part of the result and the source is a double is to do it like this

Code:

x.d = 64
Debug PeekW(@x + 6) >> 4 - 1023

If both source and result are integer, you can also use bsr

Code:

Procedure.i Log2(x.i)
  CompilerIf #PB_Compiler_Processor = #PB_Processor_x86
    !mov eax, -1
    !bsr edx, [p.v_x]
    !cmovnz eax, edx
  CompilerElse
    !mov rax, -1
    !bsr rdx, [p.v_x]
    !cmovnz rax, rdx
  CompilerEndIf
  ProcedureReturn
EndProcedure

PureBasic Forum

How to do Log2 ?

Who is online