Single-line Scintilla?

kenmo · **Posted:** Tue Sep 25, 2012 1:07 am

Scintilla / the ScintillaGadget is a wonderful tool. Cross-platform, easy to customize and stylize, simple callback, etc. I just started using it this past year and I appreciate it very much...

I appreciate it so much I would like to use it in place of some StringGadgets (for formatting, mainly). Is it possible to force a ScintillaGadget to only allow a single line of text?

I have a feeling I will just need to watch the callback and manually filter out newline characters when typed or pasted.... unless anyone knows of a better way.

RASHAD · **Joined:** Sun Apr 12, 2009 6:27 am **Posts:** 1475

Maybe ?

Code:

  If OpenWindow(0, 0, 0, 320, 90, "ScintillaGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  
        InitScintilla()
        ScintillaGadget(0, 10, 10, 300, 40, #Null)        
        ScintillaSendMessage(0, #SCI_STYLESETFORE, 0, RGB(255, 0, 0))
        
 Repeat    
  Select WaitWindowEvent()
     
     Case #PB_Event_CloseWindow
          Quit = 1
          
     Case #PB_Event_Gadget
        Select EventGadget()
           Case 0
                  If ScintillaSendMessage(0, #SCI_GETLINECOUNT) > 1
                     Repeat                    
                        ScintillaSendMessage(0, #SCI_DELETEBACK)                    
                     Until ScintillaSendMessage(0, #SCI_GETLINECOUNT) = 1
                  EndIf
        EndSelect 
  EndSelect
Until Quit = 1
  EndIf

falsam · **Posted:** Tue Sep 25, 2012 9:00 am

To complete the code Rashad,
You can remove the horizontal scroll.

Code:

ScintillaSendMessage(0, #SCI_SETHSCROLLBAR, 0)

SetGadgetText not work. replaced by

Code:

ScintillaSendMessage(0, #SCI_SETTEXT, 0, @"Hello")

GettGadgetText not work. replaced by this procedure

Code:

Procedure.s ScintillaGetText(Gadget.l)
  Protected SciLength.i, *MemoryID.l, Buffer.s
  
  SciLength = ScintillaSendMessage(Gadget, #SCI_GETLENGTH)+1
      *MemoryID = AllocateMemory(SciLength)
      If *MemoryID
        ScintillaSendMessage(Gadget, #SCI_GETTEXT, SciLength, *MemoryID)
        Buffer=PeekS(*MemoryID)
        FreeMemory(*MemoryID)  
      EndIf
      ProcedureReturn(Buffer)
EndProcedure

Rashad code updated

Code:

Procedure.s ScintillaGetText(Gadget.l)
  Protected SciLength.i, *MemoryID.l, Buffer.s
  
  SciLength = ScintillaSendMessage(Gadget, #SCI_GETLENGTH)+1
      *MemoryID = AllocateMemory(SciLength)
      If *MemoryID
        ScintillaSendMessage(Gadget, #SCI_GETTEXT, SciLength, *MemoryID)
        Buffer=PeekS(*MemoryID)
        FreeMemory(*MemoryID)  
      EndIf
      ProcedureReturn(Buffer)
EndProcedure

Procedure ScintillaSetText(Gadget.l, Buffer.s)
  ScintillaSendMessage(Gadget, #SCI_SETTEXT, 0, @Buffer)
EndProcedure


If OpenWindow(0, 0, 0, 320, 90, "ScintillaGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  
        InitScintilla()
        ScintillaGadget(0, 10, 10, 300, 40, #Null)        
        ScintillaSendMessage(0, #SCI_STYLESETFORE, 0, RGB(255, 0, 0))
        
        ScintillaSendMessage(0, #SCI_SETHSCROLLBAR, 0)
        
        ScintillaSetText(0, "Hello")
        Debug ScintillaGetText(0)

        
 Repeat    
     Select WaitWindowEvent()
     
     Case #PB_Event_CloseWindow
          Quit = 1
          
     Case #PB_Event_Gadget
        Select EventGadget()
           Case 0
                 If ScintillaSendMessage(0, #SCI_GETLINECOUNT) > 1
                    ScintillaSendMessage(0, #SCI_DELETEBACK)
                 EndIf              
        EndSelect
  EndSelect
Until Quit = 1
  EndIf

RASHAD · **Joined:** Sun Apr 12, 2009 6:27 am **Posts:** 1475

kenmo did not ask about hiding the horizontal scroll :mrgreen:

Much more simple

Code:

  If OpenWindow(0, 0, 0, 300, 90, "ScintillaGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  
        InitScintilla()
        ContainerGadget(0,10,10,300,22)
          ScintillaGadget(1,-16, 0, 300, 40, #Null)
        CloseGadgetList()        
        ScintillaSendMessage(1, #SCI_STYLESETFORE, 0, RGB(255, 0, 0))
        
 Repeat    
  Select WaitWindowEvent()
     
     Case #PB_Event_CloseWindow
          Quit = 1
          
     Case #PB_Event_Gadget
        Select EventGadget()
           Case 1
                  If ScintillaSendMessage(1, #SCI_GETLINECOUNT) > 1
                     Repeat                    
                        ScintillaSendMessage(1, #SCI_DELETEBACK)                    
                     Until ScintillaSendMessage(1, #SCI_GETLINECOUNT) = 1
                  EndIf
        EndSelect 
  EndSelect
Until Quit = 1
  EndIf

falsam · **Posted:** Tue Sep 25, 2012 9:51 am

RASHAD wrote:

kenmo did not ask about hiding the horizontal scroll :mrgreen:

He did not ask .... but ask later when he has tested your previous code: p

Next time I'll wait before intervening. I would take rather a coffee

RASHAD · **Joined:** Sun Apr 12, 2009 6:27 am **Posts:** 1475

You are a fan of ScintillaGadget() falsam
I can not beat you in that field

kenmo · **Posted:** Wed Sep 26, 2012 1:51 am

Thanks to both of you, RASHAD and falsam!

This was easier than I expected.

PureBasic Forum

Single-line Scintilla?

Who is online